Discussion :

[2lester]

Bonjour,

J'ai besoin d'une macro qui supprime les colonnes d'un fichier ayant pour valeur en cellule de 1ère ligne (en-tête de la colonne) "Service", "Métier exercé" et "Date formation".

Ci-dessous le code que j'essaye d'utiliser pour cela mais il ne fonctionne pas... Je n'arrive pas à trouver la solution.

Quelqu'un pour m'aider ? Par avance merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Sub SupprCol()
 
Dim i%
Dim j%
 
For i = 1 To 1 'La première ligne
For j = 1 To 60 'les 60 premières colonnes
 
If Cells(i, j) = "Service" Then
If Cells(i, j) = "Métier exercé" Then
If Cells(i, j) = "Date formation" Then
 
Cells(i, j).EntireColumn.Delete
 
End If
End If
End If
 
Next
Next
 
 
End Sub

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Dim LastCol As Integer, i As Integer
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    LastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
    For i = LastCol To 1 Step -1
        If .Cells(1, i).Value <> "" Then
            If InStr("Service|Métier exercé|Date formation|", .Cells(1, i).Value) > 0 Then .Columns(i).Delete
        End If
    Next i
End With

[Mrfreeze117]

Bonjour,

Tu peux essayer ça.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub SupprCol()
 
Dim i As Long
Dim j As Long
 
For i = 1 To 1 'La première ligne
 
    For j = 1 To 60 'les 60 premières colonnes
 
        If Cells(i, j) = "Service" Or Cells(i, j) = "Métier exercé" Or Cells(i, j) = "Date formation" Then
            Cells(i, j).EntireColumn.Delete
        End If
 
    Next
 
Next
 
End Sub

Par contre ta variable i ne sert à rien vu qu'elle ne change pas. ( c'est peut être pour la suite du coup je l'ai laissé).

[Mrfreeze117]

Re bonjour,

Ceux qui ont voté négativement pour mon poste, peuvent-il m'expliquer pourquoi? Je souhaite juste progresser, mais si on ne m'explique pas ce qui ne vas pas je resterai toujours au même stade. Merci d'avance.

[mercatog]

Bonsoir
Le vote négatif signifie que tu n'as pas testé avant de répondre.

Suppose que tu as an A1: Service et en B1 Service et en C1 Toto
Les colonne A et B devraient être supprimé

Pour j=1, tu supprimes la colonne 1, la colonne 2 devient colonne 1 et colonne 3 devient colonne 2

Pour j=2, en B1 tu as l'ancienne C1, càd Toto ne sera pas supprimé

En fin de compte, tu auras Service en A1 (l'ancienne B1)

Moralité:

Pour la suppression, commence de la dernière colonne vers la première

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For j=60 To 1 Step -1

Pour la réponse au forum, il faudrait tester au préalable le code proposé
Pour le vote, c'est un détail et n'est en aucun cas une insulte.

[Mrfreeze117]

Merci pour ta réponse

J'avais fait un test mais j'ai pas pensé à mettre deux fois la même chose dans deux cellule côte à côte.

Pour le vote ne t'inquiète pas je le prends pas mal du tout c'est juste que j'aime bien comprendre où sont mes erreurs, pour éviter de les refaire. Et sans explication ce n'est pas facile.

Merci encore

Du coup j'ai corrigé mon code je vous le mets même si ta solution me parait plus abouti.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub SupprCol()
 
Dim i As Long
Dim j As Long
 
For i = 1 To 1 'La première ligne
 
    For j = 1 To 60 'les 60 premières colonnes
 
        If Cells(i, j) = "Service" Or Cells(i, j) = "Métier exercé" Or Cells(i, j) = "Date formation" Then
            Cells(i, j).EntireColumn.Delete
            j = j - 1
        End If
 
    Next
 
Next
 
End Sub

[Philippe Tulliez]

Bonsoir,
Une autre option

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub SupprCol()
Dim j As Long
  For j = Cells(1, Columns.Count).End(xlToLeft).Column To 1 Step -1
    Select Case Cells(1, j)
     Case "Service", "Métier exercé", "Date formation"
      Columns(j).Delete
    End Select
  Next
End Sub

[2lester]

Mercatog, Mrfreeze117 et Corona : un grand merci pour votre aide
J'ai utilisé le code de Corona, c'est le plus court (économie de lignes )
Bonne journée

[Judel1993]

Bonjour,

Je rencontre le même problème mais dans le sens opposé: je cherche à supprimer les colonnes dont la première cellule ne contient ni les valeurs "Service", "Métier exercé" et "Date formation" (pour reprendre l'exemple utilisé.

J'ai beau utiliser <>, tout disparaît

Quelqu'un pourrait-il m'aider?

Judel

[Philippe Tulliez]

Bonjour,
Tu peux utiliser le Case Else pour effectuer la suppression. Il y a d'autres solutions mais pas le temps de m'y pencher

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub SupprCol()
  Dim j As Long
  For j = Cells(1, Columns.Count).End(xlToLeft).Column To 1 Step -1
    Select Case Cells(1, j)
     Case "Service", "Métier exercé", "Date formation"
     Case Else
       Columns(j).Delete
    End Select
  Next
End Sub

Attention que la casse doit être respectée sinon il faut changer le test en utilisant la fonction LCase ou UCase (lignes 4 et 5 à modifier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    Select Case LCase(Cells(1, j))
     Case "service", "métier exercé", "date formation"

[Judel1993]

C'était exactement ça!
Merci beaucoup Philippe, je me serai arraché bien moins de cheveux si j'avais demandé cette aide bien plus tôt!