Discussion :

[kodyone]

Salut à tous.
Je suis sur un projet et en tant que débutant sur Excel VBA, il y'a certaines choses que je n'arrive pas à faire. C'est pourquoi j'ai fait un fichier exemple pour mieux vous présentez mon besoin.
Dans mon classeur joint, j'ai 4 feuilles : Impressions, Photocopies, Scans, Rapport.
Dans la feuille "Impression", il y'a la plage "plage1"
Dans la feuille "Photocopies", il y'a la plage "plage2"
Dans la feuille "Scans", il y'a la plage "plage3"

Je souhaite donc avec un code VBA sous forme d'un rapport à la fin de chaque mois, envoyé les données des 3 plages (plage1, plage2, plage3) dans la feuille Rapport selon l'ordre que j'ai faite dans cette feuille (Rapport)

Comment faire ?

[Philippe Tulliez]

Bonjour,
Pour copier une plage de cellules vers une autre plage, on utilise la méthode Copy de l'objet Range en utilisant son argument Destination
En supposant que vous ayez nommé la plage 1 "PlageImpression" à l'aide du gestionnaire des noms et que la première cellule de la plage à coller dans la feuille nommée "Rapport" est la cellule C5

Le code sera par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub t()
  With ThisWorkbook
   Range("PlageImpression").Copy Destination:=.Worksheets("Rapport").Range("B3")
  End With
End Sub

Exemple pour copier 3 plages nommées vers 3 adresses cibles de la feuille nommée Rapport

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub t()
  Dim s As Variant
  Dim t As Variant
  Dim e As Byte
  s = Array("PlageImpression", "PlagePhotocopie", "PlageScan") ' Nom des plages sources
  t = Array("C5", "C20", "C35")                                ' Adresse des premières cellules cibles
  With ThisWorkbook.Worksheets("Rapport")
   For e = 0 To UBound(s)
     Range(s(e)).Copy Destination:=.Range(t(e))
   Next
  End With
End Sub

[kodyone]

Bonjour

Philippe Tulliez

Merci beaucoup pour votre contribution.
Avant tout, j'ai essayé votre code en utilisant mes données comme Ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
Sub t()
  Dim s As Variant
  Dim t As Variant
  Dim e As Byte
  s = Array("plage1", "plage2", "plage3") ' Nom des plages sources
  t = Array("B5", "B20", "B35")           ' Adresse des premières cellules cibles
  With ThisWorkbook.Worksheets("Rapport")
   For e = 0 To UBound(s)
     Range(s(e)).Copy Destination:=.Range(t(e))
   Next
  End With
End Sub

Ça me renvoi un message d'erreur : "La méthode 'Range' le l'objet 'Worksheet' a échoué"

En plus, pour ce qui est des cellules cibles, je ne l'ai connais pas d'abord car comme c'est un travail mensuel, il se peut que la plage 1 "plage1" prenne beaucoup de lignes, avec la méthode de copie que vous avez donné, je voulais un alignement des plages comme suit :
La plage (plage1) est sur la celule ("B5")
La plage (plage2) est sur la dernière ligne+2 lignes de la plage (plage1)
Il en est de même de la plage (plage3) pour la plage (plage2)

[Philippe Tulliez]

Bonjour,

Ça me renvoi un message d'erreur : "La méthode 'Range' le l'objet 'Worksheet' a échoué"

Sans connaître le numéro de la ligne où a lieu le bug, il est difficile d'apporter de l'aide

En plus, pour ce qui est des cellules cibles, je ne l'ai connais pas d'abord car comme c'est un travail mensuel, il se peut que la plage 1 "plage1" prenne beaucoup de lignes, avec la méthode de copie que vous avez donné, je voulais un alignement des plages comme suit :
La plage (plage1) est sur la celule ("B5")
La plage (plage2) est sur la dernière ligne+2 lignes de la plage (plage1)
Il en est de même de la plage (plage3) pour la plage (plage2)

Si vous distillez vos informations au compte-gouttes, nous n'allons pas nous en sortir.
Dans ce cas, nul besoin de nommer les plages sources et, pour charger les données quel que soit le nombre de lignes du tableau, on utilisera la propriété CurrentRegion, qui est l'équivalent du raccourci clavier Ctrl + *.
Pour que cela fonctionne, il est nécessaire de conserver au minimum une ligne de titre commençant à la cellule définie par la constante a (ici B5) dans les feuilles sources.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub t()
  Const Ecart As Byte = 2  ' Nombre de ligne séparant les tableaux collés
  Const A As String = "B5" ' Adresse de la première cellule de chaque feuille
  Const TargetSheetName As String = "Rapport"
  Dim s As Variant
  Dim e As Byte
  Dim l As Variant
  Dim rng As Range
  s = Array("Impressions", "Photocopies", "Scans") ' Nom des feuilles
 
  With ThisWorkbook
  .Worksheets("Rapport").Cells.Clear ' Supprime les données
   For e = 0 To UBound(s)
     Set rng = .Worksheets(s(e)).Range(A).CurrentRegion
     With .Worksheets(TargetSheetName)
      If rng.Rows.Count > 1 Then
        rng.Copy Destination:=.Range(A).Offset(l)
        l = l + rng.Rows.Count + Ecart
      End If
     End With
   Next
  End With
  Set rng = Nothing
End Sub