Discussion :

[dodimat]

Bonjour
Je suis à la recherche du cablage et du programme pour gérer un aiguillage commandé par un servomoteur SG 90. Je souhaite que l'aiguillage se déplace au passage du train devant un capteur FC 51 et retrouve sa position initiale aprés.
Quelqu'un pourrait il m'aider merci à la personne qui me répondra.
J'ai un UNO disponible.

[Jay M]

Le site locoduino regorge d’informations pour ce domaine

https://www.locoduino.org/

[jpbbricole]

Bonsoir dodimat

Voici une façon de faire.

Le capteur se connecte sur la pin captPin, le servo sur la pin servoAigPin.
Les angles de l'aiguillage droit ou tourner sont dans:

const int servoAigDroite = 20; // Position en degrés du servo pour l'aiguille droite
const int servoAigTourne = 120; // Position en degrés du servo pour l'aiguille tourne

La vitesse du servo dans servAigSpeed.

Tant qu'il y a des détections du capteur, l'aiguillage tourne avec un maintient de captOnTempo millisecondes.
Ce programme nécessite la bibliothèque:
<VarSpeedServo.h> // https://github.com/netlabtoolkit/VarSpeedServo

Le programme:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
/*
    Name:       ARDDEV_aiguillageCapteurFc51.ino
    Created:	04.02.2024
    Author:     jpbbricole
	https://www.developpez.net/forums/d2161847/general-developpement/programmation-systeme/embarque/arduino/aiguillage-capteur-fc-51-a/
*/
#include <VarSpeedServo.h>     // https://github.com/netlabtoolkit/VarSpeedServo
 
const int captPin = 2;     // Pin du capteur
const int captEatOn = LOW;     // Etat lu quand capteur actif
 
const unsigned long captOnTempo = 1000;     // Temporisation du capteur on
unsigned long captOnMillis = 0;     // Temporisation du capteur on, chrono
 
VarSpeedServo servoAig;     // Creation de l'objet serevoAig
const int servoAigPin = 3;     // Pin de connexion du servo
 
const int servoAigDroite = 20;     // Position en  degrés du servo pour l'aiguille droite
const int servoAigTourne = 120;     // Position en  degrés du servo pour l'aiguille tourne
const int servAigSpeed = 80;     // Vitesse du servo (0-255)
 
void setup()
{
	Serial.begin(115200);
 
	pinMode(captPin, INPUT_PULLUP);     // Entrée active à 0
	servoAig.attach(servoAigPin);     // Déémarrage du servo
 
	servoAig.write(servoAigDroite, servAigSpeed);     // Aiguille droite
}
 
void loop()
{
	if (digitalRead(captPin) == captEatOn)     // Si le capteur est actif
	{
		if (captOnMillis == 0)
		{
			servoAig.write(servoAigTourne, servAigSpeed);     // L'aiguille tourne
		}
		captOnMillis = millis();
 
	}
 
	if (captOnMillis != 0 && (millis() - captOnMillis >= captOnTempo))     // Si temporisation terminée
	{
		servoAig.write(servoAigDroite, servAigSpeed);     // Aiguille droite
		captOnMillis = 0;     // Temporisation desactivée
	}
}

Le schéma:
jpbbricole

Cordialement
jpbbricole

[dodimat]

Le site locoduino regorge d’informations pour ce domaine

https://www.locoduino.org/

Merci pour votre réponse j'ai visité le site mais étant nul en électronique ce n'est pas facile de se faire une idée de ce qu'il faut faire. Niveau cablage c'est bon mais c'est au niveau programme que je sèche.
Bonne journée

[dodimat]

Bonsoir dodimat

Voici une façon de faire.

Le capteur se connecte sur la pin captPin, le servo sur la pin servoAigPin.
Les angles de l'aiguillage droit ou tourner sont dans:

const int servoAigDroite = 20; // Position en degrés du servo pour l'aiguille droite
const int servoAigTourne = 120; // Position en degrés du servo pour l'aiguille tourne

La vitesse du servo dans servAigSpeed.

Tant qu'il y a des détections du capteur, l'aiguillage tourne avec un maintient de captOnTempo millisecondes.
Ce programme nécessite la bibliothèque:
<VarSpeedServo.h> // https://github.com/netlabtoolkit/VarSpeedServo

Le programme:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
/*
    Name:       ARDDEV_aiguillageCapteurFc51.ino
    Created:	04.02.2024
    Author:     jpbbricole
	https://www.developpez.net/forums/d2161847/general-developpement/programmation-systeme/embarque/arduino/aiguillage-capteur-fc-51-a/
*/
#include <VarSpeedServo.h>     // https://github.com/netlabtoolkit/VarSpeedServo
 
