Problème avec TIMEOUT et BITSADMIN

**Anarown** · 29/11/2020, 14h14

Bonjour à tous,

Je crée actuellement une petite interface pour le programme youtube-dl.exe sous DOS et je rencontre deux problème que je n'arrive pas à solutionner

1) TIMEOUT ligne 19 qui me retourne un "'TIMEOUT' n’est pas reconnu en tant que commande interne ou externe, un programme exécutable ou un fichier de commandes."
2) START ligne 15 que j'aimerais remplacer par une commande du type "bitsadmin", "powershell" ou "VBS"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

bitsadmin /transfer "youtube-dl" https://youtube-dl.org/downloads/latest/youtube-dl.exe C:\Users\Admin\Downloads\youtube-dl.exe

lui me retourne une erreur 403: "0x80190193 - État HTTP 403*: Le client n’a pas les droits d’accès suffisants à l’objet serveur demandé".

Ou powershell

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

powershell -Command Invoke-WebRequest https://youtube-dl.org/downloads/latest/youtube-dl.exe -OutFile C:\Users\Admin\Downloads\youtube-dl.exe

lui ne me retourne strictement rien mais ne fonctionne pas non plus.

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
@ECHO OFF
TITLE Icarus.bat (v2020.11.29)
COLOR 09
 
SET SOURCEPATH=%~dp0
SET PATH=C:\Icarus
SET MYPROCESS=youtube-dl.exe
CD "%SOURCEPATH%"
 
IF EXIST "%PATH%\data\%MYPROCESS%" GOTO MENU
MD "%PATH%\data"
MD "%PATH%\download"
COPY /Y "%SOURCEPATH%\Icarus.bat" "%PATH%\Icarus.bat"
IF EXIST "%USERPROFILE%\Downloads\%MYPROCESS%" COPY /Y "%USERPROFILE%\Downloads\%MYPROCESS%" "%PATH%\data\" && GOTO MENU
START /MIN explorer https://youtube-dl.org/downloads/latest/youtube-dl.exe
 
:DL
CLS
TIMEOUT /T 1 /NOBREAK
IF EXIST "%USERPROFILE%\Downloads\%MYPROCESS%" MOVE /Y "%USERPROFILE%\Downloads\%MYPROCESS%" "%PATH%\data\" && GOTO ENDL
GOTO DL
 
:ENDL
START %PATH%\Icarus.bat
EXIT
 
:MENU
CD "%PATH%\"
CLS
ECHO     ____                    
ECHO    /  _/______ _______ _____
ECHO   _/ // __/ _ `/ __/ // (_-(
ECHO  /___/\__/\_,_/_/  \_,_/___/
ECHO              Y-DL Interface
ECHO.
SET /p "LINK=> Link : "
ECHO.                                             
"%PATH%\data\%MYPROCESS%" -f best --geo-bypass -i --yes-playlist "%LINK%"
 
IF NOT EXIST "%PATH%\*.mp3" IF NOT EXIST "%PATH%\*.mp4" GOTO BAD
IF EXIST "%PATH%\*.mp3" MOVE /Y "%PATH%\*.mp3" "%PATH%\download\" && GOTO GOOD
IF EXIST "%PATH%\*.mp4" MOVE /Y "%PATH%\*.mp4" "%PATH%\download\" && GOTO GOOD
 
:GOOD
ECHO.
ECHO Finish !
ECHO x=msgbox("Download complete !" ,64, "Icarus") > "%PATH%\data\msgbox.vbs"
"%PATH%\data\msgbox.vbs"
DEL /Q "%PATH%\data\msgbox.vbs"
START explorer "%PATH%\download\"
GOTO MENU
 
:BAD
ECHO.
ECHO Error !
ECHO x=msgbox("Download or Link error !" ,16, "Icarus") > "%PATH%\data\msgbox.vbs"
"%PATH%\data\msgbox.vbs"
DEL /Q "%PATH%\data\msgbox.vbs"
GOTO MENU
 
