Discussion :

[alsimbad]

ok wielfried. j'ai testé. tu devrais corrigé le

senkeys "{DOWN}",true

j'ai compris le principe. mais mais pour l'utilité, je reste septique. je ne vois pas comment cela peut renvoyer les coordonées de la ligne suivante, mais peut etre que je m'y prend mal. j'ai testé tout betement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub vvv()
Range("A1").Select
SendKeys "{DOWN}", True
While ActiveCell.Row <= Range("A65535").End(xlUp).Row
' tu effectues ton traitement sur la ligne de Activecell
SendKeys "{DOWN}", True
MsgBox ActiveCell
Wend
End Sub

et le message que j'ai sur chaque ligne c'est ce qu'il y a A1, à moins de passer par un truc genre l'incrementation d'une variable, je ne trouve pas cela tres pratique
. la formulation de pierre parait tout de même plus interressante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
For Each Cellule In Range("a1:a4").SpecialCells(xlCellTypeVisible)
        MsgBox Cellule
    Next Cellule

[wilfried_42]

re:

je n'ai jamais dis le contraire, mais notre ami désirait plusieurs formulations possibles du moins c'est ce que j'ai compris

Et finalement ce petit exercice, m'ouvre des possibilités auxquelles je n'avais pas penséés.

exemple : recherche d'un enregistrement unique avec multi-criteres Via les filtres automatiques, recuperation immediate de l'enregistrement avec uniquement un Sendkeys

Pour la faute de frappe: j'ai corrigé, merci bien

Cordialement
Wilfried

[thierryyyyyyy]

pour avoir les coordonnées de ta cellule active, il suffit d'un
"selection.row" et "selection.column"
ou "selection.address".

Merci pour le senkeys, ça aussi ça peut aider.

[zazaraignée]

N'oublies pas de cliquer sur

[Pierre Fauconnier]

Bonjour

Petite fonction perso qui permet de décaler en tenant compte des cellules visibles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Function DecalerCellulesVisibles(CelluleDepart As Range, Optional Lignes As Long = 0, Optional Colonnes As Long = 0) As Range
    Dim i As Long
    Dim Cellule As Range
 
    On Error GoTo Fin
 
    Set Cellule = CelluleDepart
    Do While i < Abs(Lignes)
        If Lignes > 0 Then Set Cellule = Cellule(2) Else Set Cellule = Cellule(0)
        If Not Cellule.EntireRow.Hidden Then i = i + 1
    Loop
 
    i = 0
    Do While i < Abs(Colonnes)
        If Colonnes > 0 Then Set Cellule = Cellule(1, 2) Else Set Cellule = Cellule(1, 0)
        If Not Cellule.EntireColumn.Hidden Then i = i + 1
    Loop
 
Fin:
    If Err = 0 Then
        Set DecalerCellulesVisibles = Cellule
        Else
        Set DecalerCellulesVisibles = Nothing
    End If
End Function

Ok?

[Pierre Fauconnier]

Swiper,

Si ceci peut t'aider pour retrouver les x valeurs non masquées d'une plage filtrée... (il y a peut-être plus simple...)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
Function SelectionnerXLignesVisibles(NbreLignes As Long) As Collection
    Dim Cellule As Range
    Dim i As Long ' compteur de boucle
    Dim ColLignes As New Collection
 
    Set Cellule = Range("a65536").End(xlUp)
    ColLignes.Add Cellule.Row
    Do While i < NbreLignes - 1
        Set Cellule = DecalerCellulesVisibles(Cellule, -1)
        If Not Cellule Is Nothing Then
            ColLignes.Add Cellule.Row
            i = i + 1
            Else
            Exit Do
        End If
    Loop
    Set SelectionnerXLignesVisibles = ColLignes
End Function
 
Sub AfficherCellules()
    Dim ColLignes As Collection
    Dim i As Long
 
    Set ColLignes = SelectionnerXLignesVisibles(50)
    For i = 1 To ColLignes.Count
        Debug.Print Range("a" & ColLignes(i))
    Next i
End Sub

La procédure AfficherCellules utilise une collection renvoyée par la fonction SelectionnerXLignesVisibles qui elle-même utilise la fonction DecalerCellulesVisibles que j'ai donnée dans une précédente réponse.

Cet exemple montre l'utilisation d'une collection, plus facile à manier qu'un tableau redimensionné.

Ok?

[Swiper]

Ô Grand Pierre, je m'incline...

Mais je reviens dans 1 ou 2 jours le temps de comprendre réellement le pourquoi du comment. ^^

Merci parce que je sais que tu t'es comme même pris la tête.