Discussion :

[zycomatic]

Bonjour à tous, je cherche le moyen à l'aide de fonctions excel (je ne pense pas qu'il soi nécessaire de le faire en VBA) d'obtenir le résultat suivant :

dans un fichier utilisateurs où j'ai le nom et le prénom, je souhaiterais créer une troisième colone qui me donnerait initiale du pnom.nom (jusque là enfantin), seulement lorsque je rencontre un prénom composé (ex : jean-michel DUPONT), je voudrais avoir le modèle suivant jm.dupont.

je dois donc rechercher dans ma chaîne si j'ai le caractère "-" et le cas échéant extraire le premier caractère situé après le "-"... je pense que celà doit être faisable mais je ne sais pas comment...

pouvez-vous m'aider SVP ?

Zyco

[fring]

Bonjour zyco,

Une solution éventuelle en supposant que les prénoms composés sont toujours séparés par un "-" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERREUR(CHERCHE("-";A1));GAUCHE(A1;1)&"."&STXT(A1;CHERCHE(" ";A1)+1;50);GAUCHE(A1;1)&STXT(A1;CHERCHE("-";A1)+1;1)&"."&STXT(A1;CHERCHE(" ";A1)+1;50))

[alsimbad]

je suppose qu'il y a plus simple, mais ça marche

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
=SI(ESTERREUR(CHERCHE("-";A1;1));STXT(A1;1;1)&"."&STXT(A1;1+CHERCHE(" ";A1;1);NBCAR(A1)-CHERCHE(" ";A1;1));STXT(A1;1;1)&STXT(A1;1+CHERCHE("-";A1;1);1)&"."&STXT(A1;1+CHERCHE(" ";A1;1);NBCAR(A1)-CHERCHE(" ";A1;1)))

[zycomatic]

Merci à tous pour vos réponses, je vais tenter tout de suite

Zyco

[zycomatic]

le raisonnement semble correct mais dans mon cas il y a peut être plus simple (je m'explique...)

j'ai le prénom en A1 et le nom en A2 dans ma cellule A3 j'ai mis la formule suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=GAUCHE(B3;1)&"."&SUBSTITUE(C3;" ";"")

qui de donne le résutat style j.dupont qu'il s'agisse de Jean ou Jean-Michel

je vais donc tenter d'utiliser votre méthode pour l'appliquer à la première partie de ma formule

à suivre

Zyco

[zycomatic]

Super ça marche, ma formule finale est la suivante

=MINUSCULE(SI(ESTERREUR(CHERCHE("-";B2;1));STXT(B2;1;1);STXT(B2;1;1)&STXT(B2;1+CHERCHE("-";B2;1);1))&"."&SUBSTITUE(C2;" ";""))

dans une tableau sous la forme suivante

login | Prenom | Nom

ça donne

jm.dupont | Jean-Michel | DUPONT

pile-poil ce que je voulais !!!

Encore merci à tous

ZYCO

[alsimbad]

évidemment, nos formules semblent plus compliquées parce que j'aurais comme l'impression qu'on a tous compris que l'on faisait l'extraction a partir d'une seule cellule. comme quoi, faut bien lire l'énoncé, en relisant , on voit bien que c'était écris

je souhaiterais créer une troisième colone