Discussion :

[Patate3181]

Bonjour à tous,
Je viens vers vous car malgré une recherche de plus d'une heure et une demande à Chat GPT (Je sais c'est pas parfait mais je voulais essayer de voir une autre idée), je me retrouve toujours bloqué et je n'ai pas trouvé équivalent sur ce forum ou sur d'autres ...

Je contextualise mon problème :

J'ai une base de données extraite depuis un logiciel interne. Dans cette BDD, j'ai environ 8K lignes (Ce sont toutes les affaires de l'entreprise, donc cette base est amenée à évoluer). (Ci joint extrait photo de la base)


Dans cette base, on va retrouver le numéro d'affaire, le NDA et le cycle. le NDA représente une immatriculation de client, elle est donc propre à un et un seul client. Cependant, en fonction du cycle, on créé une nouvelle affaire.

Par exemple le client immatriculé sous le numéro 123456789 peut avoir deux affaire si il change de cycle


Dans l'exemple ci dessus, on voit bien que le même NDA possède 3 cycles différents et 3 numéros d'affaires.

Ce que je souhaite faire, c'est : Si le NDA est déjà présent alors supprimer TOUTES les lignes correspondantes. donc dans l'exemple en haut, les 3 lignes.

L'objectif de ce fichier est d'identifier les clients n'ayant pas encore pris contact avec nous et donc n'ayant qu'un seul cycle.

Je précise aussi que cette macro sera présente sur le PERSONAL.xlsb car il s'agit d'une extraction qu'ils devront réaliser tous les mois.

J'espère que ceci est compréhensible !

Le code que j'avais imaginé au début est quelque chose comme ça cependant il ne me semble ni optimisé ni ultra fonctionnel en vérité.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
For Each Cell In WsBdd.Range("B2:B" & DernLign).Cells
ValeurCherchee = Cell.value
 
For i = DernLign To 1 Step -1
    If Cells(i, 1).Value = ValeurCherchee Then
        Rows(i).Delete
    End If
Next i
Next Cell

Un grand merci d'avance hâte de vous lire !

[deedolith]

Dans l'exemple ci dessus, on voit bien que le même NDA possède 3 cycles différents et 3 numéros d'affaires.

Heu ...
S'il y a 3 lignes on en supprime 3,
S'il y a 2 lignes on en supprime 2,
S'il y a 1 ligne on en supprime 1,
Pas logique ton truc, on final on supprime tout.

Comment les données arrivent t'elles dans Excel ?
Fichier CSV ?
Import de fichier texte ?
Power Query ?

Plutôt que supprimer des lignes, ne serait-il pas plus sage de ne pas les lire en premier lieux ?
(Cela dépend de la façon dont les données atterrissent dans Excel).

[Patate3181]

Alors oui, dans ce cas précis, on supprime toutes les lignes en effet. Si elles ont le même NDA avec un cycle différent, ça veut dire qu'ils ont déjà pris contact avec nous pour effectuer la surveillance ou le renouvellement !

Je ne veux que ceux qui ne sont présent qu'une seule fois dans la base.

Le fichier source est un fichier .xlsx

Et non je ne souhaite pas consulter les lignes qui sont en doublons, je veux justement ne plus les voir et les supprimer de ma base car ils ne m'intéressent pas. C'est une base de relance commerciale.

Si NDA 123456789 apparait qu'une fois => On doit le recontacter pour faire le renouvellement

Si NDA 123456789 apparait deux fois ou plus => On l'a déjà recontacté et il a déjà probablement planifié son renouvellement donc je ne veux plus le voir. Ni sa ligne renouvellement, ni sa ligne initiale, elle ne me sert à rien

[halaster08]

Bonjour,

Sans vba: utiliser la fonction nb.si sur le NDA pour compter le nombre de lignes avec le meme NDA, filtrer sur ceux >1, puis les supprimer
En vba: utiliser l'enregistreur de macro sur les étapes ci-dessus, nettoyer un peu le code et voilà

[Franc]

Bonjour, teste ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub SupprLignes()
 
Dim ws As Worksheet
Dim rng As Range
Dim dict As Object
Dim i As Long
Dim key As Variant
 
Set ws = ThisWorkbook.Sheets("Feuil1")
Set rng = ws.Range("B2:B" & ws.Cells(ws.Rows.Count, "B").End(xlUp).Row)
Set dict = CreateObject("Scripting.Dictionary")
 
' Premier parcours pour compter les occurrences de chaque valeur
For i = 1 To rng.Count
    If dict.exists(rng(i, 1).Value) Then
        dict(rng(i, 1).Value) = dict(rng(i, 1).Value) + 1
    Else
        dict.Add rng(i, 1).Value, 1
    End If
Next i
 
' Deuxième parcours pour supprimer les lignes ayant une valeur en double ou plus
For i = rng.Count To 1 Step -1
    If dict(rng(i, 1).Value) > 1 Then
        rng(i, 1).EntireRow.Delete
    End If
Next i
 
End Sub

[Patate3181]

Salut Halaster08 et Franc, je vous remercie grandement !

C'est exactement ce que je recherchais !

J'ai pris la solution de Franc qui est plus rapide à l'utilisation néanmoins j'ai réussi au même résultat avec la fonction de Halaster08 donc merci beaucoup à tous les deux ! vous êtes top !