Discussion :

[Sonitha]

Bonjour,

Pour commencer, je m'excuse pour le titre. Je ne trouve pas de phrase simple qui résume ma demande.

Je souhaiterais trouver une formule pour ma problématique suivante, je vais essayer d'expliquer au mieux mais même-même dans ma tête je m'embrouille:

Contexte: (les noms des colonnes ont été modifiés)
J'ai un tableau avec 2 feuilles nommées respectivement "Feuille1" et "Contact".
Dans la feuille"Contact", il y a les colonnes"Adresse" "Portable" "Fixe" "Email 1" "Email2"...

Les 2 feuilles possèdent une colonne commune nommée "Entreprise".

Cette fois-ci je souhaiterais indiquer "OUI" dans la colonne "E" de ma Feuille1, toutes les entreprises qui possèdent au moins une donnée dans les colonnes "Adresse""Portable""Fixe""Email1""Email2"... de la feuille "contact".

J'ai essayé Si((NB.SI...)) mais ça ne fonctionne pas, comme celui-ci:
SI(NB.SI(Contact!$A:$A,B1,Adresse!$B:$B,"<>",Portable!$C:$C,"<>",Fixe!$D:$D,"<>",Email1!$E:$E,"<>",Email2!$F:$F,"<>")>0,"OUI","")

B1 = correspond à la 1ère ligne de la colonne "entreprise" de la Feuille1

Je ne sais si c'est assez clair pour vous.

Je vous remercie par avance de votre aide.

Bonne journée
Sonitha

[Philippe Tulliez]

Bonjour,
La fonction NBVAL permet de dénombrer les cellules remplies donc en l'imbriquant dans la fonction SI vous pouvez renvoyer OUI ou NON
Vous n'avez pas précisé si vos données sont dans des plages "classique" ou si elles se trouvent dans un tableau structuré
Exemple d'une formule qui renvoie "Oui" si au moins une des cellules de B à D est remplie ou NON dans le cas contraire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NBVAL(B2:D2);"Oui";"Non")

[Sonitha]

Bonjour,
La fonction NBVAL permet de dénombrer les cellules remplies donc en l'imbriquant dans la fonction SI vous pouvez renvoyer OUI ou NON
Vous n'avez pas précisé si vos données sont dans des plages "classique" ou si elles se trouvent dans un tableau structuré
Exemple d'une formule qui renvoie "Oui" si au moins une des cellules de B à D est remplie ou NON dans le cas contraire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NBVAL(B2:D2);"Oui";"Non")

Bonjour,

Merci pour votre retour.

Concernant les données, mes données se trouvent dans un tableau structuré avec des noms différents pour chaque colonne.

[Sonitha]

Bonjour,
La fonction NBVAL permet de dénombrer les cellules remplies donc en l'imbriquant dans la fonction SI vous pouvez renvoyer OUI ou NON
Vous n'avez pas précisé si vos données sont dans des plages "classique" ou si elles se trouvent dans un tableau structuré
Exemple d'une formule qui renvoie "Oui" si au moins une des cellules de B à D est remplie ou NON dans le cas contraire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NBVAL(B2:D2);"Oui";"Non")

Pour compléter ma réponse précédente. Sauriez-vous m'aiguiller sur comment incrémenter dans SI(NBVAL(...)) les données communes entre les 2 feuilles?

Je vous remercie par avance.
Sonitha

[Philippe Tulliez]

Bonjour,

Concernant les données, mes données se trouvent dans un tableau structuré avec des noms différents pour chaque colonne.

En voyant la formule que vous avez publiée, j'ai des doutes quant au fait que vos données soient dans un tableau structuré

[Sonitha]

Bonjour,

En voyant la formule que vous avez publiée, j'ai des doutes quant au fait que vos données soient dans un tableau structuré

Pour la formule:
SI(NB.SI(Contact!$A:$A,B1,Adresse!$B:$B,"<>",Portable!$C:$C,"<>",Fixe!$D:$D,"<>",Email1!$E:$E,"<>",Email2!$F:$F,"<>")>0,"OUI","")

Parlez-vous de l'absence "[]" pour chaque valeur?

Pourriez-vous m'expliquer la signification de "tableau structuré?"
Je n'ai peut-être pas saisi le sens.

Merci.

[Philippe Tulliez]

Bonjour,

Pourriez-vous m'expliquer la signification de "tableau structuré?"
Je n'ai peut-être pas saisi le sens.