const int captPin = 2;     // Pin du capteur
const int captEatOn = LOW;     // Etat lu quand capteur actif
 
const unsigned long captOnTempo = 1000;     // Temporisation du capteur on
unsigned long captOnMillis = 0;     // Temporisation du capteur on, chrono
 
VarSpeedServo servoAig;     // Creation de l'objet serevoAig
const int servoAigPin = 3;     // Pin de connexion du servo
 
const int servoAigDroite = 20;     // Position en  degrés du servo pour l'aiguille droite
const int servoAigTourne = 120;     // Position en  degrés du servo pour l'aiguille tourne
const int servAigSpeed = 80;     // Vitesse du servo (0-255)
 
void setup()
{
	Serial.begin(115200);
 
	pinMode(captPin, INPUT_PULLUP);     // Entrée active à 0
	servoAig.attach(servoAigPin);     // Déémarrage du servo
 
	servoAig.write(servoAigDroite, servAigSpeed);     // Aiguille droite
}
 
void loop()
{
	if (digitalRead(captPin) == captEatOn)     // Si le capteur est actif
	{
		if (captOnMillis == 0)
		{
			servoAig.write(servoAigTourne, servAigSpeed);     // L'aiguille tourne
		}
		captOnMillis = millis();
 
	}
 
	if (captOnMillis != 0 && (millis() - captOnMillis >= captOnTempo))     // Si temporisation terminée
	{
		servoAig.write(servoAigDroite, servAigSpeed);     // Aiguille droite
		captOnMillis = 0;     // Temporisation desactivée
	}
}

Cordialement
jpbbricole

Bonjour
Merci infiniment pour votre réponse et votre programme je vais l'essayer mais comme je suis nul en électronique et en programmation j'aurais certainement d'autres questions à vous poser si vous êtes d'accord bien sûr.
cordialement
dodimat

[jpbbricole]

Bonjour dodimat

Pas de problème, j'ai mis le schéma dans le post #3.

Bonne journée
jpbbricole

[Jay M]

idéalement il faut alimenter le servo autrement que par la pin 5V de l'arduino.

[jpbbricole]

Bonjour Jay M

idéalement il faut alimenter le servo autrement que par la pin 5V de l'arduino.

S'il n'y a qu'un SG-90, ça fonctionne très bien.

Cordialement
jpbbricole

[Jay M]

c'est pour cela que j'ai dit "idéalement".

tout dépend de l'usage. Par exemple le "stall current" d'un SG-90 c'est ~750mA - ça fait déjà beaucoup pour la piste 5V de l'arduino et si vous êtes en USB vous n'avez que 500mA de dispo et si l'arduino est alimenté par son jack en 12V par exemple le régulateur devra dissiper plus de 5W... c'est trop.

De manière générale il faut éviter d'utiliser son arduino comme une alimentation.

[dodimat]

Merci à tous pour vos réponses vous êtes tous super. J'ai essayé le cabage et leprogramme de JPB ça marche trés bien et je lui suis trés reconnaisant il faut maintenant que je regarde le programme de plus prés pour essayer de le comprendre.
Si je peux me permettre comment feriez vous l'alimentation?
cordialement

[jpbbricole]

Bonjour dodimat

J'alimenterai ça avec un chargeur USB.

Si tu n'as qu'un servo, le chargeur connecté au port USB de l'Arduino.

Ou, depuis le jack d'alimentation, un adapteur secteur qui sort entre 7 et 12 volts, des informations sur le sujet, chez Locoduino.

Cordialement
jpbbricole

[jpbbricole]

Bonjour Dodimat.

Voilà la version à 2 aiguillages, elle serait, moyennant très peu de programmation, extensible à 4 aiguillages.
Je n’ai volontairement pas alimenté les servo en +5V car contrairement à la version à 1 servo qui pouvait âtre alimentée avec l’Arduino, avec 2 servo ou plus, il faut une alimentation spécifique pour ces servo.

Le programme:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
/*
    Name:       ARDDEV_aiguillageFc51Nano.ino
    Created:	11.02.2024
    Author:     jpbbricole
	Remarque:	Commande d'aiguillages par des capteurs IR FC-51
 
	https://www.developpez.net/forums/d2161847/general-developpement/programmation-systeme/embarque/arduino/aiguillage-capteur-fc-51-a/
 
*/
#include <VarSpeedServo.h>     // https://github.com/netlabtoolkit/VarSpeedServo
 
