Discussion :

[pascalcom]

Bonjour,
J'ai vraiment du mal avec "Range(cells).
Cela fait un moment que je cherche mon erreur mais en vain. Je fais une recherche d'une cellule et je récupère (ligne colonne). Delà je veux récupérer une valeur et la copier dans une autre feuille. Tout va bien si je mets "nom1 = Range("B4") " la variable nom1 est bien retenue par contre en mettant " nom1 = Range(Cells(ligne - 1, Col)) " erreur "la méthode Range de l'objet a échoué".
Avez vous une idée de mon erreur?
Merci beaucoup pour votre aide
Portez vous bien
Pascal

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub recherche_match()

Application.ScreenUpdating = False
'Call DEpro
Dim MATCH As String 'MATCH
Dim nom1 As String '
Dim nom2 As String '
Dim x As Range
Dim plage As Range
Dim ligne As Integer
Dim Col As Integer

    Sheets("saisie").Select
    MATCH = Range("C4")
    
    Sheets("Tournoi32").Select
    Set x = Range("B4:B300,D4:D300,F4:F300").Find(MATCH, , xlValues, xlWhole, , , False)

    If Not x Is Nothing Then
        ligne = x.Row
        Col = x.Column
MsgBox MATCH 'test
MsgBox Col 'test
        
        nom1 = Range(Cells(ligne - 1, Col))
        'nom1 = Range("B4") 'test
MsgBox nom1 'test

        Sheets("saisie").Select
        Range("D4") = nom1
End If
End Sub

[BENNASR]

bonjour
je crois

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 nom1 = Cells(ligne - 1, Col)

au lieu de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 nom1 = Range(Cells(ligne - 1, Col))

autre chose
je crois qu'il est recommandé d'éviter les select, définir ton onglet de traitement à travers :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
dim F as worksheet
set F = Sheets("saisie")
'
'
 Set x = F.Range("B4:B300,D4:D300,F4:F300").Find(MATCH, , xlValues, xlWhole, , , False)
'
'

[Philippe Tulliez]

Bonjour,
Lorsqu'il sagit de définir une seule cellule, la syntaxe de Range et Cells est relativement simple

Pour les exemples ci-dessous, les plages concernées sont dans la feuille nommée db du classeur où se trouve le code VBA (ThisWorkbook) et donc la déclaration des variables objets sera la même pour tous les exemples

En tête de procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim sht As Worksheet
Dim rng As Range
Set sht = ThisWorkbook.Worksheets("db")

Exemples pour définir

• la cellule B4 avec Range

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  Set rng = sht.Range("B4")

• la cellule B4 avec Cells

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  Set rng = sht.Cells(4, 2)

• la plage de cellules A2:C7 avec Range

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  Set rng = sht.Range("A2:C7")

• la plage de cellules A2:C7 avec Range et Cells
  

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  1
  2
  3
  With sht
    Set rng = .Range(.Cells(2, 1), .Cells(7, 3))
  End With

[pascalcom]

Merci énormément pour votre aide.
Pourquoi faire compliquer quand on peut faire simple!
J'ose comment sélectionner plusieurs plages (Range() séparateur , ) mais cells?

Encore merci
Portez vous bien.
Pascal

[Philippe Tulliez]

Bonjour,

J'ose comment sélectionner plusieurs plages (Range() séparateur , ) mais cells?

Pour définir une variable objet de type Range dont les plages ne sont pas contiguës

• Exemple avec Range
  

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  Set rng = sht.Range("A2:C6, F2:G6, K2:M6")

• Exemple avec la combinaison Range et Cells
  

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  1
  2
  3
  4
  With sht
    Set rng = Application.Union(.Range(.Cells(2, 1), .Cells(6, 3)), .Range(.Cells(2, 5), .Cells(6, 7)), .Range(.Cells(2, 11), .Cells(6, 13)))
    Debug.Print rng.Address
  End With