C'est la conversion d'une plage classique en tableau (commande Mettre sous forme de tableau du groupe style de l'onglet [Accueil]
Il n'y a que des avantages à les utiliser
Pour en savoir plus, je vous conseille la lecture de ce tutoriel Apprendre à utiliser les tableaux structurés Excel : création, manipulations et avantages(1)

[Sonitha]

Bonjour,

C'est la conversion d'une plage classique en tableau (commande Mettre sous forme de tableau du groupe style de l'onglet [Accueil]
Il n'y a que des avantages à les utiliser
Pour en savoir plus, je vous conseille la lecture de ce tutoriel Apprendre à utiliser les tableaux structurés Excel : création, manipulations et avantages(1)

Je vous remercie pour le lien. J'ai bien un tableau structuré dans ce cas.
Pourrais-je vous partager une partie de mon tableau pour expertise?

[Philippe Tulliez]

Bonjour,

J'ai bien un tableau structuré dans ce cas

C'est alors curieux que vous référencez des colonnes entières de la feuille alors que vous travaillez avec des tableaux structurés comme la formule ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SI(NB.SI(Contact!$A:$A,B1,Adresse!$B:$B,"<>",Portable!$C:$C,"<>",Fixe!$D:$D,"<>",Email1!$E:$E,"<>",Email2!$F:$F,"<>")>0,"OUI","")

Pourrais-je vous partager une partie de mon tableau pour expertise?

Vous pouvez

[Sonitha]

Bonjour,

C'est alors curieux que vous référencez des colonnes entières de la feuille alors que vous travaillez avec des tableaux structurés comme la formule ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SI(NB.SI(Contact!$A:$A,B1,Adresse!$B:$B,"<>",Portable!$C:$C,"<>",Fixe!$D:$D,"<>",Email1!$E:$E,"<>",Email2!$F:$F,"<>")>0,"OUI","")

Vous pouvez

Merci.
Le voici. J'ai modifié les données confidentielles.
Extrait_AU_EXCEL.xlsx

[Philippe Tulliez]

Bonjour,
Vous n'avez pas précisé la version Office avec laquelle vous travaillez
En supposant que vous ayez la version 365, j'ai opté pour la concaténation de plusieurs fonctions RECHERCHEX imbriquées dans NBCAR elle même imbriquée dans le SI
On devrait pouvoir raccourcir la formule avec LAMBDA et LET mais je n'ai pas le temps de m'y pencher

La formule ci-dessous doit être complétée par les autres colonnes (j'ai rebaptiser les tableaux pour ne pas avoir Tableau1 et Tableau2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NBCAR(RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Adresse Perso];"") & RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Adresse Siège];"") & RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Tel Portable];""));"Oui";"Non")

Il me semble que ce serait plus simple d'ajouter une colonne dans la table t_Entreprise avec la formule qui renverrait Oui et Non et dans la colonne Coordonnées de la table t_Suivi une simple fonction de recherche qui irait chercher le OUI ou le NON

Ce qui donnerait dans la nouvelle colonne nommée Coordonnées de la table nommée t_Entreprise

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NBVAL(t_Entreprise[@[Adresse Perso]:[Email2]]);"Oui";"Non")

et dans colonne Coordonnées de la table t_Suivi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Coordonénes];"")

Une autre option serait de faire une requête Power Query qui renverrait une table à deux colonnes (N° SIRET et la colonne avec OUI/NON)

[Sonitha]

Bonjour,
Vous n'avez pas précisé la version Office avec laquelle vous travaillez
En supposant que vous ayez la version 365, j'ai opté pour la concaténation de plusieurs fonctions RECHERCHEX imbriquées dans NBCAR elle même imbriquée dans le SI
On devrait pouvoir raccourcir la formule avec LAMBDA et LET mais je n'ai pas le temps de m'y pencher

Bonjour,
Merci beaucoup pour les différentes options proposées et de m'avoir accordé du temps.
Je travaille avec Office 2010. Par conséquent, la fonction "XLOOKUP" n'est pas reconnue(J'ai un _xlfn.XLOOKUP).
C'est de ma faute, je n'ai pas précisé effectivement.

La formule ci-dessous doit être complétée par les autres colonnes (j'ai rebaptiser les tableaux pour ne pas avoir Tableau1 et Tableau2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NBCAR(RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Adresse Perso];"") & RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Adresse Siège];"") & RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Tel Portable];""));"Oui";"Non")

Je viens de découvrir qu'il est possible de renommer les tableaux grâce à vous.
De mon côté, je vais tester les différentes formules et je reviendrai vers vous pour le résultat final.
Encore merci!!
Bonne journée

[Philippe Tulliez]

Bonjour,

Je travaille avec Office 2010. Par conséquent, la fonction "XLOOKUP" n'est pas reconnue(J'ai un _xlfn.XLOOKUP).