REM ############################################################################
REM #                                                                          #
REM #  Icarus is a small DOS (Windows 32/64bits) interface for youtube-dl.exe  #
REM #  Icarus : https://youtu.be/p1kAi19F3xA                                   #
REM #  youtube-dl : https://youtube-dl.org/                                    #
REM #                                                                          #
REM #  Installation :                                                          #
REM #  1. Copy paste this page in Notepad and save it in "Icarus.bat"          #
REM #  2. Launch "Icarus.bat"                                                  #
REM #                                                                          #
REM #  bitcoin : bc1qhu42g3zzuj6kdzdxt7aqegczp4zwf459vpjy8a                    #
REM #  Cont@ct : icarus@mail.com                                               #
REM #                                                                          #
REM ############################################################################

Merci pour toute aide apportée :)

Pour ceux qui veulent suivre le projet : http://nihilnp.cluster029.hosting.ov...rus/icarus.txt

**Anarown** · 30/11/2020, 11h19

J'ai essayé avec un script VBS tant qu'à faire que j'ai trouvé ici: https://www.developpez.net/forums/d9.../#post11653217

Code Vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Dim strFileURL,strHDLocation
' Tes paramètres
    strFileURL = "http://definitions.symantec.com/defs/symcdefsi64.exe"
    strHDLocation = "C:\Temp\symcdefsi64.exe"
' Récupérer le fichier
    Set Ws = CreateObject("WScript.Shell")
    Set objXMLHTTP = CreateObject("MSXML2.XMLHTTP")
    objXMLHTTP.open "GET", strFileURL, false
    objXMLHTTP.send()
If objXMLHTTP.Status = 200 Then
Set objADOStream = CreateObject("ADODB.Stream")
objADOStream.Open
objADOStream.Type = 1 'adTypeBinary
objADOStream.Write objXMLHTTP.ResponseBody
objADOStream.Position = 0    'Set the stream position to the start
Set objFSO = Createobject("Scripting.FileSystemObject")
If objFSO.Fileexists(strHDLocation) Then objFSO.DeleteFile strHDLocation
Set objFSO = Nothing
objADOStream.SaveToFile strHDLocation
objADOStream.Close
Set objADOStream = Nothing
End If
Set objXMLHTTP = Nothing 
'Ws.Run strHDLocation 'ici si vous voulez exécuter le fichier téléchargé ou non
Set WS = Nothing

Mais il me retourne aussi une erreur, des idées ?

**barnabe0057** · 30/11/2020, 14h17

Bonjour,

1) Apparemment la commande TIMEOUT n'est pas présente sur ton système, à la place tu peux utiliser

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

ping -n 1 localhost >nul

2) Je n'ai pas la solution concernant BITSADMIN ou Powershell, par contre avec la commande curl je n'ai pas de problème :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

curl -L --max-time 60 -# -k --output youtube-dl.exe "https://yt-dl.org/downloads/latest/youtube-dl.exe"

**Anarown** · 30/11/2020, 14h32

Envoyé par barnabe0057

Bonjour,

1) Apparemment la commande TIMEOUT n'est pas présente sur ton système, à la place tu peux utiliser

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

ping -n 1 localhost >nul

Justement je viens de prendre une screen pour mieux expliquer le problème, on peut clairement voir qu'en CMD externe la commande est bien présente mais elle ne fonctionne pas dans mon .bat, hors dans une version antérieur elle fonctionnait correctement, je ne sais pas ce que j'ai changer dans mon code pour qu'elle ne fonctionne plus..

Merci beaucoup pour l'aide apportée, je test tout ça et je clôture la discussion si c'est ok.

**barnabe0057** · 30/11/2020, 14h37

Je viens de comprendre, TIMEOUT ne fonctionne plus car tu as modifié la variable d'environnement %PATH%, tu devrais utiliser un autre nom pour ta variable.

**Anarown** · 30/11/2020, 16h07

Merci énormément, la commande CURL fonctionne parfaitement après avoir comme tu dis, rename ma variable.
La commande CURL me permet d'enlever quelque ligne de code, notamment ma boucle DL et la commande TIMEOUT par la même occasion ^^

Encore un grand merci pour l'aide apportée ! :)

Problème avec TIMEOUT et BITSADMIN [Batch]

Scripts/Batch

Vue hybride

Discussions similaires

Partager

Partager