Discussion :

[Stephane_123]

Hello,

J'ai un problème avec ma boucle qui est supposée passer en revue toutes les lignes d'une table Access "Weights1". Voilà le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
   ...  
    Set Rst = db.OpenRecordset("Weights1", dbOpenTable)
    Rst.MoveFirst
    Do While Not Rst.EOF
 
    Worksheets(sheet).Range("A2").CopyFromRecordset Rst
        Calculate
        temp = Cells(3, 14).Value & ";" & Cells(3, 15).Value & ";" & Cells(3,16).Value & _
        ";" & Cells(3, 17).Value
 
    Write #iFileNum, temp
 
    Rst.MoveNext    
    Loop
...

Donc le code fonctionne correctement jusqu'à Rst.MoveNext puis bug en précisant 'aucun enregistrement'. Je dois dire que je suis coincé, merci pour vos réponses.

[Invité]

Une question peut-être stupide, mais bon
Dans ta table "Weights1", tu as bien plusieurs lignes d'enregistrements ?

A+

[Stephane_123]

oui oui

En fait le problème vient de la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Worksheets(sheet).Range("A2").CopyFromRecordset Rst

Il semble que, après avoir calculer dans la Worksheet, l'enregistrement est effacé en sorte que le programme quitte la boucle.

J'ai voulu faire la manip suivante avec une nouvelle variable Rst2 mais là, il ne compile plus:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
...
dim Rst2 As DAO.Recordset
dim rst as DAO.Recordset
...
Set Rst = db.OpenRecordset("Weights1", dbOpenDynaset)
    'Set Rst = db.OpenRecordset("Weights1", dbOpenForwardOnly, dbReadOnly,dbOpentable)
    Rst.MoveFirst
 
    Do
        Rst = Rst2
        Worksheets(sheet).Range("A2").CopyFromRecordset Rst2
        Calculate
        temp = Cells(3, 14).Value & ";" & Cells(3, 15).Value & ";" & Cells(3, 16).Value & _
        ";" & Cells(3, 17).Value
 
    Write #iFileNum, temp
 
    Rst.MoveNext
 
    Loop Until Rst.EOF

Il n'aime pas le Rst = Rst2

[Invité]

Combien de champ as-tu dans ta table ?

Peux tu donner un peu plus de code, pour vérifier si tu déclare comme il faut tous tes objets, ainsi que l'instance Access !?

A+

[Stephane_123]

Ok voilà le code en entier. Pour la table access c'est variable, mais disons 10^6 lignes environs.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
'Chope des poids dans Access, calcule les stats dans Excel et insrcrit les résultats
'dans un fichier JUNK.txt avec ";" comme séparateur
 
Option Explicit
Const ML_PATH = "C:bd1.mdb"
Const sheet = "Sheet_PF"
 
Sub optimweightsPF_txt_do()
 
    Dim db As DAO.Database, Rst As DAO.Recordset
    Dim sst As DAO.Recordset, Rst2 As DAO.Recordset
    Dim oAccesS As Access.Application
    Dim request As String
    Dim sSQL As String
    Dim temp As String
    Dim strDestFile As String
    Dim iFileNum As Long
 
    ' Ouverture de la base de données
    'creation d'une instance Access par automation
    Set oAccesS = CreateObject("Access.Application")
 
    'chargement de la BDD
    oAccesS.OpenCurrentDatabase ML_PATH
 
    'affectation d'une référence à la BDD
    Set db = oAccesS.CurrentDb
 
    Application.ScreenUpdating = False
 
    strDestFile = "c:JUNK.txt"
 
    iFileNum = FreeFile
 
    Open strDestFile For Output As #iFileNum
 
    Set Rst = db.OpenRecordset("Weights1", dbOpenDynaset)
    Rst.MoveFirst
 
    Do
        Rst = Rst2
        Worksheets(sheet).Range("A2").CopyFromRecordset Rst2
        Calculate
        temp = Cells(3, 14).Value & ";" & Cells(3, 15).Value & ";" & Cells(3, 16).Value & _
        ";" & Cells(3, 17).Value
 
    Write #iFileNum, temp
 
    Rst.MoveNext
 
    Loop Until Rst.EOF
 
    'Next i
 
    Close #iFileNum
 
    Rst.Close
    Set db = Nothing
    Set oAccesS = Nothing
 
 
    MsgBox ("Execution terminée")
 
End Sub

[Invité]

Ca y est, j'ai compris :yes:

En fait l'instruction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Rst = db.OpenRecordset("Weights1", dbOpenDynaset)

récupère l'ensemble des enregistrements de la table,
si tu regardes bien,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets(sheet).Range("A2").CopyFromRecordset Rst

Colle dans ta feuille toutes les lignes et pas une seule !
Donc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Rst.MoveNext

ne sert qu'à te créer une erreur
puisque tu as déjà tout récupéré !

Je pense que le mieux est alors de faire une boucle sur chaque cellule
de ta feuille, contenant une valeur, et d'écrire à ce moment là ton fichier texte !

Essayes cà :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
'Chope des poids dans Access, calcule les stats dans Excel et insrcrit les résultats
'dans un fichier JUNK.txt avec ";" comme séparateur
 
Option Explicit
Const ML_PATH = "C:\bd1.mdb"
Const sheet = "Sheet PF"
 
Sub optimweightsPF_txt_do()
 
    Dim db As DAO.Database, Rst As DAO.Recordset
    Dim sst As DAO.Recordset, Rst2 As DAO.Recordset
    Dim oAccesS As Access.Application
    Dim request As String
    Dim sSQL As String
    Dim temp As String
    Dim strDestFile As String
    Dim iFileNum As Long
 
    ' Ouverture de la base de données
    'creation d'une instance Access par automation
    Set oAccesS = CreateObject("Access.Application")
 
    'chargement de la BDD
    oAccesS.OpenCurrentDatabase ML_PATH
 
    'affectation d'une référence à la BDD
    Set db = oAccesS.CurrentDb
 
    'Application.ScreenUpdating = False
 
    strDestFile = "c:\JUNK.txt"
 
    iFileNum = FreeFile
 
    Open strDestFile For Output As #iFileNum
 
    Set Rst = db.OpenRecordset("Weights1", dbOpenDynaset)
    Rst.MoveFirst ' Pourquoi pas
    Worksheets(sheet).Range("A2").CopyFromRecordset Rst
    Calculate
    Dim Cel As Range
    For Each Cel In Sheets(sheet).Range("A2:A" & Range("A65535").End(xlUp).Row)
      temp = Cells(Cel.Row, 14).Value & ";" & Cells(Cel.Row, 15).Value & ";" & Cells(Cel.Row, 16).Value & _
        ";" & Cells(Cel.Row, 17).Value
      Write #iFileNum, temp
    Next
    Close #iFileNum
 
    Rst.Close
    db.Close
    Set db = Nothing
    oAccesS.CloseCurrentDatabase
    Set oAccesS = Nothing
 
    MsgBox ("Execution terminée")  
End Sub

Voilà