Discussion :

[973thom]

Bonjour,

avec l'aide de la faq j'essai de désactiver le bouton fermer d'un formulaire (la petite croix) si un autre formulaire est ouvert.

Ainsi j'ai écrit ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Public Function is_form_opened(fname As String) As Boolean
Dim LeFichier As String
 
On Error GoTo not_opened
 
    LeFichier = Forms(fname).Name
    is_form_opened = True
Exit Function
not_opened:
 
    If (Err.Number = 2450) Then
        is_form_opened = False
        Err.Clear
    End If
End Function
 
Private Sub Form_Open(Cancel As Integer)
 
	If is_form_opened("frm_recherche") = True Then
   	 Me.Form.CloseButton = False
	End If
 
End Sub

Cependant j'obtiens le message d'erreur suivant :

"impossible d'attribuer une valeur à cet objet"

Pouvez vous m'aider SVP

Merci d'avance

thomas

[120]

ou se situe ton erreur?

[snoopy69]

Bonjour ... j'ai peut être une solution.

Tu aimerais en fait enlever la petite croix en haut à droite de ton formulaire ???

Si c'est le cas, tu peux aller dans les propriétés de ton formulaire ( MODE CREATION / CLIQUE DROIT SUR LE COIN EN HAUT A GAUCHE / PROPRIETE ) une nouvelle fenêtre va s'ouvrir et dans cette fenêtre il te faut mettre non à côté de : Affichage fermer ( je ne suis plus sur que cela s'appel comme cela )

Si par contre tu veux absolument le faire en VBA là je ne peux pas t'aider ...

A tout bientôt ...

[973thom]

Bonjour à tous

ben en fait il faut absolmument que je le fasse en VBa car il faut que la croix "fermer le formulaire" soit désactiver lorsqu'un autre formulaire est actif.

ou se situe ton erreur?

Et mon erreur se situe justement dans le cas où ce second formulaire est actif... j'obtiens alors le message d'erreur précité ...


merci

thomas

[120]

je crois que ton erreur se déclenche car tu essaies de changer une propriété du formulaire alors que celui ci n'est pas encore ouvert...
essaie de mettre ton code dans le form_activate

[120]

Vous ne pouvez définir la propriété BoutonFermer (CloseButton) qu'en mode Création de formulaire.

[ARO]

Bonjour,

Extrait de l'aide access :

Vous ne pouvez définir la propriété BoutonFermer (CloseButton) qu'en mode Création de formulaire.

[973thom]

à bon ....

bon ben je suis encore grillé sur ce coup là ...

@ +++ et merci de t'être penché sur mon pb

[ARO]

Bonjour,

Ce code pourrait d'aider.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Private Sub Form_Open(Cancel As Integer)
 
   If is_form_opened("frm_recherche") = True Then
      ShowSystemMenu Me, False
   End If
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
Option Compare Database
Option Explicit
 
Private Declare Function SendMessage Lib "user32" _
 Alias "SendMessageA" _
 (ByVal hwnd As Long, ByVal wMsg As Long, _
 ByVal wParam As Long, ByVal lParam As Long) As Long
 
Private Declare Function GetWindowLong Lib "user32" _
 Alias "GetWindowLongA" (ByVal hwnd As Long, _
 ByVal nIndex As Long) As Long
 
Private Declare Function SetWindowLong Lib "user32" _
 Alias "SetWindowLongA" (ByVal hwnd As Long, _
 ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
 
' GetWindowLong Constant
 
Private Const GWL_STYLE = -16
Private Const WS_SYSMENU = &H80000
Private Const WM_NCPAINT = &H85
 
 
Public Sub ShowSystemMenu(frm As Form, ShowIt As Boolean)
    On Error GoTo HandleErrors
    Dim lngOldStyle As Long
    Dim lngNewStyle As Long
 
     ' Get the current window style of the form.
    lngOldStyle = GetWindowLong(frm.hwnd, GWL_STYLE)
 
    If ShowIt Then
    ' Turn on the bit that enables system menu.
    lngNewStyle = lngOldStyle Or WS_SYSMENU
    Else
    ' Turn off the bit the shows the system menu.
    lngNewStyle = lngOldStyle And Not WS_SYSMENU
    End If
 
    ' Set the new window style.
    Call SetWindowLong(frm.hwnd, GWL_STYLE, lngNewStyle)
 
    ' The 1 as the third parameter tells
    ' the window to repaint its entire border.
    Call SendMessage(frm.hwnd, WM_NCPAINT, 1, 0)
 
ExitHere:
    Exit Sub
 
HandleErrors:
    Resume ExitHere
End Sub

[973thom]

ok,

merci beaucoup

je regarde celà tout de suite...

@ ++

[973thom]

Merci beaucoup ARO !!!

Je ne comprends pas tout mais pour le moment cela fonctionne parfaitement et je n'ai plus de problème de navigation entre mes formulaires.

Bonne soirée

thomas