Discussion :

[mathieu.....]

Bonjour à toutes et à tous,

Je voudrais faire en sorte que mon code lit ma combobox.
En fonction de cette valeur ça recherche le mot dans le tableau en question et copie les données de la même ligne et le colle dans une autre feuille.

Si une âme charitable pouvait m'aider ça serait super gentil.

Merci beaucoup

Mathieu

[EricDgn]

Bonjour,

Si je comprends bien, vous avez un formulaire (userform) dans lequel vous avez fait une sélection dans une liste déroulante (combobox) et ensuite sur clic d'un bouton vous retrouve cela dans un tableau pour en recopier la ligne dans un autre. S'agit-il de tableaux structurés ou de plages? Le texte à retrouver se trouve-t-il dans une colonne particulière ou "n'importe où"?

Cordialement.

[BENNASR]

Une proposition
deux onglets et un userform
alim le combobox sans doublons / filtrer la base de données / envoyer les données dans l'onglet 2 / défiltrer l'onglet 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Private Sub CommandButton1_Click()
Dim filtre As String
Dim F1 As Worksheet
Dim F2 As Worksheet
Set F1 = Sheets("base")
Set F2 = Sheets("Recherche")
Application.ScreenUpdating = False
F2.Cells.ClearContents
filtre = ComboBox1.Value
F1.Range("A1:D" & F1.Range("A" & Rows.Count).End(xlUp).Row).AutoFilter Field:=1, Criteria1:=filtre
F2.Range("A1") = F1.Range("A1")
F2.Range("B1") = F1.Range("B1")
F2.Range("C1") = F1.Range("C1")
F2.Range("D1") = F1.Range("D1")
F1.Range("A2:D" & F1.Range("A" & Rows.Count).End(xlUp).Row).SpecialCells(xlCellTypeVisible).Copy Destination:=F2.Range("A2")
If F1.FilterMode = True Then F1.ShowAllData
 F2.Select
 Application.ScreenUpdating = True
 Unload Me
End Sub
 
 
 
Private Sub UserForm_Initialize()
 
Dim i As Integer
Dim dernLigne As Long
dernLigne = Sheets("base").Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To dernLigne
  ComboBox1 = Sheets("base").Range("A" & i)
  If ComboBox1.ListIndex = -1 Then ComboBox1.AddItem Sheets("base").Range("A" & i)
Next i
ComboBox1.Value = ""
End Sub

revenir pour commentaire du code si ça te convient

[mathieu.....]

Merci beaucoup, c'est exactement ce que j'avais besoin.

Bonne continuation!