Discussion :

[CeluiQuiCherche]

Bonjour,

plusieurs fois, je me suis trouvé confronté à un petit problème sans en trouver d'explication.

La question est dans l'exemple ci-après, pourquoi la ligne 19 (coche = ws.CheckBox1) ne fonctionne pas ?

Je suppose que c'est dû au type d'objet pour lequel je n'a pas utilisé la bonne syntaxe...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub test()
 
    Dim ws As Worksheet
    Dim val As Double
    Dim coche As Boolean
 
    Set ws = ThisWorkbook.Worksheets("Feuil1")
 
    'OK
    val = hisWorkbook.Worksheets("Feuil1").Range("A1")
 
    'OK
    val = ws.Range("A1")
 
    'OK
    coche = ThisWorkbook.Worksheets("Feuil1").CheckBox1
 
    'Pas OK
    coche = ws.CheckBox1
 
    Set ws = Nothing
End Sub

Si quelqu'un pouvait m'expliquer ou m'indiquer un tuto, j'en serai fort reconnaissant.

Cordialement.

[Patrice740]

Bonjour,

Avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
    'OK
    coche = ThisWorkbook.Worksheets("Feuil1").OLEObjects("CheckBox1").Object.Value
 
    'OK
    coche = ws.OLEObjects("CheckBox1").Object.Value

[CeluiQuiCherche]

Merci beaucoup pour la syntaxe correcte.

Mais a-t-on l'explication du fait que coche = ThisWorkbook.Worksheets("Feuil1").CheckBox1 fonctionne alors que coche = ws.CheckBox1 ne fonctionne pas?

[Patrice740]

Mais a-t-on l'explication du fait que "coche = ThisWorkbook.Worksheets("Feuil1").CheckBox1" fonctionne alors que "coche = ws.CheckBox1" ne fonctionne pas?

Non, pas d'explication, sinon que la première ne devrait pas fonctionner, mais VBA accepte beaucoup de choses étranges ...
C'est peut-être lié au fait qu'il est aussi possible de passer par les CodeName :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    coche = Feuil1.CheckBox1.Value

[Pierre Fauconnier]

Salut.

Tout a (presque) toujours une explication

En fait, CheckBox1 n'est pas une propriété de l'objet Worksheet, ni de l'objet Worksheets("Feuill1") qui est un worksheet, mais bien de l'objet Feuil1 (si le codename = name).
Si tu utilises worksheets("Feuil1").CheckBox, le compilateur voit que tu travailles avec une collection. Il va laisser passer parce qu'il ne sait pas exactement avec quoi tu vas travailler, une collection n'étant pas typée. Mais il y aura une erreur à l'exécution car worksheets("Feuil1") pointe vers un worksheet et un worksheet n'expose pas la propriété CheckBox.

Si à gauche du point, tu utilises Feuil1 ou une variable typée Feuil1, tu n'as pas de problèmes car le compilateur regarde non pas "un objet Worksheet" mais l'objet particulier Feuil1, et il dit "ok, il y a une propriété CheckBox pour cet objet", et il passe.

Si tu utilises ws en tant que worksheet, au moment de la compilation, le compilateur ne sait pas que plus tard, à l'exécution, ws pointera vers Feuil1. Il regarde donc un objet Worksheet, et pas un objet Feuil1, et il dit: "Pas bon. Un objet worksheet ne possède pas de propriété Checkbox, je bloque".

Dans l'héritage des objets, on a Object, puis Worksheet qui hérite de Object et qui précise les propriétés et méthodes utilisables par un worksheet, puis Feuil1, qui hérite de worksheet et donc de ses propriétés et méthodes et qui expose les siennes en plus, dont l'ActiveX CheckBox1.

[Patrice740]

Bien vu Pierre, bonne explication

Ça fonctionne en déclarant le bon objet, celui qui contient le checkbox :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub test()
Dim ws As Feuil1
  Set ws = Feuil1
  coche = ws.CheckBox1
End Sub

[CeluiQuiCherche]

Merci Pierre pour cette explication très précise. J'ai tout compris.

je butais régulièrement sur 2 ou 3 phénomènes de ce genre aussi bien sur VBA Excel que VBA Access. Je comprend mieux maintenant.