Discussion :

[Bastien13R]

Bonjour,

Je voudrais extraire le texte ci dessous, mais je n'y arrive pas.

Texte à extraire:
{"name":"Yakuza: Like a Dragon","api_id":"2300-16348","id":16348,"length_seconds":4526,"deck":"What happens ","video_type":"Quick Looks","youtube_id":"hR1FN_6ITEE","image":"vatar\/0\/31\/3253938-yakuza_like_a_dragon_ql.jpg"}

Source:
[{"name":"..."},{"name":"..."},{"name":"Yakuza: Like a Dragon","api_id":"2300-16348","id":16348,"length_seconds":4526,"deck":"What happens ","video_type":"Quick Looks","youtube_id":"hR1FN_6ITEE","image":"vatar\/0\/31\/3253938-yakuza_like_a_dragon_ql.jpg"},{"name":""}, ect ]

L'ensemble du texte est dynamique, à l'exception de "Quick Looks". J'ai réussi à extraire la partie droite du texte avec STXT, mais impossible d’extraire la partie gauche.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=STXT(A1;CHERCHE("Quick Looks";A1;1);CHERCHE(",{";A1;CHERCHE("Quick Looks";A1;1)+1)-CHERCHE("Quick Looks";A1;1))

Resultat: "Quick Looks","youtube_id":"hR1FN_6ITEE","image":"vatar\/0\/31\/3253938-yakuza_like_a_dragon_ql.jpg"}"

Comment faire? je suis perdu

Salutations,

[Pierre Fauconnier]

Salut

Principe:

1. On cherche la position du début de la chaine dans le json => Pos1;
2. A partir du début +1, on cherche la fin de la chaine "}" => Pos2;
3. On extrait une chaine de longueur Pos2-Pos1+1 à partir de Pos1.

=STXT(A1;CHERCHE("{""name"":""Yakuza";A1);CHERCHE("}";A1;CHERCHE("{""name"":""Yakuza";A1)+1)-CHERCHE("{""name"":""Yakuza";A1)+1)
Tu peux utiliser l'audit de formule pour décomposer le déroulement de la formule.

NB: Exclusivité 365: Si tu as la version XL365, tu peux utiliser LET et raccourcir ta fonction, car dans la formule donnée ci-dessus, tu remarqueras que l'on calcule 3 fois la position du début de la chaine. On pourrait donc utilement la stocker dans une variable de formule grâce à LET:
=LET(Pos;CHERCHE("{""name"":""Yakuza";A1);STXT(A1;Pos;CHERCHE("}";A1;Pos+1)-Pos+1))

Ceci dit, je ne comprends pas pourquoi tu demandes l'extraction de droite à gauche

[Pierre Dumas]

Bonjour

Je pense que la question soulevée par Bastien13R revient à chercher la position d'un caractère avant celle d'un autre caractère. Si j'ai bien compris, au final, il faut extraire toute la chaîne entre accolades autour de Quick Looks.



Comme vu dans l'image, j'ai décomposé afin que la démarche soit bien comprise, mais on peut tout mettre en une seule formule. La chaîne à extraire se trouve en B1.

Je cherche le nombre de caractères jusqu'à Quick Looks : =NBCAR(GAUCHE(B1;CHERCHE("Quick Looks";B1)))
Je cherche le nombre de caractères jusqu'à Quick looks sans les { : =NBCAR(SUBSTITUE(GAUCHE(B1;CHERCHE("Quick Looks";B1));"{";""))
J'en déduis le nombre de { jusqu'à Quick Looks : =B5-B6
Je substitue la précédente { par un § : =SUBSTITUE(B1;"{";"§";B7)
Donc la précédente { avant Quick Looks se trouve à la position : =CHERCHE("§";B8)
Sur le même principe, je substitue la prochaine } après Quick Looks par un § : =SUBSTITUE(B1;"}";"§";B7)
Donc la prochaine } se trouve à la position : =CHERCHE("§";B10)
D'où, finalement (ouf), la chaîne à extraire : =STXT(B1;B9;B11-B9+1)

