Discussion :

[VincentCA]

Bonjour,

Novice en macro et code VBA, je souhaiterais un peu d'aide sur ce forum.
Dans la feuille de calcul en PJ, la colonne A représente la valeur a rechercher.
La colonne B est la valeur attitrée a la valeur recherchée.
En dessous les affections de chaque valeur attitrée.
Exemple eck = box 1 si valeur recherchée aaaaa

Est il possible avec un code VBA de créer une fenêtre où l'on viendrai flasher un code barre. Celui ci serait reconnu a sa même valeur de la colonne A. Puis en fonction de la valeur attitrée en B, renverra un message box "box numéro..."

Merci de votre aide,

[BENNASR]

Bonjour vincent, la forum
flasher un code dépasse mes connaissance
mais un simple recherche avec VBA tu peux procéder ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub test()
 Dim Code As Range, magasin As Range, y As Range, F1 As Worksheet
 Dim CodeArechercher As String
   Set F1 = Sheets("Feuille 1")
   Set Code = F1.Range("A2:A" & F1.Range("A" & Rows.Count).End(xlUp).Row)
   Set magasin = F1.Range("D2:D" & F1.Range("D" & Rows.Count).End(xlUp).Row)
   CodeArechercher = InputBox("Indiquez le code de l'article à rechercher", "saisir un Code", "saisir un code svp") '
   Set c = Code.Find(CodeArechercher, LookIn:=xlValues, lookat:=xlWhole)
If Not c Is Nothing Then
Article = F1.Cells(c.Row, 2)
Set CodeMagasin = magasin.Find(Article, LookIn:=xlValues, lookat:=xlWhole)
MsgBox F1.Cells(CodeMagasin.Row, 5)
End If
End Sub

j'espère que ça t'aide à avancer dans ton projet

[VincentCA]

Merci pour cette réponse rapide et efficace.
Après réflexion et test, serait il possible de s'acquitter des validations en appuyant sur Entrée.
Exemple :
Après avoir appuyé sur GO, nous saisissons un code. Pouvons nous supprimons le OK avec une TAB. Puis à l'apparition du message box n°, ne pas appuyer sur OK mais une temporisation du message 3s par exemple ?

[jurassic pork]

Hello,

Est il possible avec un code VBA de créer une fenêtre où l'on viendrai flasher un code barre.

Avec une "douchette" ?
Pour réaliser ce que tu veux faire, un formulaire serait plus adéquat :
voici ce que je te propose :
Un formulaire qui :

