VBA REGEXP Pattern

**Alain BENOIST** · 21/04/2022, 08h16

Bonjour,

je bloque sur la fonction RegExP en VBA.
Je cherche à supprimer une partie d'une chaine provenant d'un emploi du temps.
J'ai 2 cas de figure qui fonctionnent séparément, mais je n'arrive pas à trouver le bon pattern qui fonctionnerait pour les 2.

1° cas:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sChaine = "abc| 08:00 à 10:00 |def"

2° cas:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sChaine = "abc| 08:00 à 10:00"

j'ai défini un pattern comme suit:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sPattern = "..\d\d:\d\d à \d\d:\d\d.."

Cela fonctionne pour le 1° cas, mais pas pour le second.
Je voudrais supprimer tous ce qui est entre les 2 | (pipe), ou entre le pipe et la fin de chaine.
Je ne trouve pas le paramètre qui précise qu'un caractère est peut être présent ou non.

Merci pour votre aide, je ne maitrise pas très bien cette fonction.
Cordialement,
Alain

**jurassic pork** · 21/04/2022, 08h27

hello,
montre-nous ton code complet et la chaîne que tu veux obtenir.
A noter qu'il y a un sous-forum dédié aux Macros et code VBA.
Ami calmant, J.P

**Alain BENOIST** · 21/04/2022, 08h51

Bonjour Jurassic Pork,

merci pour ta célérité.
Je suis allé faire un tour sur ce forum, mais je n'ai pas trouvé la réponse.

Voici le code très limité, mais c'est un test avant intégration dans le vrai programme.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
Sub testREGEX()
    Dim sChaine1 As String
    Dim sChaine2 As String
    Dim fResult1 As Boolean
    Dim fResult2 As Boolean
    Dim sPattern As String
 
    ' Suppression de la plage d'horaire, | compris
    ' Il ne doit rester que soit abcdef, soit abc
 
 
    sChaine1 = "abc| 08:00 à 10:00 |def"
    sChaine2 = "abc| 08:00 à 10:00"
    sPattern = "..\d\d:\d\d à \d\d:\d\d.."
 
    fResult1 = REGEX_Test(sPattern, sChaine1)
    fResult2 = REGEX_Test(sPattern, sChaine2)
 
    sChaine1 = REGEX_Replace(sPattern, sChaine1, "", False, True)
    sChaine2 = REGEX_Replace(sPattern, sChaine2, "", False, True)
 
 
End Sub
 
' https://cafeine.developpez.com/access/tutoriel/regexp/
' https://www.developpez.net/forums/d2130886/logiciels/microsoft-office/excel/vba-regexp-pattern/#post11835975
 
' Pour utiliser Regex dans VBA, il faut d’abord définir la référence dans l’éditeur VBE.
' Dans l’éditeur VBE, aller dans Outils > Références > Microsoft VBScript Regular Expressions
 
Function REGEX_Test(sPattern As String, sString As String) As Boolean
    Dim oRegex As Object
    Set oRegex = New RegExp
 
    oRegex.Pattern = sPattern
 
    REGEX_Test = oRegex.Test(sString)
 
End Function
 
Function REGEX_Replace(sPattern As String, sOldString As String, sNewString As String, fGlobal As Boolean, fIgnoreCase As Boolean) As String
    Dim oRegex As Object
    Set oRegex = New RegExp
 
    oRegex.Pattern = sPattern
    oRegex.Global = fGlobal
    oRegex.IgnoreCase = fIgnoreCase
 
    REGEX_Replace = oRegex.Replace(sOldString, sNewString)
 
End Function

**jurassic pork** · 21/04/2022, 10h25

hello,
voici une solution qui capture deux groupes au maximum (dans le motif entre parenthèses).
Mon motif n'est peut-être pas optimal mais il a l'air de fonctionner avec tes chaînes d'essai :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub ExtractData()
sChaine1 = "abc| 08:00 à 10:00 |def"
sChaine2 = "abc| 08:00 à 10:00"
Debug.Print RecupChaine(sChaine1)
Debug.Print RecupChaine(sChaine2)
End Sub
 
Function RecupChaine(maChaine) As String
Dim res
Dim objReg As RegExp
Set objReg = New RegExp
objReg.Pattern = "(.+?)\|[^\|]+\|*(.*)$"
Set objMatches = objReg.Execute(maChaine)
For Each Match In objMatches             'The variable match will contain the full match
    a = Match.Submatches.Count           'total number of groups in the full match
    For i = 0 To a - 1
        'Debug.Print Match.Submatches.Item(i)  'display each group
        res = res & Match.Submatches.Item(i)
    Next
Next
RecupChaine = res
Set objReg = Nothing
End Function

Résultat :

abcdef
abc

**Pierre Fauconnier** · 21/04/2022, 15h49

Salut.

Tu veux absolument le réaliser par RegExp? VBA est outillé de base pour les cas que tu énonces.

Dois-tu garder les pipes?

Sans RegExp, voici une fonction qui réalise ce que tu souhaites:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function CleanText(Text As String) As String
  Dim ToClean As String
  Dim P1 As Long, P2 As Long
 
  P1 = InStr(1, Text, "|")
  If P1 <> 0 Then
    P2 = InStr(P1 + 1, Text, "|")
    If P2 = 0 Then
      CleanText = Left(Text, P1 - 1)
    Else
      CleanText = Replace(Text, Mid(Text, P1, P2 - P1 + 1), "")
    End If
  Else
    CleanText = Text
  End If
End Function

**Alain BENOIST** · 22/04/2022, 19h51

