Discussion :

[PJOUV]

Bonjour.
Je cherche, depuis une macro Word en VBA, à pouvoir tester l’état de la touche Verr Num (Num Lock) et éventuellement la modifier.
J’ai essayé plusieurs solutions :
• Pour connaître son état :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.NumLock

Cela semble fonctionner, encore que de façon étrange, puisque j’obtiens True quand la touche est désactivée, et False quand activée !
• Pour l’activer :
Je mets au début du module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Declare Function GetKeyState Lib "user32" (ByVal iVirtualKey As Integer) As Long

Puis dans la macro :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If GetKeyState(vbKeyNumlock) = 0 Then
     SendKeys "{NUMLOCK}"
End If

GetKeyState(vbKeyNumlock) renvoie plus logiquement « 0 » quand Numéro Lock est désactivé, « 1 » quand il est activé.
• Pour la désactiver :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If Not (Application.NumLock) Then ' Si activé.
     SendKeys "{NUMLOCK}"
End If

Le problème est que, dans ces deux derniers cas, le résultat est aléatoire. Ça peut marcher un moment, puis cela ne répond plus, la touche n’est pas modifiée.
Quelqu’un aurait-il une solution stable ?
Je suis sur Windows 7, Word 2010.
Merci d’avance.
Pjouv

[hyperion13]

Salut
Une probable solution ici

[PJOUV]

Bonjour !
Désolé pour la – très – tardive réponse !… Mais je pensais recevoir un message en cas de réponse à ma question – j’ai dû faire une fausse manipulation.
Merci beaucoup en tout cas, parmi les solutions que présentait votre lien, j’ai retenu celle-ci qui marche très bien.
Je la recopie à toutes fins utiles.
Merci encore.

Mettre dans un module le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
Option Explicit
' Code trouvé sur :
' https://stackoverflow.com/questions/38018232/send-keys-is-disabling-numlock
 
' API declarations
#If VBA7 And Win64 Then
    Private Declare PtrSafe Sub keybd_event Lib "USER32" ( _
                                ByVal bVk As Byte, _
                                ByVal bScan As Byte, _
                                ByVal dwflags As Long, _
                                ByVal dwExtraInfo As Long)
    Private Declare PtrSafe Function GetKeyState Lib "USER32" (ByVal nVKey As Long) As Integer
#Else
    Private Declare Sub keybd_event Lib "USER32" ( _
                                ByVal bVk As Byte, _
                                ByVal bScan As Byte, _
                                ByVal dwflags As Long, _
                                ByVal dwExtraInfo As Long)
    Private Declare Function GetKeyState Lib "USER32" (ByVal nVKey As Long) As Integer
#End If
 
'Constant declarations
Private Const VK_NUMLOCK = &H90
Private Const KEYEVENTF_EXTENDEDKEY = &H1
Private Const KEYEVENTF_KEYUP = &H2
 
'===================================================================
'PROPERTIES
'
 
'=========================================
'Returns the current Numlock state
Public Property Get Numlock() As Boolean
    Numlock = Numlock_State
End Property
 
'=========================================
'Sets the Numlock state
'   true = turn numlock on
'   false = turn numlock off
Public Property Let Numlock(State As Boolean)
    If State <> Numlock_State Then Numlock_Toggle
End Property
 
'===================================================================
'METHODS
'
 
'=========================================
'Returns the current Numlock state
Private Function Numlock_State() As Boolean
    DoEvents    'Required for key messages to be processed
    Numlock_State = CBool(GetKeyState(VK_NUMLOCK))
End Function
 
'=========================================
'Sets the Numlock state
'
'   State:  true = turn numlock on
'           false = turn numlock off
Private Sub Numlock_Set(State As Boolean)
    If State <> Numlock_State Then Numlock_Toggle
End Sub
 
'=========================================
'Toggles the Numlock state
Public Sub Numlock_Toggle()
    Dim previous_state As Boolean
    previous_state = Numlock_State
 
    keybd_event VK_NUMLOCK, &H45, KEYEVENTF_EXTENDEDKEY, 0  'Simulate Numlock key Press
    keybd_event VK_NUMLOCK, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0        'Simulate Numlock key Release
 
End Sub

Exemples d’utilisation donnés par l’auteur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Public Sub Example()
    'Turn Numlock on:
    Numlock = True
 
    'Turn Numlock off:
    Numlock = False
 
    'Check Numlock state:
    Dim IsOn As Boolean
    IsOn = Numlock
 
    'Toggle Numlock state:
    Numlock_Toggle
End Sub