Discussion :

[mnssylvain]

bonjour,

j'ai composé à l'aide du forum un code pour supprimer les fichier ancien d'un dossier.

Le problème c'est que ma condition if ne marche pas comme il le faudrait.

il me suprime des fichiers ancien (c ce qu'on lui demande)
mais
il me supprime par exemple un fichier que je viens de creer à l'instant
il ne me suprime pas certain fichiers anciens.

voici le code en question

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Dim rs As DAO.Recordset
Set rs = CurrentDb.OpenRecordset("Paramètres", dbOpenDynaset)
 
Dim fs As New Scripting.FileSystemObject
Set fs = CreateObject("Scripting.FileSystemObject")
 
Dim objShell As Shell32.Shell
    Dim strFileName As Shell32.FolderItem
    Dim objFolder As Shell32.Folder
    Dim Resultat As String
    Dim streparchive As String
    Dim i As Byte
 
    streparchive = rs!Repsauvarchive
 
 
 
    Set objShell = CreateObject("Shell.Application")
    'Répertoire cible
    Set objFolder = objShell.nameSpace(streparchive)
 
 
    'boucle sur tous les elements du repertoire
    For Each strFileName In objFolder.Items
 
        'Pour que les dosssiers ne soient pas pris en comptes
        If strFileName.isFolder = False Then
        Resultat = ""
           ' For i = 0 To 2
        MsgBox (streparchive & strFileName)
         MsgBox FileDateTime(streparchive & strFileName)
      ' donne la date du fichier
      MsgBox (CStr(Year(Now()) - 5))
 
 
                If FileDateTime(streparchive & strFileName) < CStr(Year(Now()) - 5) Then
 
fs.DeleteFile (streparchive & strFileName), True
 
Else
 
 End If
 
 
End If
Next
 
 
End Sub

les différentes msgbox me permmettent juste de controler le contenu de mes variables.
elles renvoient bien ce qui est attendu à savoir la date du fichier et la date - 5 ans.

Mais la condition est hasardeuse...

Merci de vérifier ce code pour me donner une éventuelle piste
merci à tous

[LedZeppII]

Bonjour,

Ton If compare une date avec une chaîne de caractère.

Voila un exemple (plus simple à mon goût) en VBA sans faire appel à des objets.
Ne boudons pas cette bonne vieille fonction Dir()

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Dim rs As DAO.Recordset
Set rs = CurrentDb.OpenRecordset("Paramètres", dbOpenDynaset)
 
    Dim Resultat As String
    Dim strRepArchive As String
    Dim strFileName As String
    Dim FileDT As Date, LimiteDT As Date
 
    strRepArchive = rs!Repsauvarchive
    If Right(strRepArchive, 1) <> "\" Then strRepArchive = strRepArchive & "\"
 
    LimiteDT = DateAdd("yyyy", -5, Date)
 
    strFileName = Dir(strRepArchive & "*.*")
    Do While strFileName <> ""
       FileDT = FileDateTime(strRepArchive & strFileName)
       If FileDT < LimiteDT Then
          MsgBox strFileName & "  " & Format(FileDT, "dd mm yyyy")
          'Kill strRepArchive & strFileName
       End If
       strFileName = Dir()
    Loop

A+

[mnssylvain]

t'es formidable LedZeppII

effectivement à quoi bon faire compliqué quand on peut faire simple

Ca marche nickel

MAis d'un point de vue théorique c'est quand meme bizare que mon code ne fonctionne pas non???

[LedZeppII]

J'ai fait quelques essais.
La fonction FileDateTime renvoie une donnée de type Variant/Date.
Dans ton code d'origine tu compares cette données avec "2002" (String).
La donnée Variant/Date est convertie en String pour effectuer la comparaison.
Je pense que c'est à cause du type Variant, car avec une donnée type Date c'est l'inverse qui se produit ("2002" est convertit en date -> 24/06/1905)

Lorsque le jour de la date de création/modif du fichier est entre 01 et 20 le If est toujours Vrai.
Par exemple "19/01/2007" < "2002" est Vrai.

Lorsque le jour de la date de création/modif du fichier est entre 21 et 31 le If est toujours Faux.
"25/01/2007" < "2002" est faux à cause du "5" en deuxième position.

Ton code fonctionne si tu remplace CStr(Year(Now()) - 5) par DateAdd("yyyy", -5, Date)

A+

[mnssylvain]

merci pour les explications

c'est très clair, je comprend mieux mantenant pourquoi ça ne marchait pas.
a+