Discussion :

[XineMA]

Bonjour tlm,

j'ai utilisé le code de cette contribution pour importer mais j'ai un petit soucis :

voila le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.VBE.VBProjects(i).VBComponents.Import ("c:\data\Cls\thisWorkbook.cls")

ou i = 2 ce qui est OK

Et le résultat est la création d'une classe s'appelant thisworbook1

j'aimerais importer du code dans la feuille Thisworkbook et non créér une classe

Merci de m'aider

Xine

[SilkyRoad]

bonjour

tu peux tester cette procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
'Nécessite d'activer la référence
'Microsoft Visual Basic for Applications Extensibility 5.3
Dim Wb As Workbook
Dim oModule As CodeModule
Dim VbComp As VBComponent
Dim x As Integer
Dim Cible As String
 
Cible = "NomModule"
'Définit le classeur de destination
Set Wb = ThisWorkbook
 
'Charge le module temporaire dans la classeur
Set VbComp = Wb.VBProject.VBComponents.Import("C:\ThisWorkbook.cls")
'Le renomme (pour le supprimer plus facilement ultérieurement)
VbComp.Name = Cible
 
Set oModule = VbComp.CodeModule
 
'Transfère les données 
'Attention les données existantes dans "ThisWorkbook" sont écrasées.
With Wb.VBProject.VBComponents("ThisWorkbook").CodeModule
    x = .CountOfLines
    .DeleteLines 1, x
    .InsertLines 1, oModule.Lines(1, oModule.CountOfLines)
End With
 
'Suppression du module temporaire
With Wb.VBProject.VBComponents
    .Remove .Item(Cible)
End With

bonne soirée
michel

[XineMA]

Merci de ta réponse SilkyRoad, ca fonctionne à merveille.