Discussion :

[lucarno33]

Bonjour,

Je recopie une feuille entière d'un classeur vers un autre classeur. En faisant cela, je perds le format des cellules, notamment le format monétaire.

Est-ce possible de faire un copier coller en VBA qui conserve le format initial dans la cellule d'arrivée.

Je vous remercie de votre aide.
Luc

[Alex020181]

Bonjour,

Si le but est de reprendre toutes les données de la feuille avec toutes les mises en forme alors tu pourrais simplement dupliquer la feuille d'un classeur vers un autre. Ainsi tu gardes toutes les propriétés de cette feuille.

Cette solution t'irait ?

Sinon pour répondre à la question oui tu peux faire un copier coller par macro. Ce qui gardera valeurs et mises en forme. Mais c'est plutôt déconseillé car chronophage et tu perds le contenu du presse papier.

Pour le coup l'enregistreur de macro te donnera le code plus rapidement.

[hyperion13]

Salut
Une idée parmi tant d'autres avec cette méthode et ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Workbooks("Source.xlsx").Worksheets("Feuil").Range(Cells(1, 1), Cells(Range("A" & Rows.Count).End(xlUp).Row, Cells(1, Columns.Count).End(xlToLeft).Column)).Copy _
Workbooks("Cible.xlsx").Worksheets("Feuil1").Range("A1").PasteSpecial Paste:=xlPasteFormats

[Philippe Tulliez]

Bonjour,
S'il s'agit de copier une plage de cellules vers une destination quelconque (même feuille ou autre feuille existante d'un même classeur ou une feuille existante d'un autre classeur) soit l'équivalent d'un Ctrl C / Ctrl V, la méthode Copy avec l'argument Destination me semble la plus appropriée.

Si le but est de copier le contenu d'une feuille entière vers un autre classeur, la méthode Copy de l'objet Worksheet (Feuille de calcul) me semble la plus judicieuse

Exemple 1
Copie de la plage de cellule débutant en cellule A1 de la feuille nommée "Données" du classeur où se trouve le code VBA vers la cellule A4 de la première feuille du classeur nommé Target Data.xlsx déjà ouvert

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Exemmple_1()
  ' Déclaration et assignation des variables
  Dim rngSource As Range
  Dim rngTarget As Range
  Dim PathRoot As String
  Set rngSource = ThisWorkbook.Worksheets("Données").Range("A1").CurrentRegion
  Set rngTarget = Workbooks("Target Data.xlsx").Worksheets(1).Range("A4")
  ' Copie des données
  rngSource.Copy Destination:=rngTarget
  ' Fin
  Set rngSource = Nothing: Set rngTarget = Nothing
End Sub

Exemple 2
Copie d'un tableau structuré nommé "t_Data" présent dans le même classeur que celui où se trouve le code VBA vers la même destination que dans l'exemple 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Exemple_2()
  ' Déclaration et assignation des variables
  Dim rngSource As Range
  Dim rngTarget As Range
  Dim PathRoot As String
  Set rngSource = Range("t_Data").ListObject.Range
  Set rngTarget = Workbooks("Target Data.xlsx").Worksheets(1).Range("A4")
  ' Copie des données
  rngSource.Copy Destination:=rngTarget
  ' Fin
  Set rngSource = Nothing: Set rngTarget = Nothing
End Sub

Exemple 3
Copie de la feuille nommée "Données" du classeur où se trouve le code VBA vers une nouvelle feuille du classeur nommé Target Data.xlsx déjà ouvert

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Exemple_3()
  ' Déclaration et assignation des variables
  Dim shtSource As Worksheet
  Dim wkbTarget As Workbook
  Set shtSource = ThisWorkbook.Worksheets("Données")
  Set wkbTarget = Workbooks("Target Data.xlsx")
  ' Copie de la feuille
  With wkbTarget
   shtSource.Copy After:=.Worksheets(.Worksheets.Count)
  End With
  ' Fin
  Set shtSource = Nothing: Set wkbTarget = Nothing
End Sub