Discussion :

[facteur]

Bonjour
je ne parviens pas a résoudre un problème . je me retourne donc vers vous

J'ai un tableau Excel avec plusieurs colonnes et je souhaiterais créer sous VB Excel, la formule SOMME.SI.ENS pour afficher des sommes avec plusieurs critères.
Et pour cela, je pensais utiliser le select case . Je sais créer des select case avec plusieurs conditions mais là ou je bloque c'est de créer une SOMME.Si avec des selects case.

Par exemple. si on se réfère au petit tableau ci dessous:
je souhaiterais avoir dans une cellule, la somme des nombre dont le critère dans la colonne "CODE" sera 1111 et le critère dans la colonne "lettres serait B".
J'avais commencé ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
sub test ()
Dim i As Long
Dim code as string
Dim Lettes as string

code=Cells(i,1)
lettres=Cells(1,2)

Select Case code
    Case 111
        Select Case lettres
            Case Is = "A"

reste du code a créer 

..........


end sub

[sabot'age]

Bonjour,

Select Case c'est plutot comme SI.MULTIPLE/SWITCH. Pas pour les conditions multiples.

Avant d'analyser les cellules, pour faire une somme il faut dans un premier temps parcourir le tableau.
On commence donc par une boucle For. On va boucler sur chaque ligne puisqu'il y a des informations à récupérer dans plusieurs colonnes.
Ensuite, pour chaque ligne, on peut faire un Select Case pour additionner, ou non, les valeurs. Mais c'est bizarre. Il vaut mieux définir en amont les conditions, et utiliser un simple If : plus versatile et moins de code nécessaire.

Ainsi, une manière plus simple de faire une somme.si est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public Sub Exemple()
  Dim myData As Variant
  With ThisWorkbook.Worksheets(1).Range("A2")
    myData = Range(.Cells, .End(xlToRight).End(xlDown)).Value2
  End With
 
  ' definition des criteres de la somme
  Dim codeCriteria As Long: codeCriteria = 111
  Dim lettCriteria As String: lettCriteria = "A"
  ' parcours des lignes du tableau
  Dim i As Long, somme As Double
  For i = LBound(myData, 1) To UBound(myData, 1)
    ' verification des conditions
    If myData(i, 1) = codeCriteria And myData(i, 2) = lettCriteria Then
      ' addition
      somme = somme + myData(i, 3)
    End If
  Next i
 
  ' resultat
  Debug.Print somme
End Sub

[BENNASR]

Bonjour
je ne suis pas certain que j'ai compris la demande mais somme.si.ens en VBA Application.WorksheetFunction.SumIfs :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub test()
Dim F As Worksheet
Set F = Sheets("Feuil2")
F.Range("F5").Value = Application.WorksheetFunction.SumIfs(F.Range("C2:C15"), F.Range("B2:B15"), "A", F.Range("A2:A15"), "111")
End Sub

[deedolith]

Hello,

Principe KISS (Keep It Simple and Stupid), Application.WorksheetFunction.SumIfs() est ton amie.
Exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Dim criteria1 As Long
criteria1 = 111
 
Dim Criteria2 As String
Criteria2 = "B"
 
Dim Result As Double
Result = Application.WorksheetFunction.SumIfs(Range("C2:C11"), Range("A2:A11"), criteria1, Range("B2:B11"), Criteria2)
 
Debug.Print Result

Pourquoi faire compliqué quand on peut faire simple ?

[Nain porte koi]

Pourquoi faire compliqué quand on peut faire simple ?

A cause des shadocks

[Valtrase]

Bonjour à tous,

Application.WorksheetFunction.SumIfs() est ton amie.

C'est clair, et pour allez plus loin et sur certaines versions d'Excel utiliser la fonction filtre qui pourras renvoyer bien plus que la somme.

Bonne programation.

[facteur]

Merci à tous pour vos réponse.
ca marche a merveille

[tototiti2008]

Bonjour,

Plutôt

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
    If myData(i, NumCol_critere1) = critère1 _
        And myData(i, NumCol_critere2) = critere2 _
        And myData(i, NumCol_critere3) <> critere3 _
        And myData(i, critere4) = critere4 Then
        somme_client = somme_client + myData(i, NumCol_Nombre)
    End If
End Sub

S'il y a un End If, alors les actions doivent être à la ligne après le Then

[facteur]

Merci à vous deux tototiti2008 et BENNASR .
Je cloture la discussion