• Reçoit le code barre dans un champ texte
• Quand dans ce champ on reçoit un caractère de fin (ex 13 = Return, ce qu'une douchette doit pouvoir faire) la recherche est effectuée dans le classeur.
• Le résultat est affiché dans le champ de Box. Si la recherche est infructueuse c'est aussi indiqué dans le champ Box
• Une temporisation réglable permet de maintenir le contenu des champs pendant un certain nombre de secondes. Ensuite les champs sont effacés et le focus est mis sur le champ de code barre pour permettre la saisie suivante.
• Un bouton permet d'effacer le contenu des champs.

Voici le code du formulaire qui reprend une partie du code de BENNASR :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Private Sub CodeBarre_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
   If KeyCode = vbKeyReturn Then
           If CodeBarre.Text <> "" Then
              Recherche (CodeBarre.Text)
           End If
    End If
End Sub
Sub Recherche(CodeARechercher As String)
 Dim Code As Range, Magasin As Range, F1 As Worksheet, c As Range, m As Range
   Set F1 = Sheets("Feuille 1")
   Set Code = F1.Range("A2:A" & F1.Range("A" & Rows.Count).End(xlUp).Row)
   Set Magasin = F1.Range("D2:D" & F1.Range("D" & Rows.Count).End(xlUp).Row)
   Set c = Code.Find(CodeARechercher, LookIn:=xlValues, lookat:=xlWhole)
   If Not c Is Nothing Then
        Article = c.Cells.Offset(0, 1)
        Set m = Magasin.Find(Article, LookIn:=xlValues, lookat:=xlWhole)
        If Not m Is Nothing Then
            Box.Text = m.Cells.Offset(0, 1)
            Delai CInt(Tempo.Text)
            Box.Text = ""
            CodeBarre.Text = ""
            CodeBarre.SetFocus
        Else
            Box.Text = "Magasin non trouvé"
        End If
   Else
        Box.Text = "Code non trouvé"
   End If
End Sub
Private Sub CmdRAZ_Click()
CodeBarre.Text = ""
Box.Text = ""
End Sub

L'utilisation de plages nommées serait préférable pour éviter d'être obligé de modifier le code en cas de changement d'implantation des données dans le classeur.

Voici le code du module Basic où il y a la macro d'ouverture du formulaire et une procédure de temporisation.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
#If VBA7 Then
    Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
#Else
    Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
#End If
Sub test()
 UserForm1.Show
End Sub
 
Sub Delai(s As Integer)
    Dim TimeOut As Single
    TimeOut = Timer + s
    Do While Timer < TimeOut
        DoEvents
        Sleep 10 ' tempo de 10 ms pour éviter charge CPU excessive
    Loop
End Sub

En pièce jointe le classeur de test.


Ami calmant, J.P

[VincentCA]

Rhooo merci beaucoup pour cette superbe avancée.
J'ai testé aujourd'hui et ça fonctionne plutôt bien.

"Le résultat est affiché dans le champ de Box. Si la recherche est infructueuse c'est aussi indiqué dans le champ Box" =>serait il possible que tout comme un résultat conforme, ça renvoie automatiquement à la lecture d'un nouveau code après temporisation (dans les cas magasin ou code non trouvé).

En colonne C, est il possible de mentionner le résultat de la box trouvée après chaque recherche ?

Merci encore énormément

[jurassic pork]

Hello,

"Le résultat est affiché dans le champ de Box. Si la recherche est infructueuse c'est aussi indiqué dans le champ Box" =>serait il possible que tout comme un résultat conforme, ça renvoie automatiquement à la lecture d'un nouveau code après temporisation (dans les cas magasin ou code non trouvé).
En colonne C, est il possible de mentionner le résultat de la box trouvée après chaque recherche ?

ce code devrait faire l'affaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Recherche(CodeARechercher As String)
 Dim Code As Range, Magasin As Range, F1 As Worksheet, c As Range, m As Range
   Set F1 = Sheets("Feuille 1")
   Set Code = F1.Range("A2:A" & F1.Range("A" & Rows.Count).End(xlUp).Row)
   Set Magasin = F1.Range("D2:D" & F1.Range("D" & Rows.Count).End(xlUp).Row)
   Set c = Code.Find(CodeARechercher, LookIn:=xlValues, lookat:=xlWhole)
   If Not c Is Nothing Then
        Article = c.Cells.Offset(0, 1)
        Set m = Magasin.Find(Article, LookIn:=xlValues, lookat:=xlWhole)
        If Not m Is Nothing Then
            Box.Text = m.Cells.Offset(0, 1)
            c.Cells.Offset(0, 2) = m.Cells.Offset(0, 1)
        Else
            Box.Text = "Magasin non trouvé"
        End If
   Else
        Box.Text = "Code non trouvé"
   End If
   Delai CInt(Tempo.Text)
   Box.Text = ""
   CodeBarre.Text = ""
   CodeBarre.SetFocus
End Sub

Ami calmant, J.P

[VincentCA]

Bonsoir,
Une fois de plus, merci pour cette précieuse aide.
Serait il possible de faire évoluer le code afin que le numéro de la box s'affiche en grand (j'entends par là, la quasi totalité de l'écran) laissant juste un peu de place pour le réglage de la temporisation et la lecture du code barre.
En utilisant le mode zoom du code formulaire, j'ai pu agrandir la fenêtre mais je n'arrive pas à modifier la taille du texte à l'intérieur de la box.
Sinon, tout marche vraiment nikel.

Autre question, serait il possible sur une deuxième feuille de charger un fichier txt (qui s'ouvre sur bloc note) à partir d'une macro pour charger direct le fichier ? Puis la feuille 1 récupérerait les données nécessaire sur les colonne A et B pour faire fonctionner la macro go

Merci, merci
Bonne soirée.

[jurassic pork]

Hello,

Serait il possible de faire évoluer le code afin que le numéro de la box s'affiche en grand (j'entends par là, la quasi totalité de l'écran) laissant juste un peu de place pour le réglage de la temporisation et la lecture du code barre.

Le mieux c'est d'afficher le contenu du champ Box dans une autre fenêtre de dialogue (en mode non modal). Pourquoi sur la quasi totalité de l'écran, ça fait très gros ? . C'est pour lire à distance ? Le périphérique est une tablette ?
Dans le cas où l'on utilise une deuxième fenêtre de dialogue : où placer la première (en haut en bas à droite à gauche en dessous ? ou fenêtre semi transparente ? )

Autre question, serait il possible sur une deuxième feuille de charger un fichier txt (qui s'ouvre sur bloc note) à partir d'une macro pour charger direct le fichier ? Puis la feuille 1 récupérerait les données nécessaire sur les colonne A et B pour faire fonctionner la macro go

Je ne comprends pas trop -> qu'y a t il dans le fichier texte ?


Ami calmant, J.P

[VincentCA]

Bonjour tout le monde,
Je me permet de relancer mon post pour bénéficier d'une aide pour faire évoluer le fichier.

Serait il possible que la box qui s'affiche dans la fenêtre soit de la police (couleur) que la cellule magasin correspondante.
Ex si la cellule a une police en bleu, que box s'écrive en bleue. Si rouge, en rouge ?

Merci de votre aide,
Bonne journée

[Philippe Tulliez]

Bonjour,

Serait il possible que la box qui s'affiche dans la fenêtre soit de la police (couleur) que la cellule magasin correspondante.
Ex si la cellule a une police en bleu, que box s'écrive en bleue. Si rouge, en rouge ?

Rien de plus simple.
La propriété ForeColor d'un TextBox gère la couleur de la police de celui-ci et la propriété Font.Color fait de même pour un objet Range

Petit exemple à adapter à votre situation.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub UserForm_Activate()
  Me.TextBox1.ForeColor = ActiveCell.Font.Color
End Sub

[VincentCA]

Bonjour,

Merci. Je vais essayer de l'adapter a la situation.
J'espère que je vais y arriver car je suis nul en VBA...
Faudra sans doute que je l'appelle box.text

[VincentCA]

Private Sub UserForm_Activate()
Me.TextBox1.ForeColor = ActiveCell.Font.Color
End Sub

Bonjour,

Pourriez vous m'aider à placer ces lignes de code au bon endroit dans mon code svp.
J'ai essayé avec box.text mais ca ne fonctionne pas.
Merci d'avance,
Vincent

[Valtrase]

Salut,
J'ai pas trop suivi le post mais je pense que tu dois coller le code après avoir trouvé la cellule m

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
'...
'...
If Not m Is Nothing Then
Box.Text = m.Cells.Offset(0,1).Value
Box.ForeColor = m.Cells.Offset(0,1).ForeColor
c.Cells.Offset(0,2).Value = m.Cells.Offset(0,1).Value
Else
Box.Forecolor = vbBlack ' // A adapter ...
'...
'...

PS. Tu as les balises # pour inclure du code dans ton post utilises-les à la place d'un document Word.