Discussion :

[abouhossam]

bjr
j'ai fait un macro dont le but est de trouver les double que j'ai dans la colonne où j'ai saisie des "n° de cadre"
le macro:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
sub macro1()
whith sheets(1)
    for i=2 to .range("a65535").end(xlup).row
       for j=1+i to .range("a65535").end(xlup).row
           if .cells(i,1)=.cells(j,1)and .cells(i,1)<>"" and .cells(j,1)<>"" then
               msgbox "ce n°      " & .cells(i,1) & "      de cadre est déjà saisi"
           end if
       next
    next
end with
end sub

le prob c'est que je veux que le message s'affiche lors de la saisi, est ce que c'est possible.
merci.

[ouskel'n'or]

Déjà, ce n'est pas Whith mais With (avec)
Pour le reste, je regarde

NB - Pense à baliser ton code, icône # -> Sélection du code + 1 clic sur #

[abouhossam]

vous avez des grandes yeux.

merci

[ouskel'n'or]

Si ça résoud ton problème, alors un petit clic sur pour qu'on sâche que c'est résolu (en bas de cette fenêtre)

[abouhossam]

non pas encore
je voulais que la macro s'execute lors de la saisie
merci.

[Abed_H]

Bonjour
sans vba Données>Validation>Autoriserersonnalisé
dans la zone Formule:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI($A:$A;A1)>1

onglet Alerte d'erreur Ect…..
Abed_H

[abouhossam]

ça marche pas.

[Abed_H]

Ouups

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI($A$1:$A$20;A1)=1

[Many31]

Ouups

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI($A$1:$A$20;A1)=1

a bah voila :/ mon tit vieux préféré qui devient gateu :/

[ouskel'n'or]

non pas encore
je voulais que la macro s'execute lors de la saisie
merci.

Tu peux également par une macro dans l'événement Change de la feuille de calculs -> Editeur VBA - Deux clics sur le nom de la feuille.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Private Sub Worksheet_Change(ByVal Target As Range)
'l'événement Change se produit en quittant la cellule que l'on vient de renseigner
Dim firstAddress As String, c As Range
    'Target correspond à la cellule active avant d'en sortir
    'si la cellule est vide, on sort sans rien faire
    If Target = "" Then Exit Sub
    'La recherche de la donnée saisie se fait dans la colonne de Target
    With ActiveSheet.Columns(Target.Column)
        'Si la donnée est trouvée, c la contient
        'Cette donnée, c'est celle qui se trouve dans la cellule active (Target)... donc
        Set c = .Find(Target.Value, LookIn:=xlValues)
        'c n'est pas "rien" si la donnée a été trouvée
        If Not c Is Nothing Then
            'on mémorise l'adresse de la donnée trouvée afin d'éviter une boucle sans fin
            firstAddress = c.Address
            'La donnée existe forcément puisqu'on vient de la saisir
            'mais on ignore si ce n'est pas une donnée pré-existante
            Do
                'Donc, si l'adresse de cette donnée est différente de celle de Target
                'on sait que target est un doublon
                If c.Address <> Target.Address Then
                    MsgBox "Le cadre " & Target & " existe déjà"
                    'On retourne alors sur Target
                    Target.Select
                    '... et on efface la donnée
                    Target = ""
                    Exit Do
                End If
                Set c = .FindNext(c)
                'Tant que la boucle ne nous replace pas sur la première donnée trouvée
            Loop While Not c Is Nothing And c.Address <> firstAddress
        End If
    End With
End Sub

Si une formule ne te suffit pas

[abouhossam]

bjr
marci bcp ouskel'n'or.
la macro ça marche mais j'ai une défficulté de comprendre ton macro peux tu m'aider à la comprendre?
merci.

[Abed_H]

Many31;2976703]a bah voila :/ mon tit vieux préféré qui devient gateu :/

Vous là-bas, au fond,
je vous demande de vous taire et de laisser parler les premiers rangs !

[ouskel'n'or]

Ok, j'ajoute des commentaires dans le post précédent... Laisse-moi juste une seconde

Edit
C'est fait, j'ai ajouté les commentaires, tu peux jeter un oeil
Bon courage

[abouhossam]

bjr
la macro ça marche mais notez vous que je voulais que la macro travail seulement sur la colonne "a", est ce que vous avez une autre aidée.
merci.

[abouhossam]

un petit problème:
si la colonne "a" contient par exemple le n° (1542) et j'ai saisi (54) ; le message "le cadre 54 existe déjà" s'est affiché car la macro a trouvé 54 dans la chaîne de 1542.
notez vous que je ne veux pas un macro qui s'execute sur toute la feuille mais sur la colonne "a" seulement
un grand merci.

[Qwazerty]

SAlut
Ben pour que ça ne prenne effet que dans la colonne A tu test au début du code si tu t'y trouve bien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Target.column <> 1 Then Exit Sub

et pour que ça tienne compte du contenue exact faut modifier l'appel au Find comme ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Find(What:="bon",LookAt:=xlWhole)

(Je l'avais dans mon Clipboard quand même cet exemple

Sinon pour ton cas ça ferait ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set c = .Find(Target.Value,LookAt:=xlWhole, LookIn:=xlValues)

A toutes fins utiles je rappelles l'utilisation de l'aide, on click sur le mot (ici find) et on tape sur

A++
Qwaz

[abouhossam]

bjr
merci QWAZERTY de ton aide la macro est:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub Worksheet_Change(ByVal Target As Range)
Dim firstAddress As String, c As Range
    If Target.Column <> 1 Then Exit Sub
      With ActiveSheet.Columns(Target.Column)
        Set c = .Find(Target.Value, LookAt:=xlWhole)
        If Not c Is Nothing Then
            firstAddress = c.Address
            Do
                If c.Address <> Target.Address And Target <> "" Then
                    MsgBox "Le cadre " & Target & " existe déjà"
                    Target.Select
                    Target = ""
                    c.Select
 
                    Exit Do
                   End If
 
                Set c = .FindNext(c)
            Loop While Not c Is Nothing And c.Address <> firstAddress
        End If
    End With
End Sub

comme tu vois j'ai ajouté and Target <> "" dans la ligne If c.Address <> Target.Address And Target <> "" Then car la macro prend en considération les cellules vides.
merci bcp.

[Qwazerty]

Salut
Penses au balise code quand tu mets du code, sinon ça enlève les indentations et le code est difficilement lisible (sélectionne ton code + bouton # dans l'éditeur, je sais pas si tu sais ou pas donc je le met)
Pour ce qui est de ton code, si tu ne veux pas tenir compte des case vid, ce que je comprend aisément tu peux faire comme cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Worksheet_Change(ByVal Target As Range)
Dim firstAddress As String, c As Range
If (Target.Column <> 1) Or (Target = "") Then Exit Sub
    With ActiveSheet.Columns(Target.Column)
        Set c = .Find(Target.Value, LookAt:=xlWhole)
        If Not c Is Nothing Then
            firstAddress = c.Address
            Do
                If c.Address <> Target.Address Then
                    MsgBox "Le cadre " & Target & " existe déjà"
                    Target = ""
                    c.Select
                    Exit Do
                End If
                Set c = .FindNext(c)
            Loop While Not c Is Nothing And c.Address <> firstAddress
        End If
    End With
 
End Sub

Il n'est pas utile de commencer a faire des opération sur cette case si de toute façon on va la rejeter par ce qu'elle est vide, autant le faire de suite elle souffrira moins
A++
Qwaz

[abouhossam]

ça marche merci.