Discussion :

[Pwouaro]

Bonjour,

Essayons d'être clair ^^'

J'ai un formulaire sur lequel figure une zone de liste (simple), contenant un ensemble de nom. Lorsque que l'on double click sur un nom, plusieurs autres champs du formulaire se mettent à jour et affichent différentes informations correspondant à la sélection.

Jusque là tout marche très bien...
Je coince sur un champ bien précis, j'aimerai que ce champ aille cherche sa valeur dans une requête existante, malheuresement cela ne fonctionne pas.

Voilà où j'en suis :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Private Sub lstDroite_DblClick(Cancel As Integer)
    Dim db As DAO.Database, rst As DAO.Recordset, fld As DAO.Field
    Dim sSQL As String
 
    Me.TXT_ID.Value = Me.lstDroite.Column(0)
    Me.TXT_NOM.Value = Me.lstDroite.Column(1)
    Me.TXT_PRENOM.Value = Me.lstDroite.Column(2)
    Me.TXT_COM.Value = Null
 
' c'est là que ça coince.
 
    sSQL = "SELECT EMP_ID, SommeDePOINT_HEURE, POINT_DATE From HEURES_POINTAGES WHERE EMP_ID = " & Me.TXT_ID & " AND POINT_DATE = " & Me.TXT_DATE & ";"
    DoCmd.RunSQL sSQL
 
' je suppose que je dois récupérer la valeur dans une variable, mais je ne vois ' pas comment faire.
 
End Sub

J'aimerai que le champ : Me.TXT_HEURESP affiche la somme des heures correspondant à la sélection. Auriez-vous des suggestions?

Merci d'avance

[aba_tarn]

essaie ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
sSQL = "SELECT EMP_ID, SommeDePOINT_HEURE, POINT_DATE From HEURES_POINTAGES WHERE EMP_ID = '" & Me.TXT_ID & "'"
sSQL= sSQL &" AND POINT_DATE = '" & Me.TXT_DATE & "'"

normalement ça devrait marcher

[Pwouaro]

Merci pour ta réponse.

En fait, ce que je voudrais c'est récupérer le résultat dans une variable pour attribuer la valeur de la variable au champ texte qui va bien.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
sSQL = "SELECT EMP_ID, SommeDePOINT_HEURE, POINT_DATE From HEURES_POINTAGES WHERE EMP_ID = '" & Me.TXT_ID & "'"
sSQL = sSQL & " AND POINT_DATE = '" & Me.TXT_DATE & "'"
 
    res = DoCmd.Execute(sSQL)
    Me.TXT_HEURESP.Value = res

Voilà ce que j'ai modifié, mais ça m'en dit pas plus.
Auriez-vous une idée?

[tribaleur]

il faut passé par un RecordSet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
dim RS_Som_Heure As ADODB.RecordSet 'permet d'exécuter des requetes de type SELECT
Dim sSQL As String 'Contient les requetes SQL
Dim CON_Connex as ADODB.Connection 'Permet d'établr une liason avec la BD
 
'on ouvre la connection à la base de données
Set CON_Connex = CurrentProject.Connection
'on initialise le RS
Set RS_Som_Heure = new ADODB.RecordSet
'on initialise la requette sql
sSQL = "SELECT SommeDePOINT_HEURE From HEURES_POINTAGES WHERE EMP_ID = '" & Me.TXT_ID & "'"
sSQL = sSQL & " AND POINT_DATE = '" & Me.TXT_DATE & "'"
 
'on ouvre le RS et on execute la requette
RS_Som_Heure.Open sSQL, CON_Connex, adOpenStatic,adLockOptimistic 
 
'on vérifie qu'il y ai des enregistrements
if(RS_Som_Heure.RecordCount > 0 ) then
  'on ce déplace sur le premier enregistrement
  RS_Som_Heure.MoveFirst
  'on affect le résultat au champ
  Me.TXT_HEURESP.Value = RS_Som_Heure("SommeDePOINT")
else
   msgbox"Aucun somme trouvé pour cette date et cet ID"
endif
 
'on ferme le RS
RS_Som_Heure.close
Set RS_Som_Heure = nothing
'on ferme la connection à la BD
Set CON_Connex = nothing

C'est un truc du genre qu'il faut faire je pense...en éspérant(???) t'aider!!

[Pwouaro]

Merci tribaleur, c'est exactement ce que je recherche.

J'ai tout de même un probleme avec le format de date (à mon avis). Access me renvoit une erreur d'exécution :

"Type de données incompatible dans l'expression du critère"

Le deboggeur m'affiche cette ligne en jaune:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
'on ouvre le RS et on execute la requette
RS_Som_Heure.Open sSQL, CON_Connex, adOpenStatic, adLockOptimistic

[tribaleur]

Si ton champ "Point_Date" est de type Date/heure il faut entouré ta valeur par des # :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

POINT_DATE = #" & Me.TXT_DATE & "#"

Tu peu même éventuellement formater ta valeur
Ex :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

POINT_DATE = #" & Format(Me.TXT_DATE, "mm/dd/yyyy") & "#"

=>/!\ J'ai mis au format mois/jour/année car dans les requetes SQL il inverse les mois et les jours sinon. Cependant ça te renverra bien les date en format français. Ex Si tu à TXT_Date = "01/10/2008", ça prendra les dates "01/10/2008" dans la BD. Si tu met au format "dd/mm/yyyy" avec la même valeur pour TXT_date ça prendra les date "10/01/2008" dans la BD.
J'ai pas bien compris pourquoi ça fait ça donc je pourrai pas t'expliquer.

