Discussion :

[Stutak]

Bonjour,

je voudrais une petite macro pour effacer tous les onglets sauf les 2 premiers.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Sub test()
Dim nombre As Long
Dim itemtablo As String
 
nombre = Sheets.Count
 
   ReDim tablo(nombre) As String
    For j = 3 To nombre
        itemtablo = Sheets(j).Name
        tablo(j) = itemtablo
    Next j
      Sheets(itemtablo).Activate
     Sheets(Array(tablo)).Select
     ActiveWindow.SelectedSheets.Delete
 
End Sub

Excel me renvoie l'erreur d'éxécution 9 : l'indice n'appartient pas à la solution.
J'ai vérifié avec un msgbox, la variable itemtablo donne bien le nom de la feuille à chaque itération.

Je ne sais pas où ça coince, soit l'array ne se créé pas, soit ma commande est mal formulée.

Merci pour votre assistance

[Philippe Tulliez]

Bonjour,

je voudrais une petite macro pour effacer tous les onglets sauf les 2 premiers.

Vous voulez effacer les données des feuilles ou bien vous voulez supprimer celles-ci ?

Attention qu'il est toujours dangereux de travailler avec le n° des feuilles quand il s'agit de les supprimer ou d'effacer leurs données car le n° des feuilles dépend de la position de celles-ci dans le classeur. Il est préférable de désigner les feuilles par leur nom ou mieux encore en utilisant leur propriété CodeName

[Stutak]

Bonjour,

je voudrais supprimer les onglets.

Merci

[Philippe Tulliez]

Bonjour,
Voici un exemple qui supprime toutes les feuilles par leur position sauf la première et la deuxième du classeur où se trouve le code VBA. N'oubliez pas le risque d'utiliser les N° des feuilles comme expliqué dans ma première intervention.

Procédure à coller dans un module standard du classeur dans lequel se trouve les feuilles à supprimer. J'ai tout de même mis un message de confirmation par acquit de conscience.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub t()
  Dim n As Integer
  If MsgBox("Confirmation de la suppression des feuilles (sauf 1 et 2) du classeur " & ThisWorkbook.Name, vbInformation + vbYesNo + vbDefaultButton2) = vbYes Then
     Application.DisplayAlerts = False
     With ThisWorkbook
      For n = .Sheets.Count To 3 Step -1
       .Sheets(n).Delete
      Next
     End With
     Application.DisplayAlerts = True
  End If
End Sub

[Stutak]

Bonjour,

cette procédure marche impec.

Savez-vous pourquoi celle avec array ne passait pas ?

Merci

[Philippe Tulliez]

Bonjour,
Je n'ai pas examiné tout votre code mais pour supprimer des feuilles par leur numéro il faut partir de la dernière vers la première ou ici vers la troisième.

[Stutak]

Bonjour,

merci pour cette info que je ne connaissait pas.
mais même en inversant l'ordre, ma procédure ne fonctionne quand même pas.

Merci

[Philippe Tulliez]

Bonjour,

mais même en inversant l'ordre, ma procédure ne fonctionne quand même pas.

Comme je l'ai écrit, je n'ai pas regardé toute votre procédure. De toutes les manières, l'usage d'une variable tableau n'a pour moi aucun sens puisque vous utilisez une collection à l'aide d'une numérotation.

[Stutak]

Bonjour,

ok Merci

[Philippe Tulliez]

Bonjour,
La raison du problème que vous avez rencontré avec votre procédure est la suivante

• Un Array commence à 0 sauf si on précise en tête de module Option Base 1
• La variable tableau nommée Tablo étant déjà un array, il n'y a pas lieu d'utiliser la fonction Array pour sélectionner les feuilles à supprimer

Voici le code corrigé
En ligne 12, il y a lieu de remplacer la méthode Select par Delete pour supprimer les feuilles au lieu de les sélectionner

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub DelSheet()
  Const FirstSheet As Integer = 4 ' Première feuille A supprimer
  Dim Counter As Integer
  Dim N As Integer
  With ThisWorkbook
    ReDim Tablo(.Sheets.Count - FirstSheet)
    For N = FirstSheet To .Sheets.Count
      Tablo(Counter) = .Sheets(N).Name: Counter = Counter + 1
    Next
  End With
  Application.DisplayAlerts = False
  Sheets(Tablo).Select
  Application.DisplayAlerts = True
End Sub

Cependant, comme je l'ai précisé, il est extrêmement dangereux de supprimer des feuilles en se basant sur leur position dans le classeur.

Voici un exemple de suppression de toutes les feuilles du classeur où se trouve le code VBA, à l'exception de celles dont le CodeName est l'un des noms qui suit "Sht_Home", "Sht_Data" ou "sht_Parameter"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub DeleteSheet()
  Dim Sh As Object
  Application.DisplayAlerts = False
  For Each Sh In ThisWorkbook.Sheets
    With Sh
      Select Case .CodeName
        Case "Sht_Home", "Sht_Data", "sht_Parameter"
        Case Else: Sh.Delete
      End Select
    End With
  Next
  Application.DisplayAlerts = True
End Sub

Pour en savoir plus sur la propriété CodeName d'une feuille, à lire éventuellement mon billet sur le sujet: VBA – CodeName d’une feuille Excel