Discussion :

[Patoche90]

Bonjour,

je cherche à faire un arbre binaire ou non sous VBA en utilisant des noeuds. Ce n'est pas pour faire une arborescence de répertoire, ni un arbre généalogique mais simplement organiser et hiérarchiser des données
J'ai rien trouvé de probant :
soit a partir d'un tableau
soit avec Treeview mais si j'ai bien compris je dois utiliser le contrôle treeview (dont je n'ai pas utilité dans ce cas)

Mais je n'ai pas trouvé une classe de type noeud avec laquelle je pourrais construire mon arbre
En fait j'imaginais quelque chose du type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Type Node
     Gauche as Node
     Droite as Node
     Donnee as MesDonnees
end Type

avec des méthodes
- AjouteNoeud
- SupprimeNoeud
- DonneValeur()
etc....

Si quelqu'un a une piste que je pourrais exploiter (exemple pouvoir appeler directement la collection Nodes, ....)

Merci de votre aide.

Cordialement.

[Pierre Fauconnier]

Salut.

Il faudrait en dire un peu plus, à mon avis.

• Quelles sont les données de départ?
• Sous quelle forme se présentent-elles?
• que veux-tu à l'arrivée?
• ...

[Patoche90]

Bonjour,

Les données de départ sont dans un ListObject que je retravaille.
Une activité = Ensemble de ligne repéré par un N_Ordre -> nommé activité élémentaire.
Chaque Ligne = Activité élémentaire qui peut-être relié a une autre par un lien de type prédecesseur (avec un décalage).
L'objectif est de créer un Arbre (binaire ou non) avec des noeuds pour retrouver la structure :
Racine : (N_Ordre = 0)
------ Activité parents
---------- Activité (enfant)
---------- Activité (enfant)
---------------Activité (feuille)
------ etc...

Le but est de remettre dans l'ordre la logique d’enchaînement des liens entre activités afin de faire les calculs nécessaires dans le bon ordre

J'espère avoir été plus clair.

Cordialement.

[Pierre Fauconnier]

Peux-tu mettre une copie d'écran de tout ou partie de ton tableau? La présentation "texte" dans le forum ne permet de bien comprendre ce que tu veux dire par "décalage".

Tu n'as pas dit comment tu voulais retrouver tes données après traitement... Peux-tu donner un exemple?

[Patoche90]

Bonjour,

Quand je parle de décalage, il s'agit du décalage de l'activité (lien Fin-Début), rien a voir avec la représentation.



En fait l'attendu est un objet de type ensemble de noeud structuré (cela peut-être un arbre) afin de balayer cet objet pour faire les calculs nécessaire.

[Patoche90]

Bonjour,

Cela semble répondre à mes attentes....
Je vais plonger dans le code pour l'adapter à mon usage.
Merci de m'avoir donner la direction ou je devais travailler.

Cordialement.

[Pierre Fauconnier]

Pour le fun, j'ai créé une classe Element. Je vais créer un élément Root et le peupler avec les données du tableau suivant, puis je supprimerai un des éléments du premier niveau (Sport):




Voici le code de la classe. J'utilise ici une collection. On aurait pu utiliser un Scripting.Dictionary mais on sort alors du VBA. Un Dictionary ira probablement plus vite sur de grands volumes de données.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Option Explicit
 
Public Name As String
Private mElements As Collection
 
Function Add(Name As String) As Element
  If Not Exists(Name) Then
    Set Add = New Element
    Add.Name = Name
    mElements.Add Add, Add.Name
  End If
End Function
 
Function Delete(Name) As Boolean
  Dim i As Long: i = 1
 
  Do While i <= mElements.Count And Not Delete
    Delete = UCase(mElements(i).Name) = UCase(Name)
    If Delete Then mElements.Remove i
  Loop
End Function
 
Function Exists(Name As String) As Boolean
  Dim i As Long: i = 1
 
  Do While i <= mElements.Count And Not Exists
    Exists = UCase(mElements(i).Name) = UCase(Name)
    i = i + 1
  Loop
End Function
 
Function getElement(Name As String) As Element
  Dim i As Long: i = 1
 
  Do While i <= mElements.Count And getElement Is Nothing
    If UCase(mElements(i).Name) = UCase(Name) Then Set getElement = mElements(i)
    i = i + 1
  Loop
End Function
 
Property Get Elements() As Collection
  Set Elements = mElements
End Property
 
Private Sub Class_Initialize()
  Set mElements = New Collection
End Sub

Voilà comment je peuplerais mon arbre, puis comment je supprimerais un élément (ici du Root, mais la classe est récursive, dont tu peux supprimer n'importe quel élément de l'arbre lorsque tu connais son parent):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Test()
  Dim Root As Element
  Dim Item As Element, SubItem As Element, SubSubItem As Element
  Dim i As Long
 
  Set Root = New Element
  Root.Name = "Racine"
  For i = 1 To Range("t_Data").Rows.Count
    Set Item = Root.getElement(Range("t_Data[Catégorie]")(i).Value)
    If Item Is Nothing Then Set Item = Root.Add(Range("t_Data[Catégorie]")(i).Value)
    Set SubItem = Item.getElement(Range("t_data[Sous-Catégorie]")(i).Value)
    If SubItem Is Nothing Then Set SubItem = Item.Add(Range("t_data[Sous-Catégorie]")(i).Value)
    Set SubSubItem = SubItem.getElement(Range("t_data[Elément]")(i).Value)
    If SubSubItem Is Nothing Then SubItem.Add (Range("t_data[Elément]")(i).Value)
  Next
 
  Root.Delete "Sport"
End Sub

Ici, on voit le Root peuplé de toutes les données, puis après la suppression de l'élément Sport