P.S : la ligne jaune est celle du RS car c'est un problème d'éxécution de la requete donc comme c'est le RS qui éxécute les instruction SQL c'est lui qui génère une erreur (enfin je l'ai toujours interprété comme ça )

[Pwouaro]

Le message d'erreur à changé :

Aucune valeur donnée pour un ou plusieurs paramètre requis.

J'ai ajouté deux msgbox pour voir si le code renvoie les bonnes valeurs et c'est le cas.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
    'on ouvre la connection à la base de données
        Set CON_Connex = CurrentProject.Connection
    'on initialise le RS
        Set RS_Som_Heure = New ADODB.Recordset
    'on initialise la requette sql
        sSQL = "SELECT EMP_ID.HEURES_POINTAGES, SommeDePOINT_HEURE.HEURES_POINTAGES, POINT_DATE.HEURES_POINTAGES From HEURES_POINTAGES WHERE EMP_ID.HEURES_POINTAGES = '" & Me.TXT_ID & "'"
        sSQL = sSQL & " AND POINT_DATE.HEURES_POINTAGES = #" & Me.TXT_DATE & "#;"
    MsgBox Me.TXT_DATE.Value
    MsgBox Me.TXT_ID.Value
    'on ouvre le RS et on execute la requette
        RS_Som_Heure.Open sSQL, CON_Connex, adOpenStatic, adLockOptimistic
 
    'on vérifie qu'il y ai des enregistrements
        If (RS_Som_Heure.RecordCount > 0) Then
    'on ce déplace sur le premier enregistrement
         RS_Som_Heure.MoveFirst
    'on affect le résultat au champ
            Me.TXT_HEURESP.Value = RS_Som_Heure("SommeDePOINT_HEURE")
        Else
            Me.TXT_HEURESP.Value = "0"
        End If

[tribaleur]

Essaie d'afficher ta requete pour vérifier si la syntaxe final est bonne.

Au pire tu essaie une requette en mettant manuellement des valeur à la place de tes champs texte pour voir où ça bug.

P.S : pour mettre au format 23h59 le masque de saisi est "Hh:Nn".

[mathieu44800]

Bonjour,

je ne sais pas si tu as copié collé le code, mais je serais toi je mettrait un .Value

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6

sSQL = "SELECT EMP_ID.HEURES_POINTAGES, SommeDePOINT_HEURE.HEURES_POINTAGES, POINT_DATE.HEURES_POINTAGES From HEURES_POINTAGES WHERE EMP_ID.HEURES_POINTAGES = '" & Me.TXT_ID & "'"
        sSQL = sSQL & " AND POINT_DATE.HEURES_POINTAGES = #" & Me.TXT_DATE & "#;"
    MsgBox Me.TXT_DATE.Value
    MsgBox Me.TXT_ID.Value

Ensuite, je metrait un CDate(Format(TextBox.Value), "DD/MM/YYYY"))

A+

[Pwouaro]

Youpi ça marche

Essaie d'afficher ta requete pour vérifier si la syntaxe final est bonne.

Au pire tu essaie une requette en mettant manuellement des valeur à la place de tes champs texte pour voir où ça bug.

P.S : pour mettre au format 23h59 le masque de saisi est "Hh:Nn".

J'ai changé de requête, je l'ai créé avec l'assistant, puis copié/collé dans l'éditeur de code. Ca tourne bien maintenant.

Je vous met le code final quand même, ainsi qu'un petit tag résolu.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private Sub lstDroite_DblClick(Cancel As Integer)
    Dim RS_Som_Heure As ADODB.Recordset 'permet d'exécuter des requetes de type SELECT
    Dim sSQL As String 'Contient les requetes SQL
    Dim CON_Connex As ADODB.Connection 'Permet d'établr une liason avec la BD
 
    Me.TXT_ID.Value = Me.lstDroite.Column(0)
    Me.TXT_NOM.Value = Me.lstDroite.Column(1)
    Me.TXT_PRENOM.Value = Me.lstDroite.Column(2)
    Me.TXT_COM.Value = Null
 
 
    'on ouvre la connection à la base de données
        Set CON_Connex = CurrentProject.Connection
    'on initialise le RS
        Set RS_Som_Heure = New ADODB.Recordset
    'on initialise la requette sql
        sSQL = "SELECT EMPLOYE.EMP_ID, Sum(POINTAGE.POINT_HEURE) AS SommeDePOINT_HEURE, POINTAGE.POINT_DATE FROM EMPLOYE INNER JOIN POINTAGE ON EMPLOYE.EMP_ID = POINTAGE.EMP_ID GROUP BY EMPLOYE.EMP_ID, POINTAGE.POINT_DATE HAVING (((EMPLOYE.EMP_ID)= " & Me.TXT_ID & ") AND ((POINTAGE.POINT_DATE)=#" & Me.TXT_DATE & "#));"
 
    MsgBox Me.TXT_DATE.Value
    MsgBox Me.TXT_ID.Value
    'on ouvre le RS et on execute la requette
    RS_Som_Heure.Open sSQL, CON_Connex, adOpenStatic, adLockOptimistic
 
    'on vérifie qu'il y ai des enregistrements
        If (RS_Som_Heure.RecordCount > 0) Then
    'on ce déplace sur le premier enregistrement
         RS_Som_Heure.MoveFirst
    'on affect le résultat au champ
            Me.TXT_HEURESP.Value = RS_Som_Heure("SommeDePOINT_HEURE")
        Else
            Me.TXT_HEURESP.Value = "0"
        End If
 
    'on ferme le RS
        RS_Som_Heure.Close
        Set RS_Som_Heure = Nothing
    'on ferme la connection à la BD
        Set CON_Connex = Nothing
 
End Sub

@mathieu

En effet les msgbox fonctionnent mieux avec ".Value" ^^'

Merci à tous!