Discussion :

[tchantches007]

Bonjour,
J'ai une liste qui m'est transmise comme celle-ci :

sam 13/05/2023	mer 24/05/2023	mer 31/05/2023
lun 19/06/2023	lun 05/06/2023	ven 16/06/2023	mer 28/06/2023	lun 26/06/2023
ven 07/07/2023	lun 17/07/2023

J'ai besoin de ressortir le nombre de samedi, de dimanche et de jour férié contenu dans ce tableau.
Existe-t-il une simple formule pour le faire ?

Merci d'avance aux champions que je sais exister ici et qui ne vont pas manquer de me répondre !

D'JeF

[78chris]

Bonjour

Excel ne connait pas les jours fériés : il faut donc en établir la liste, nommée souvent JF. On utilise ensuite le test

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI(JF;Date)>1

pour savoir si une date en fait partie

Pour le samedi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=JOURSEM(Date;2)=6

le dimanche

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=JOURSEM(Date;2)=7

ou les deux à la fois

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=JOURSEM(Date;2)>5

Sur une plage complète

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((NB.SI.ENS(JF;A2:E4)>0)+(SIERREUR(ET(A2:E4<>"";JOURSEM(A2:E4;2)>5);0)))

à valider en matriciel avec CTRL Shift Entrée

[tchantches007]

Un tout grand merci pour cette première étape !
Etape, en effet, car comme on peut le voir ici, il y manque quelque chose et c'est bien mon problème.
si la formule compte bien les jours fériés, elle "oublie" les samedis et dimanche ...



Une idée ?

[njhub]

Bonjour tchantches007, le forum

Voyez dans le fichier joint si la formule matricielle proposée ci dessous peut vous aider

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI(ESTNUM(EQUIV(Datz;JF_BE;0));">0")+NB.SI(JOURSEM(Datz;2);">5")-NB.SI.ENS(JOURSEM(Datz;2);">5";ESTNUM(EQUIV(Datz;JF_BE;0));">0")

tchantches007-JF&WE_BE.ods



Je viens de m'apercevoir que vous étiez sous excel

tchantches007-JF&WE_BE.xlsx

[tchantches007]

Bonjour a toi aussi ôh njhub !!!

Ta formule fonctionne parfaitement !!!
par contre, impossible de la transférer en Excel et je dois avouer que je ne vois pas pourquoi !?

[78chris]

RE
[QUOTE=tchantches007;12013335]
si la formule compte bien les jours fériés, elle "oublie" les samedis et dimanche ...

Effectivement
Ceci fonctionne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((NB.SI.ENS(JF;A2:E4)>0)+((A2:E4<>"")*(GAUCHE(TEXTE(A2:E4;"jjj");3)="sam"))+(GAUCHE(TEXTE(A2:E4;"jjj");3)="dim"))

Et pour les fériés tombant un WE

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(((NB.SI.ENS(JF;A2:E4)>0)*(GAUCHE(TEXTE(A2:E4;"jjj");3)<>"sam")*(GAUCHE(TEXTE(A2:E4;"jjj");3)<>"dim"))+((A2:E4<>"")*(GAUCHE(TEXTE(A2:E4;"jjj");3)="sam")+(GAUCHE(TEXTE(A2:E4;"jjj");3)="dim")))

[78chris]

Re

Ta formule fonctionne parfaitement !!!
par contre, impossible de la transférer en Excel et je dois avouer que je ne vois pas pourquoi !?

Excel n'accepte aucune transformation de la plage dans un NB.SI (& co)

[tchantches007]

Merci a toi 78Chris !

"Excel n'accepte aucune transformation de la plage dans un NB.SI"

ce qui veux dire ?? (Excusez cet ignoble ignorant).

Avec la formule de la réponse précédente, j'ai aussi un souci, et hum, avec la capture suivante, je pense qu'il n'y a pas besoin de détail ?!



Ceci dit, éliminer UNE fois par an les samedis et dimanches de la liste des jours fériés ne me parait pas un travail d'une extrême complexité ni qui sera grandement gourmande en effort et temps.
Je vais donc m'incliner avec respect devant vous et avec votre approbation cloturer cette discussion .... après avoir reçu de 78Chris, s'il le veux bien la petite explication demandée ci-dessus...

Merci !

[78chris]

Re
Bizarre

[riton00]

Bonjour tchantches007, le forum

Ne pourrais-tu pas mettre un fichier anonymisé complété par des explications exhaustives, cela permettrait aux intervenants de répondre plus précisément à ta question.

Slts

[tchantches007]

Re
Bizarre

Oui, effectivement, mais c'est "MEA CULPA"
CTRL-SHIFT-ENTER est manquant !


Et donc c'est tout à fait fonctionnel.

Merci encore !

[Pierre Dumas]

Bonsoir

Pour arriver à compter les 14 dates concernées dans l'image ci-dessous :



Je peux aussi proposer la formule suivante (un peu plus courte) :
=SOMMEPROD( ( (ESTNUM(EQUIV(Tableau1[Jours];Tab_JF[JF];0)) + (JOURSEM(Tableau1[Jours];2)>5) )>=1) *1)

Les deux tableaux (gris et oranges sont des tableaux structurés)
On cherche dans un premier temps, quelles sont les dates qui sont parmi les jours fériés.
On cherche aussi quelles sont celles qui tombent un WE
Le >1, c'est pour les cas où il y a des Jours fériés qui tombent les WE. Cela permet de compter la date qu'une seule fois et non pas deux.

En espérant que cela serve.

Pierre Dumas

[78chris]

Bonsoir

Je peux aussi proposer la formule suivante (un peu plus courte) :
=SOMMEPROD( ( (ESTNUM(EQUIV(Tableau1[Jours];Tab_JF[JF];0)) + (JOURSEM(Tableau1[Jours];2)>5) )>=1) *1)

Le tableau initial avait plusieurs colonnes et lignes et dans ce cas cela ne fonctionne pas...

[Pierre Dumas]

Bonjour 78chris et le forum

Suite à ta remarque, j'ai eu un doute et j'ai essayé.

Je confirme que la formule donnée fonctionne. Il suffit de changer la plage des dates. Au lieu de prendre Tableau1[Jours], on prends la plage A2:C9

Ceci étant, je suis sur une version 2021. Il y a peut-être une petite différence.

Est-ce que tu peux indiquer si cela fonctionne ou pas sur une version 2019 ?

En espérant que cela aide.

Pierre Dumas

[78chris]

RE Pierre

En fait j'ai copié depuis le message initial et n'avait pas vu que les dates étaient passées en texte (erreur de débutant !)

Mais reste un souci avec les cellules vides

EDIT : ces 2 là fonctionnent

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD( ( (ESTNUM(EQUIV(A2:F4;JF;0)) + (JOURSEM(SI(A2:F2="";3;A2:E4);2)>5))>=1) *1)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(((NB.SI.ENS(JF;A2:F4)>0)+(JOURSEM(SI(A2:F2="";3;A2:E4);2)>5)>=1)*1)