En remplacement de la fonction =RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Coordonénes];"")
Je me suis rendu compte que j'avais fait une coquille avec le nom de la colonne COORDONNEES. Je l'ai corrigée dans le classeur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(t_Entreprise;EQUIV([@[Numéro SIRET]];t_Entreprise[KBIS];0);EQUIV(t_Suivi[[#En-têtes];[COORDONNEES]];t_Entreprise[#En-têtes];0))

A ajouter éventuellement, la fonction SIERREUR

Je viens de découvrir qu'il est possible de renommer les tableaux grâce à vous.

Je vous invite à lire le tutoriel que je vous ai référencé Apprendre à utiliser les tableaux structurés Excel : création, manipulations et avantages(1) , vous découvrirez certainement bien d'autres fonctionnalités intéressantes

[EDIT]
A lire éventuellement Les fonctions Index et Equiv, pour en savoir plus sur les fonctions INDEX et EQUIV (MATCH pour la version anglaise),

[Sonitha]

Bonjour,
En remplacement de la fonction =RECHERCHEX([@[Numéro SIRET]];t_Entreprise[KBIS];t_Entreprise[Coordonénes];"")Je me suis rendu compte que j'avais fait une coquille avec le nom de la colonne COORDONNEES. Je l'ai corrigée dans le classeur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(t_Entreprise;EQUIV([@[Numéro SIRET]];t_Entreprise[KBIS];0);EQUIV(t_Suivi[[#En-têtes];[COORDONNEES]];t_Entreprise[#En-têtes];0))

A ajouter éventuellement, la fonction SIERREUR

Je vous remercie beaucoup pour les liens et pour le nouveau fichier. En effet, je me rends compte que j'ai d'énormes lacunes.
Ça va beaucoup m'aider à avancer dans mon apprentissage.

Après avoir creusé toute la matinée et essuyé pas mal d'échecs, j'ai trouvé que SI(SOMMEPROD...)) fonctionne également et je voulais vous la partager (je vous l'ai mis en PJ en infra).

=SI(SOMMEPROD(($B4=ENTREPRISES!$B:$B)*((ENTREPRISES!$C:$C<>"")+(ENTREPRISES!$E:$E<>"")+(ENTREPRISES!$F:$F<>"")+(ENTREPRISES!$G:$G<>"")+(ENTREPRISES!$H:$H<>"")))>0; "OUI"; "")

Il ne reste plus maintenant qu'à trouver une option de verrouillage efficace pour les formules pour éviter de supprimer ou modifier par mégarde tout en permettant l'insertion de ligne.
Ce sera l'objet de mon prochain sujet sur le forum.
Encore merci infiniment à vous pour votre aide et vos conseils précieux.


Extrait_AU_EXCEL_RESOLU.xlsx

[Philippe Tulliez]

Bonjour,

Après avoir creusé toute la matinée et essuyé pas mal d'échecs, j'ai trouvé que SI(SOMMEPROD...)) fonctionne également et je voulais vous la partager (je vous l'ai mis en PJ en infra).

Pourquoi référencer des colonnes entières alors que vous travaillez avec des tableaux structurés ?
Votre formule devrait être écrite comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMMEPROD( ([@PACAGE]=t_Entreprise[KBIS]) * ((t_Entreprise[Adresse Perso]<>"") + (t_Entreprise[Tel Portable]<>"") + (t_Entreprise[Tel Fixe]<>"") + (t_Entreprise[Email 1]<>"") + (t_Entreprise[Email2]<>"") ))>0; "OUI"; "")

Il ne reste plus maintenant qu'à trouver une option de verrouillage efficace pour les formules pour éviter de supprimer ou modifier par mégarde tout en permettant l'insertion de ligne.

Il y a une solution en VBA, si l'on veut conserver les possibilités des tableaux structurés

J'ai écrit un billet sur ce sujet Excel - VBA - Empêcher la sélection d'une cellule d'un tableau structuré qui contient une formule

[Sonitha]

Bonjour,


Pourquoi référencer des colonnes entières alors que vous travaillez avec des tableaux structurés ?
Votre formule devrait être écrite comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMMEPROD( ([@PACAGE]=t_Entreprise[KBIS]) * ((t_Entreprise[Adresse Perso]<>"") + (t_Entreprise[Tel Portable]<>"") + (t_Entreprise[Tel Fixe]<>"") + (t_Entreprise[Email 1]<>"") + (t_Entreprise[Email2]<>"") ))>0; "OUI"; "")

Il y a une solution en VBA, si l'on veut conserver les possibilités des tableaux structurés

J'ai écrit un billet sur ce sujet Excel - VBA - Empêcher la sélection d'une cellule d'un tableau structuré qui contient une formule

Je vous remercie encore pour toutes les formules ainsi que le lien vers les billets VBA et tous vos.
J'ai essayé de reproduire la formule mais je manque encore d'expérience VBA. En effet, entre-temps j'ai suivi les autres tutos sur la prise en main de VBA mais pour le moment, lorsque j'essaie d'appliquer la formule et les instructions, je n'arrive pas encore à avoir le résultat attendu.

Pour le moment, je vais marquer que le sujet en objet est résolu et je reviendrai vous donner des nouvelles concernant la sécurisation des formules.

Bonne journée
Sonitha