GIF animé dans UserForm

**JulieD33** · 17/04/2015, 11h50

Bonjour le forum,

Je me tourne vers vous pour tenter d'optimiser un code que j'ai mis en place à partir de ce tuto :

http://silkyroad.developpez.com/VBA/ExcelImageGIF/

Ce code consiste à stocker une image gif puis de la visualiser. J'ai donc dans un premier temps stocké mon image gif en binaire dans une feuille excel puis j'ai supprimer le code qui m'a permis de faire ça puisque je n'en ai plus besoin une fois que l'image est stockée dans mon fichier.

Ensuite, j'ai suivi à la lettre le tuto en l'adaptant à mon besoin c'est à dire faire apparaître le gif animé dans un userform à partir d'une condition sur 2 de mes cellules.

Tout fonctionne très bien à un détail près.. le gif met 20 secondes pour s'afficher ce qui est énorme !!

Je sais que stocker l'image n'est pas des plus "léger" mais mon fichier sera utilisé par plusieurs ordinateurs différents et en réseau ce qui m'oblige à stocker l'image dans le fichier.

Au début mon image était créée sur le disque C et elle mettait environ 3s pour s'afficher puis j'ai du changer le lien pour lui dire de se créer dans le répertoire du fichier excel, qui se trouve sur le réseau et la catastrophe 20s!

Y'a t-il un moyen d'optimiser le code pour rendre plus rapide l'apparition du gif ou est-ce simplement un problème de réseau?

Je vous joins un fichier test qui récapitule mon problème. J'espère avoir été claire dans mes explications.

Merci d'avance pour votre aide.

Julie

**mercatog** · 17/04/2015, 13h24

Essaie ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Private Sub UserForm_Initialize()
Dim i As Long, k As Long, P As Long, F As Long
Dim Hauteur As Long, Largeur As Long
Dim S As String
Dim j As Integer
Dim B() As Byte
Dim Tb
 
With ThisWorkbook.Worksheets("GIF").UsedRange
    Tb = .Value
    P = .Count
End With
 
ReDim Preserve B(1 To P)
For i = 1 To UBound(Tb, 1)
    For j = 1 To UBound(Tb, 2)
        k = k + 1
        B(k) = Tb(i, j)
    Next j
Next i
 
F = FreeFile
S = ThisWorkbook.Path & "\imageTemp.gif"
Open S For Binary Access Write As F
Put #F, , B
Close F
 
With Me.WebBrowser1
    Largeur = .Width * 96 / 72
    Hauteur = .Height * 96 / 72
    .Navigate _
        "ABOUT:<HTML><CENTER><HEAD><body scroll='no' LEFTMARGIN=0 TOPMARGIN=0><IMG WIDTH=" _
        & Largeur & " HEIGHT=" & Hauteur & " SRC='" & S & _
        "'</IMG></BODY></CENTER></HTML>"
End With
End Sub

**JulieD33** · 17/04/2015, 13h43

Ah super ça fonctionne

Merci infiniment!

Julie

**salseropom** · 25/12/2024, 19h16

Merci beaucoup pour vos partages. C'est nickel !!

GIF animé dans UserForm [XL-2007]

Macros et VBA Excel

Vue hybride

Discussions similaires

Partager

Partager