Discussion :

[Phileas78]

Bonjour,
Recherche infructueuse sur l'ensemble du NET, je me retourne vers vous.
J'ai un formulaire avec des questions simples (validé / non validé) structurées par chapitre. Je peux répondre à l'ensemble des questions mais je peux aussi valider le chapitre et alors l'ensemble des questions qui en dépendent sont automatiquement validées. Jusque là, j'ai su faire avec le code suivant (pour un exemple de chapitre de 8 checkbox):

Private Sub CheckBox1_click()
Dim i As Long
With ActiveSheet
If CheckBox1 = True Then
For i = 2 To 9
With .OLEObjects("CheckBox" & i)
.Object.Value = True
End With
Next i
Else
For i = 2 To 9
With .OLEObjects("CheckBox" & i)
.Object.Value = False
End With
Next i
End If
End With
End Sub

Mon problème : si je valide le chapitre, je ne peux pas dévalider une question dépendante. Dans mon cas de 8 questions, si j'en ai 7 à valider, je souhaiterais pouvoir valider les 8 et en dévalider 1 - fonctionnalité qui me semble pouvoir être appréciable.
Je suis preneur de tout conseil.

[Franc]

Bonjour, voici une idée:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub CheckBox1_Click()
    Dim i As Long
 
    ' Si CheckBox1 est cochée, coche toutes les autres ; sinon, décoche toutes les autres
    For i = 2 To 9
        Me.Controls("CheckBox" & i).Value = Me.Controls("CheckBox1").Value
    Next i
End Sub

[Thumb down]

bonjour,
pour info, on ne teste pas un Boolean pour mettre la même valeur à un autre Boolean

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub CheckBox1_click()
    Dim i As Long
    With ActiveSheet
        For i = 2 To 9
            .OLEObjects("CheckBox" & i).Object.Value = CheckBox1
        Next i
    End With

pour le reste je ne vois pas pourquoi tu ne pourrais pas décocher la question 8

Désolé franc mais de toute évidence j'écris moins vite que toi

[Franc]

bonjour,
pour info, on ne teste pas un Boolean pour mettre la même valeur à un autre Boolean

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub CheckBox1_click()
    Dim i As Long
    With ActiveSheet
        For i = 2 To 9
            .OLEObjects("CheckBox" & i).Object.Value = CheckBox1
        Next i
    End With

pour le reste je ne vois pas pourquoi tu ne pourrais pas décocher la question 8

Désolé franc mais de toute évidence j'écris moins vite que toi

Pas de souci, c'est toujours bien d'avoir le choix entre différentes solutions

[Phileas78]

Merci pour la rapidité de vos retours.

Malheureusement, le code est probablement plus propre mais le résultat est le même : la propriété Enabled de mes checkbox "filles" passe automatiquement sur "False" et je ne peux donc les décocher. J'ai essayé de forcer la propriété sans y parvenir.

[Thumb down]

La propriété Enabled ne peut pas passer automatiquement à False ou alors tu il faut nous montrer la partie de code qui le fait.

Ou plus simplement la supprimer.

[Philippe Tulliez]

Bonjour,
Voici une proposition
Dans une feuille plusieurs CheckBox nommés chk_Chap_1_0 ...chk_Chap_1_3 et chk_Chap_2_0 ...chk_Chap_2_3
Chaque CheckBox se trouve dans un groupe Chap_1, Chap_2, etc.
Dès que l'on clique sur un CheckBox suffixé 0, tous les CheckBox du groupe prennent la même valeur que celui-ci

Une procédure UpdateGroupCheckboxState qui se charge de faire la modification de la propriété Value des CheckBox et autant de procédures événementielles qu'il n'y a de CheckBox suffixé "0"

Code de l'une des procédures événementielles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub chk_Chap_1_0_Click()
  With Me.chk_Chap_1_0
    UpdateGroupCheckboxState .GroupName, .Value
  End With
End Sub

La procédure qui modifie la propriété Value des CheckBox du même groupe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub UpdateGroupCheckboxState(GroupName As String, Flag As Boolean)
    Dim oleObj As OLEObject
    Dim prefix As String
    Dim suffix As String
 
    ' Extrait le préfixe de nom de groupe
    prefix = GroupName & "_"
 
    ' Parcourir tous les OLEObjects de la feuille
    For Each oleObj In Me.OLEObjects
        If TypeName(oleObj.Object) = "CheckBox" Then
            With oleObj.Object
                If InStr(1, oleObj.Name, prefix, vbTextCompare) Then
                    ' Extrait le suffixe
                    suffix = Mid(oleObj.Name, InStrRev(oleObj.Name, "_") + 1)
                    ' Exclure le contrôle principal (suffixe "0")
                    If suffix <> "0" Then
                        .Value = Flag
                    End If
                End If
            End With
        End If
    Next
    Set oleObj = Nothing
End Sub

Illustration

[Phileas78]

Nickel Philippe, c'est exactement ce que je cherchais et ton script va me permettre de m'adapter à la structure du questionnaire.

Pour info, mon code fonctionnait aussi en fixant la propriété Enabled sur True mais j'avais laissé la procédure dans un module au lieu de la positionner sur la feuille.

Merci à tous les 3 pour l'aide.

[Philippe Tulliez]

Bonjour,
Merci pour le retour

Pour info, mon code fonctionnait aussi en fixant la propriété Enabled sur True mais j'avais laissé la procédure dans un module au lieu de la positionner sur la feuille.

Il est parfaitement possible de déplacer la procédure UpdateGroupCheckboxState dans un module standard. C'est d'ailleurs comme cela que je pratique d'habitude mais alors je passe l'objet lui-même en paramètre, ce qui permet encore de réduire le nombre d'argument.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub UpdateGroupCheckboxState(oCheckBox As Msforms.CheckBox)
  ' Argument
  '   oCheckBox Objet CheckBox qui déclenche l'action
 
  Dim oleObj As OLEObject
  Dim prefix As String
  Dim suffix As String
 
  ' Extrait le préfixe de nom de groupe
  prefix = Left(oCheckBox.Name, InStrRev(oCheckBox.Name, "_") - 1) & "_"
 
  ' Parcourir tous les OLEObjects de la feuille
  For Each oleObj In oCheckBox.Parent.OLEObjects
    If TypeName(oleObj.Object) = TypeName(oCheckBox) Then
      With oleObj.Object
        If InStr(1, oleObj.Name, prefix, vbTextCompare) Then
          ' Extrait le suffixe
          suffix = Mid(oleObj.Name, InStrRev(oleObj.Name, "_") + 1)
          ' Exclure le contrôle principal (suffixe "0")
          If suffix <> "0" Then .Value = oCheckBox.Value
        End If
      End With
    End If
  Next oleObj
  Set oleObj = Nothing
End Sub

Dans ce cas, il y a lieu de modifier les procédures événementielles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub chk_Chap_1_0_Click()
  With Me
    UpdateGroupCheckboxState .chk_Chap_1_0
  End With
End Sub