Bonjour à tous les deux,

merci pour vous réponses et conseils, mais aucune des solutions n'est satisfaisante.
Sur les exemples donnés, cela fonctionne, mais les chaines à modifier comportent d'autres informations séparées par d'autres pipes.

Je vais m'orienter vers la décomposition de mes chaines par un split et les traiter indépendamment.

Merci encore,
Alain

**Pierre Fauconnier** · 23/04/2022, 07h12

Envoyé par Alain BENOIST

[...]mais aucune des solutions n'est satisfaisante.[...]

Il est toujours plus fructueux d'expliquer le besoin en détails dès le début. Comme le disait JP, les solutions proposées reprenaient tes exemples avec un \ ou deux \. Les RegExp n'aiment pas l'approximation et, plus que le pattern "technique" en lui-même, c'est souvent l'expression même du besoin qui est "compliquée".

Tu ne couperas pas à l'expression claire de ton besoin, agrémentée d'exemples pertinents et si possible exhaustifs des cas rencontrés, quelle que soit la solution que tu voudras mettre en place. Ce n'est qu'au départ de l'expression claire et détaillée de ton besoin qu'il sera possible de choisir la meilleure voie de résolution (RegExp, split, ...).

**jurassic pork** · 23/04/2022, 08h43

Hello,

Envoyé par Alain BENOIST

merci pour vous réponses et conseils, mais aucune des solutions n'est satisfaisante.

Pierre a raison , si tu nous donnes pas tous les cas de figures, l'expression régulière ne fonctionnera pas forcément, elle doit être écrite en fonction des différents cas de figures et parfois ce n'est pas possible. Alors si tu peux nous donner d'autres cas de figures pour voir si cela est faisable en expression régulière.
Ami calmant J.P

**Alain BENOIST** · 23/04/2022, 10h43

Bonjour,

vous avez entièrement raison.
Mais il y a trop de cas possibles (2 à 6 données séparées par des pipes).
Je fais ce programme pour quelqu'un qui le maintiendra par la suite, mais qui débute en VBA.
L'emploi de regexp est déjà complexe pour moi, alors ce sera pire pour lui.

C'est pour cette raison que je vais rester simple et à sa portée en utilisant split.

A titre d'exemple, voici ce que je dois traiter, et récupérer quelques bribes dans chacun des items :

Encore merci pour votre aide et pour votre ténacité.
Alain

**jurassic pork** · 23/04/2022, 12h28

Avec ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub ExtractData()
sChaine1 = "abc| 08:00 à 10:00 | 08:00 à 10:00 | 08:00 à 10:00 |def"
sChaine2 = "xyz| 08:00 à 10:00"
sChaine3 = "Repas | 12:00 à 14:00"
sChaine4 = "Congés | 14:00 à 23:00"
sChaine5 = "Indisponible | 08:00 à 10:00 | piscine"
sChaine6 = "DIVERS | 08:00 à 10:00 | Lieu(x): BI 1014 EAO INTRANET BUR | Intervenant(s): Bousseau | Groupe(s): HORS CF [DFG] | Création | Cours de bureautique au profit de la SRP."
sChaine7 = "BUR 802 | 16:00 à 18:00 | Lieu(x): BI 0005 EAO INTRANET | Intervenant(s): Bousseau | Groupe(s): BAT4 D 356 (HL94) [411] | Validé | 1 enseignant guide les élèves."
Debug.Print RecupChaine(sChaine1)
Debug.Print RecupChaine(sChaine2)
Debug.Print RecupChaine(sChaine3)
Debug.Print RecupChaine(sChaine4)
Debug.Print RecupChaine(sChaine5)
Debug.Print RecupChaine(sChaine6)
Debug.Print RecupChaine(sChaine7)
End Sub
 
Function RecupChaine(maChaine) As String
Dim res
Dim objReg As RegExp
Set objReg = New RegExp
objReg.Pattern = "(.+?)\s*\|.*\|\s*(.+)$"
If objReg.Test(maChaine) Then
Set objMatches = objReg.Execute(maChaine)
For Each Match In objMatches             'The variable match will contain the full match
    a = Match.Submatches.Count           'total number of groups in the full match
    For i = 0 To a - 1
        'Debug.Print Match.Submatches.Item(i)  'display each group
        res = res & Match.Submatches.Item(i) & " : "
    Next
Next
Else
objReg.Pattern = "(.+?)\s*\|.*$"
Set objMatches = objReg.Execute(maChaine)
For Each Match In objMatches             'The variable match will contain the full match
    a = Match.Submatches.Count           'total number of groups in the full match
    For i = 0 To a - 1
        'Debug.Print Match.Submatches.Item(i)  'display each group
        res = res & Match.Submatches.Item(i) & " : "
    Next
Next
End If
RecupChaine = res
Set objReg = Nothing
End Function

Voici ce que j'obtiens :

abc : def :
xyz :
Repas :
Congés :
Indisponible : piscine :
DIVERS : Cours de bureautique au profit de la SRP. :
BUR 802 : 1 enseignant guide les élèves. :

C'est vrai qu'avec un split sur | c'est plus simple : si il n'y a que 2 éléments prendre le premier. Si il y a plus de 2 éléments prendre le premier et le dernier.

**Pierre Fauconnier** · 23/04/2022, 19h21

Salut.

perso, je m'orienterais vers Power Query

Nom : 2022-04-23_194801.png
Affichages : 601
Taille : 138,8 Ko

VBA REGEXP Pattern

Macros et VBA Excel

Vue hybride

Discussions similaires

Partager

Partager