//------------------------------------- Caspteurs
const int captPin[] = {2, 3};     // Pin des capteurs
const int captEatOn = LOW;     // Etat lu quand capteur actif
const int captNombre = sizeof(captPin) / sizeof(captPin[0]);     // Nombre de capteurs
 
const unsigned long captOnTempo = 1000;     // Temporisation des capteurs on
 
unsigned long captOnMillis[] = {0, 0};     // Temporisation des capteurs on, chrono
 
//------------------------------------- Servo
VarSpeedServo servoAig[captNombre];     // Creation des objets serevoAig
 
struct servoParamDef     // Définition des servo
{
	const int pin;     // Pin de connexion du servo
	int aigDroite;     // Angle pour aiguille droite
	int aigTourne;     // Angle pour aiguille tourne
	int speed;     // Vitesse du servo
	boolean wait;     // Attente fin de mouvement du servo
};
servoParamDef servoAigParam[] =      // Servo, paramètres
{
//   Pin   Aig Drite   Aig Tourne   Vitesse    Attente
	{ 6,      20,         120,        80,      false},
	{ 7,      20,         120,        80,      false},
};
 
void setup()
{
	Serial.begin(115200);
 
	//--------------------------------- Initialisation Capteurs et servo
	for (int c = 0; c < captNombre; c ++)
	{
		pinMode(captPin[c], INPUT_PULLUP);     // Entrée active à 0
		servoAig[c].attach(servoAigParam[c].pin);     // Déémarrage du servo
 
		servoAig[c].write(servoAigParam[c].aigDroite, servoAigParam[c].speed, servoAigParam[c].wait);     // Aiguille droite au départ
	}
 
}
 
void loop()
{
	for (int c = 0; c < captNombre; c ++)
	{
		if (digitalRead(captPin[c]) == captEatOn)     // Si le capteur est actif
		{
			if (captOnMillis[c] == 0)
			{
				servoAig[c].write(servoAigParam[c].aigTourne, servoAigParam[c].speed, servoAigParam[c].wait);     // L'aiguille tourne
				Serial.println("Aiguille " + String(c) + " tourne");
			}
			captOnMillis[c] = millis();		
		}
	}
 
	for (int c = 0; c < captNombre; c ++)
	{
		if (captOnMillis[c] != 0 && (millis() - captOnMillis[c] >= captOnTempo))     // Si temporisation du capteur terminée
		{
			servoAig[c].write(servoAigParam[c].aigDroite, servoAigParam[c].speed, servoAigParam[c].wait);     // Aiguille droite
			Serial.println("Aiguille " + String(c) + " droite");
 
			captOnMillis[c] = 0;     // Temporisation desactivée pour ce capteur
		}
	}
}

Le schéme:


N'hésites pas à poser des questions

Bon dimanche
Cordialement
jpbbricole

[dodimat]

Bonsoir jpbbricole
Immense merci pour ce que tu fais pour moi j'attends mon nano pour test c'est sûr que j'aurais certainement d'autres questions quand j'essaierais ça.
Bonne soirée
Cordialement
Dodimat

[dodimat]

Bonjour Jpbbricole
J'aurais une question qui n' a rien à voir avec le sujet précedent. Je parcours le site locoduino et j'ai vu qu'on pouvait avec un montage de cartes gérer ses locos à partir d'une tablette. Pour cela il faut un shield ethernet connecté à la box est ce possible si la box est au rez de chaussée et le réseau au deuxieme étage si c'est oui quels éléments faut il?
BON AM

[jpbbricole]

Bonjour Dodimat

Peux tu mettre un lien sur l'article Locoduino ?

Cordialement
jpbbricole

[dodimat]

Bonjour JPBBRICOLE
Voici l'adresse https://www.locoduino.org/spip.php?article185
Bon dimanche
cordialement
dodimat

[jpbbricole]

Bonsoir dodimat

J'ai lu l'article, et ça dépasse mes compétences, navré
Le mieux est que tu poses la question chez Locoduino.

Bonne soirée
jpbbricole

[dodimat]

Bonjour JPBBRICOLE
Merci pour ta réponse si ça te dépasse je vais éviter de me lancer sur un tel projet compte tenu de mes compétences.
Bonne journée à toi

[dodimat]

Bonjour JPBBRICOLE
J'ai reçu mon nano et ça marche super bien merci pour tout.
Bonne journée à toi
Cordialement
Dodimat

[dodimat]

Rebonjour
Pour augmenter le temps de déviation du servo quelle ligne faut il modifier sur le programme stp.
Bon AM