Pour les fans, les masochistes, les malades, ou tout simplement ceux qui en ont besoin, voici le résultat en une seule formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
=STXT(B1;
            CHERCHE("§";SUBSTITUE(B1;"{";"§";NBCAR(GAUCHE(B1;CHERCHE("Quick Looks";B1)))-NBCAR(SUBSTITUE(GAUCHE(B1;CHERCHE("Quick Looks";B1));"{";""))));
            CHERCHE("§";SUBSTITUE(B1;"}";"§";NBCAR(GAUCHE(B1;CHERCHE("Quick Looks";B1)))-NBCAR(SUBSTITUE(GAUCHE(B1;CHERCHE("Quick Looks";B1));"{";""))))-CHERCHE("§";SUBSTITUE(B1;"{";"§";NBCAR(GAUCHE(B1;CHERCHE("Quick Looks";B1)))-NBCAR(SUBSTITUE(GAUCHE(B1;CHERCHE("Quick Looks";B1));"{";""))))+1)

NB : je viens de me rendre compte que l'on pouvait certainement réduire la formule pour aller chercher } après Quick Looks, mais j'ai la flemme.


En espérant que cela convienne.

Bonne journée

Pierre Dumas

[Pierre Fauconnier]

Salut Pierre


Je ne l'avais pas compris ainsi. On va voir ce que l'auteur a voulu dire

[Patrice740]

Bonjour Pierre,

Je substitue la précédente { par un § : =SUBSTITUE(B1;"{";"§";B7)

Dans ce cas, je n'utilise jamais un caractère suceptible d'exister dans une chaine standard, en général j'utilise CAR(1)
=SUBSTITUE(B1;"{";CAR(1);B7)

[Pierre Dumas]

Salut Pierre


Je ne l'avais pas compris ainsi. On va voir ce que l'auteur a voulu dire

Bonjour Pierre

Oui, je m'en étais rendu compte.
En tout cas, cela m'a permis de progresser car je ne savais pas bien faire cela avant.
J'aime bien répondre aux questions du forum car cela me pousse, me questionne sur des points que je n'envisageais pas et me permets de me perfectionner. C'est purement égoïste comme démarche

Bonne journée

Pierre

[Pierre Fauconnier]

@ Pierre,


En relisant le post initial, je pense effectivement qu'il faut raisonner comme tu le fais, puisque le demandeur parle bien de texte dynamique à l'exception de "Quick Looks"... Pour ce qui est d'apprendre, j'ai appris énormément en lisant et en répondant sur les forums (Le MPFE de Microsoft puis DVP depuis 17 ans). Et ce n'est pas égoïste puisque l'on partage nos connaissances sur le forum

@Patrice,

sur le choix du caractère.


@ Tous,

Excel 365 permet de retourner "+/- facilement" une chaine de caractères. Je l'ai montré dans ce billet qui extrait le nom d'un fichier de son chemin complet

[Bastien13R]

Bonjour à tous,

Je tenais à vous remercier avant de rentrer dans les détails! 🙏

@Pierre Dumas

Oui très bien résumé. Je cherche à extraire l'ensemble du texte compris entre les {} et contenant "Quick Looks".

Cependant, en analysant de plus prêt le fichier (j'avais oublié de le joindre désolé), j'ai pu observé qu'il pouvait y avoir plusieurs balises contenant "Quick Looks" selon les lignes, mais que la bonne commençait toujours par: {"name":"nom_du_jeu"...

On peut retrouver le nom du jeu en colonne B.

D'autre part j'avais vu que dans certaines lignes (5%), "Quick looks" était absent bien que la condition décrite plus haut s'appliqué.

Serait-il possible de prendre en compte ces variables dans la formule?

[Pierre Fauconnier]

Pourrais-tu préciser ta version d'Excel?

Power Query est équipé pour extraire des données d'un fichier json. Je m'orienterais vers cet outil plutôt que de tenter de créer un "parseur" par formule Excel...

Code json :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
[
{Prénom:"Alain", Nom:"Térieur",DN:"1994-05-04",Actif:true},
{Prénom:"Julie", Nom:"Hénas",DN:"1990-07-12",Actif:true},
{Prénom:"Jean", Nom:"Aymard",DN:"1967-12-04",Actif:true}
]

[Pierre Dumas]

Re,

+1 à Patrice aussi pour l'utilisation du caractère
+1 à Pierre pour l'utilisation de PowerQuery.

@Bastien13R
Je ne peux que pousser à utiliser la solution proposée par Pierre plutôt que de réinventer la roue par formule.
Si ce n'est pas possible, il faut mieux détailler ce qu'il y a dans le message 8.
Dans quelles lignes il y a plusieurs fois Quick Looks ?
Dans quelles lignes Quick Looks est absent ?
Dans quelle colonne est la chaîne à extraire ?
...

Bon après-midi

Pierre Dumas