Discussion :

[retraite83]

Bonjour,

par curiosité j'ai testé 2 boucles de Range pour copier une cellule dans une autre

Une 1ere boucle en faisant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil1.Range("A" & lig) = Feuil1.Range("B" & lig)

Une seconde en faisant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil1.Range("B" & lig).Copy Feuil1.Range("A" & lig)

La seconde boucle est beaucoup plus rapide, j'ai peut être lu une explication, la 1ere boucle passe par le presse papier pas la seconde ?

[Alex020181]

Bonjour,

La seconde est plus rapide ? Pas la première ?

Pour ma part je pencherait pour la première...

.copy (la seconde) passe par le presse papier comme vous l'avez vu (=copier/coller). La première duplique directement sans faire l'étape de la copie.

[Patrice740]

Bonjour,

Aucune de ces boucles passe par le presse-papier !

Par contre la première est bien plus rapide, elle ne copie que les valeurs, que la seconde qui copie tout (valeurs, formats, commentaires, validations, ...) :
Essaies ce test :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Option Explicit
Sub test()
Dim lig As Long
Dim t0 As Single, t1 As Single, t2 As Single, t3 As Single, t4 As Single
 
  DoEvents
  Application.ScreenUpdating = False
    t0 = Timer
    For lig = 1 To 400
      Feuil1.Range("A" & lig).Value = Feuil1.Range("B" & lig).Value
    Next lig
    t1 = Timer - t0
  DoEvents
    t0 = Timer
    For lig = 1 To 400
      Feuil1.Range("B" & lig).Copy Feuil1.Range("A" & lig)
    Next lig
    t2 = Timer - t0
  DoEvents
  Application.Calculation = xlCalculationManual
    t0 = Timer
    For lig = 1 To 400
      Feuil1.Range("A" & lig).Value = Feuil1.Range("B" & lig).Value
    Next lig
    t3 = Timer - t0
  DoEvents
    t0 = Timer
    For lig = 1 To 400
      Feuil1.Range("B" & lig).Copy Feuil1.Range("A" & lig)
    Next lig
    t4 = Timer - t0
  Application.Calculation = xlCalculationAutomatic
 
  MsgBox "Boucle 1 avec calcul : " & t1 & vbCr & _
         "Boucle 2 avec calcul : " & t2 & vbCr & _
         "Boucle 3 sans calcul : " & t3 & vbCr & _
         "Boucle 4 sans calcul : " & t4
 
End Sub

Les DoEvents réduisent les chances que Windows reprenne la main pendant la boucle (volontairement réduite) mais si tu exécutes la boucle plusieurs fois tu verras que ça arrive parfois (le temps de la boucle 1 est alors différent de celui de la 3), l'écart entre la 2 et la 4 dépend des formules dans la feuille.

[Alex020181]

Le .copy copie la valeur dans le presse papier.
J'ai créé un fichier de 50 000 lignes pour test et ouvert un bloc note.

Pendant que la macro .copy tournait j'ai fait plusieurs ctrlv dans le bloc note et Windows collait la valeur de la cellule Excel. Donc le presse papier est bien utilisé.

[Philippe Tulliez]

Bonjour Alex,

Le .copy copie la valeur dans le presse papier.

Je pense qu'il existe une différence entre la méthode Copy avec ou sans l'argument Destination
Si l'on fait un Copier/Coller classique, la copie passe par dans le presse papier. En revanche si l'on place le curseur de la souris sur l'un des côtés de la plage à copier ou a déplacer (le pointeur de la souris devient une croix avec flèches) et que l'on déplace, je pense que cela ne passe pas par le presse papier. Il suffit de faire un Ctrl + V pour s'en convaincre
L'enregistreur de macros génère d'ailleurs un autre code en proposant Copy Destination:=

[retraite83]

#3

je pensai qu'il fallait ajouter .Value pour ne copier que les valeurs ?

[Patrice740]

je pensai qu'il fallait ajouter .Value pour ne copier que les valeurs ?

Non, quand tu écris :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil1.Range("A" & lig) = Feuil1.Range("B" & lig)

C'est pareil, en moins formel, que quand j'écris :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil1.Range("A" & lig).Value = Feuil1.Range("B" & lig).Value

Car .Value est la propriété par défaut de l'objet Range.

[Patrice740]

Le .copy copie la valeur dans le presse papier.

Effectivement, lors du .copy destination, la copie est aussi envoyée au presse papier, en même temps que dans la plage de destination.
Mais la copie ne passe pas du presse papier contrairement au cas où on utilise .copy puis .paste :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit
Sub test()
Dim lig As Long
Dim t0 As Single, t1 As Single, t2 As Single, t3 As Single, t4 As Single
 
  DoEvents
  Application.ScreenUpdating = False
    t0 = Timer
    For lig = 1 To 400
      Feuil1.Range("B" & lig).Copy Feuil1.Range("A" & lig)
    Next lig
    t1 = Timer - t0
  DoEvents
    t0 = Timer
    For lig = 1 To 400
      Feuil1.Range("B" & lig).Copy
      Feuil1.Paste Range("A" & lig)
    Next lig
    t2 = Timer - t0
 
  MsgBox "Boucle 1 avec calcul : " & t1 & vbCr & _
         "Boucle 2 avec calcul : " & t2
 
End Sub