Discussion :

[Many31]

Bonjour a tous pour une énieme question... cette fois ci je doute qu'il y ait des possibilité de résoudre ce pb sur Vba :/

==> comment mettre en forme une partie du texte contenu dans une cellule...

Les macros enregistrée ne peuvent pas suivre sur ce sujet... une erreur d'enregistrement est produite.

Pourtant il est possible de mettre en forme une partie du texte seulement:

exemple

Ce texte ci. Par A. Talon

cet exemple est possible dans une cellule... coder cette mise en forme?? est ce possible?

[Invité]

Bonjour

C'est possible, regardes dans l'aide avec Characters

Remarque : je ne me souvenais pas du nom, je l'ai retrouvé grâce à l'enregistreur de macro.

Starec

[Many31]

ouaip je viens de voir aussi -_-" je me suis fait eu par Excel.... deg

en fait excel veut bien faire une mise en forme spécifique... la seule chose qu'il refuse c'est la sélection du texte par la souris.
Dans ce cas là l'enregistreur ne suit plus...

donc mon problème c'est de savoir maintenant si je peux réaliser cette mise en forme dans un objet. :/

[cafeine]

Hello,

Un exemple de code pour mettre en évidence un mot sur une plage de cellules afin d'illustrer l'utilisation de Characters.

Utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

highlightword   "gestion", Range("A1:A30")

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Option Explicit
 
Public Sub HighlightWord(ByVal str As String, r As Range)
 
    Dim res As Range
    Dim firstAddress As String, pos As Long
 
    ' on fait une recherche sur la plage
    With r.Cells
        Set res = .Find(What:=str, After:=r.Cells(1, 1), LookIn:=xlFormulas _
            , LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False)
 
        If Not res Is Nothing Then
            firstAddress = res.Address
            Do
                pos = InStr(res.Value, str)
                Do While pos > 0
                    With res.Characters(pos, Len(str))
                        'ici on mettra en gras rouge
                        .Font.Color = vbRed
                        .Font.Bold = True
                    End With
                    pos = InStr(pos + 1, res.Value, str)
                Loop
                Set res = .Find(What:=str, After:=res, LookIn:=xlFormulas _
                        , LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlNext, _
                        MatchCase:=False, SearchFormat:=False)
            Loop While Not res Is Nothing And res.Address <> firstAddress
        End If
    End With
 
    Set res = Nothing
 
End Sub

[Many31]

Merci a vous. Suite au recherche je pense qu'une simple combobox ne pourrait suffire et comme j'arrive pas a activer les Rich Text Box je pense que je vais pas perséver dans cette voie et me contenter de mettre en forme le texte des cellules :/