Discussion :

[michel.r06]

Bonjour,

Voila mon souci.
Je dois transformer un fichier TXT en HTML, jusque là pas de problème, mais en fonction du résultat de ma ligne dans le TXT je dois l'ecrire en couleur dons mon HTML en vert les OK et rouge les PB.
dons mon txt, il y a les lignes suivantes :

[10/09/2021] CONNECTION AU xxx.xxx.xxx.200 ------------------------------- OK
-----------------------------------------------------------------------------------------------------------------
[10/09/2021] CONNECTION AU xxx.xxx.xxx.201 --------------- OK
-----------------------------------------------------------------------------------------------------------------
[10/09/2021] CONNECTION AU xxx.xxx.xxx.202 ------------------- PB
-----------------------------------------------------------------------------------------------------------------
[10/09/2021] CONNECTION AU xxx.xxx.xxx.203 --------------- OK
-----------------------------------------------------------------------------------------------------------------
[10/09/2021] CONNECTION AU xxx.xxx.xxx.204 ------------------- PB
-----------------------------------------------------------------------------------------------------------------
[10/09/2021] CONNECTION AU xxx.xxx.xxx.205 --------------------------- OK
-----------------------------------------------------------------------------------------------------------------

mon code:

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Rem *************** Conversion HTML *******************
@ECHO OFF
SETLOCAL enabledelayedexpansion
SET "br=^<br^>"
SET "hr=^<hr^>"
SET "h1=^<h1^>"
SET "sh1=^</h1^>"
SET "bold=^<b^>"
SET "sbold=^</b^>"
SET "fcr=^<font color="red"^>"
SET "fcg=^<font color="green"^>"
set aa=%date:~6,4%
set mm=%date:~3,2%
set jj=%date:~0,2%
set DD=%jj%%mm%%aa%
set fichier=ping.log
 
(
FOR /f "delims=" %%i IN ('type %fichier%^|findstr /n "$"') DO (
SET line=%%i&CALL :test
)
)>pingcolor.html
 
exit
 
:test
:: remove line number from line
SET "line=%line:*:=%"
IF NOT DEFINED line ECHO(%br%&GOTO :EOF
SET "line2=%line:"=_%"
SET "line3=%line:"=%"
IF NOT "%line2%"=="%line3%" GOTO ecrire
IF "%line%"=="==="  ECHO(%hr%&GOTO :EOF
IF "%line:~0,5%"=="Date:"  ECHO(%bold%%line%%sbold%&GOTO :EOF
IF "%line:~0,2%%line:~-2%"=="****" ECHO(%h1%%line:~2,-2%%sh1%&GOTO :EOF
:ecrire
ECHO(%fcr%!line!%br%
GOTO :eof

je peux tout écrire en rouge ou en vert, mais je ne sais pas comment tester le PB ou le OK pour une sortie differentiée.
Merci de votre aide.

[Flammrock]

Tu peux faire comme ça :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
@echo off
setlocal enabledelayedexpansion
 
rem le fichier log
set file=ping.log
 
rem le fichier html
set htmlfile=pingcolor.html
 
 
 
rem on vide le fichier html
type nul > "!htmlfile!"
 
rem on itère sur chaque ligne du fichier
for /f "tokens=1,* delims=:" %%i in ('type "%file%"^|findstr /n "$"') do (
 
    set "line=%%~j"
 
    rem on construit la ligne
    call :buildline line htmlline
 
    rem on ajoute au fichier
    (
        echo;!htmlline!
    )>> "!htmlfile!"
)
 
exit
 
 
 
 
:buildline <in:line> <out:htmlline>
 
    rem h1
    echo;!%~1!|findstr /r /c:"^\*\*.*\*\*$" >nul 2>&1 && (
        set "%~2=<h1>!%~1:~2,-2!</h1>"
        exit /b
    )
 
    rem bold
    echo;!%~1!|findstr /r /c:"^Date:" >nul 2>&1 && (
        set "%~2=<b>!%~1!</b><br>"
        exit /b
    )
 
    rem hr
    echo;!%~1!|findstr /r /c:"^===$" >nul 2>&1 && (
        set "%~2=<hr>"
        exit /b
    )
 
    rem OK => green
    echo;!%~1!|findstr "OK" >nul 2>&1 && (
        set "%~2=<span style="color:green;">!%~1!</span><br>"
        exit /b
    )
 
    rem PB => red
    echo;!%~1!|findstr "PB" >nul 2>&1 && (
        set "%~2=<span style="color:red;">!%~1!</span><br>"
        exit /b
    )
 
    rem par defaut
    set "%~2=!%~1!<br>"
 
exit /b

[michel.r06]

Bonjour,

Merci c'est parfait.

cela répond à mes attente.

Merci encore