Discussion :

[69Pierre]

Bonjour.
Je n'ai visiblement rien compris des "cours" précédent.

Je parcours un répertoire et souhaite copier le fichier qui contient une chaine de caractères :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
REM sources
set REM_Folder="D:\Test_Package_2019_Package_REM"
REM destination
set Zip_Par_Serveur="D:\Test_Package_2019_Par_Serveur"
set WAS_Folder="%Zip_Par_Serveur%\serveur_WAS"
 
 
REM Partie de nom a chercher
set Expl="EXPLOI"
 
for /f %%a in (%REM_Folder%\*) do (
	if not x%%a:%Expl%==x%%a copy %%F %WAS_Folder%\%Expl%.zip  >> %logs%
	)

[barnabe0057]

Salut,

Je vois plusieurs erreurs :

- les paramètres de la boucle FOR
- la substitution via la variable de boucle
- le choix d'utiliser IF
- potentiellement les double-quotes autour de la chaîne à rechercher
- potentiellement les double-quotes autour des variables
- à quoi correspond la variable %%F ???

Si les fichiers à parcourir sont des fichiers zip je pense qu'il faudra les dézipper avant de pouvoir regarder à l'intérieur.

[69Pierre]

Salut,

Je vois plusieurs erreurs :

- les paramètres de la boucle FOR : aïe, aïe, aïe!
- la substitution via la variable de boucle : Ca c'est que je n'ai pas compris
- le choix d'utiliser IF
- potentiellement les double-quotes autour de la chaîne à rechercher
- potentiellement les double-quotes autour des variables
- à quoi correspond la variable %%F ??? J'enlève, c'est un reliquat de mes tests

Si les fichiers à parcourir sont des fichiers zip je pense qu'il faudra les dézipper avant de pouvoir regarder à l'intérieur : Je parcours un répertoire qui contient des zip et je cherche ceux qui ont dans leur nom la chaine de caractéres "EXPLOI" pour les copier.

[barnabe0057]

Ah ok il s'agit de rechercher dans le nom du fichier, je comprends mieux.

Voilà comment je ferais :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
REM sources
set "REM_Folder=D:\Test_Package_2019_Package_REM"
REM destination
set "Zip_Par_Serveur=D:\Test_Package_2019_Par_Serveur"
set "WAS_Folder=%Zip_Par_Serveur%\serveur_WAS"
 
 
REM Partie de nom a chercher
set "Expl=EXPLOI"
 
for %%A in ("%REM_Folder%\*.zip") do (
	echo %%~nA | findstr /LIC:"%Expl%" >nul && copy "%%~fA" "%WAS_Folder%\%Expl%.zip" >> %logs%
)

[69Pierre]

Balèze, ça marche...

Je laisse ouvert, je vais avoir des questions :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

echo %%~nA

Je ne comprends ni le echo, ni le ~a

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

findstr /LIC:

non plus

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

copy "%%~fA"

non plus

[barnabe0057]

Concernant les variables de substitution de la boucle FOR : admettons que tu as une variable %%I qui vaut toto.zip, pour récupérer le chemin du fichier tu peux faire appel à la variable %%~dpI

Voilà les valeurs que tu peux utiliser :

%~I - étend %I en supprimant les guillemets (")
%~fI - étend %I en nom de chemin d’accès reconnu
%~dI - étend %I en lettre de lecteur uniquement
%~pI - étend %I en chemin d’accès uniquement
%~nI - étend %I en nom de fichier uniquement
%~xI - étend %I en extension de fichier uniquement
%~sI - chemin étendu contenant uniquement des noms courts
%~aI - étend %I en attributs du fichier
%~tI - étend %I en date/heure du fichier
%~zI - étend %I en taille du fichier
%~$PATH:I - parcourt les répertoires de la variable
d’environnement PATH et étend %I en nom du
premier fichier reconnu trouvé. Si le nom de la
variable d’environnement n’est pas défini ou
que le fichier n’est pas trouvé par la recherche,
alors ce modificateur étend en chaîne vide

Donc pour récupérer uniquement le nom du fichier j'ai utilisé %%~nA, que j'ai transmis à FINDSTR via un echo et un pipe

Pareil pour la commande copy, j'avais besoin du chemin complet incluant le nom et l'extension du fichier, j'ai donc utilisé %%~fA qui est équivalent à %%~dpnxA