Discussion :

[GeomR]

Bonjour,

Je cherche à ce que mon programme fasse une boucle pour ouvrir des fichiers et récupérer ce qu'il y a dedans puis les refermer, un à un.
Ce que j'aimerais c'est renvoyer le numéro de mes fichiers qui sont contenu dans une cellule d'un tableau, pour le concaténer avec le chemin qui doit ouvrir les fichiers.
Puis la boucle fait qu'il passe à la prochaine cellule et donc au numéro de fichier suivant.

Je sais pas si je me suis bien exprimé !

Merci d'avance !

[ouskel'n'or]

As-tu un code à nous proposer qu'on puisse t'aider à résoudre le problème que tu rencontres ?

[GeomR]

Voilà mon code de base qui me permet d'ouvrir à la suite tout les fichiers d'un répertoire pour ensuite remplir mon tableau avec les informations demandés. J'aimerai faire une boucle pour plutot qu'il liste tout les fichiers de mon répertoire, il récupère le numéro de fichier dans les cellules d'un tableau.

Chemin & "\Fiche_PI_BI_*.xls"
* = cellule B2 par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Sub test()
 
    Dim derlig As Integer, i As Integer, mavar As String
 
    Application.ScreenUpdating = False
 
    Fichier_Analyse = ThisWorkbook.Name
    Call RechercheFichier(Chemin, Fichier)
    Windows(Fichier_Analyse).Activate
 
 
    FichierAnalyser = Dir(Chemin & "\Fiche_PI_BI_*.xls")
    If FichierAnalyser <> "" Then
        Do
            Application.StatusBar = "Traitement du fichier " & FichierAnalyser
 
            Workbooks.Open Filename = Chemin & "\" & FichierAnalyser
            Windows(FichierAnalyser).Activate
 
 
    derlig = Workbooks("CoordonnéesBIPI.xls").Sheets("Antony").Range("g65536").End(xlUp).Row + 1
 
    For i = 11 To 22
            mavar = Workbooks("Fiche_PI_BI_*.xls").Sheets("Page 1").Cells(i, 3).Value
            Workbooks("CoordonnéesBIPI.xls").Sheets("Antony").Cells(derlig, i - 4).Value = mavar
 
    Next
 
            Windows(FichierAnalyser).Activate
            ActiveWindow.Close SaveChanges:=False
 
            FichierAnalyser = Dir
            If FichierAnalyser = "" Then Exit Do
        Loop
    End If
    Application.StatusBar = ""
    Beep
    Application.ScreenUpdating = True
'
End Sub

[Jean-Pierre49]

Bonjour,

Je n'ais pas tout compris

Ce ne serait pas un truc du genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    FichierAnalyser = Dir(Chemin & "\Fiche_PI_BI_" & Cells(x, y) & ".xls")

ou x et y serait la position de ta cellule pendant ta boucle

[GeomR]

Voila c'est exactement ça ! Et une fois le fichier traité, il passerait au numéro de cellule suivant, sachant qu'ils sont tous dans la même colonne !

[Jean-Pierre49]

Voici l'orientation que je prendrais pour faire ce que tu veux

Je n'ais pas testé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
Sub test()
                            Dim FichierAnalyse          As Workbook
                            Dim FichierAnalyser         As Workbook
                            Dim Chemin                  As String
                            Dim CompA                   As Integer
    Dim derlig As Integer, i As Integer, mavar As String
 
    Set FichierAnalyse = ActiveWorkbook
    Chemin = "C\....\....\"
 
    Application.ScreenUpdating = False
 For CompA = 2 To FichierAnalyse.Sheets("Antony").Range("B65536").End(xlUp).Row + 1 ' voir ou tu mets tes indices de fichier
    Workbooks.Open Filename:=Chemin & "Fiche_PI_BI_" & Cells(CompA, 2) & ".xls"
    Set FichierAnalyser = ActiveWorkbook
 
    derlig = FichierAnalyse.Sheets("Antony").Range("G65536").End(xlUp).Row + 1
 
    For i = 11 To 22
        FichierAnalyse.Sheets("Antony").Cells(derlig, i - 4).Value = FichierAnalyser.Sheets("Page 1").Cells(i, 3).Value
    Next
 
    FichierAnalyser.Close SaveChanges:=False
 Next CompA
    Application.ScreenUpdating = True
 
End Sub

Tu dis

[GeomR]

Merci beaucoup pour ta proposition ! Pourrais tu me détailler un peu ce que fait ta macro ? J'ai des connaissances limitées en VB.

Merci d'avance

Edit : en tout cas le code marche nickel ! Merci bien !