Discussion :

[shepard01]

Bonjour,

Je fait régulièrement la même chose: recopier des données d'un formulaire PDF dans un document Word.

J'aimerai donc avoir des pistes pour pouvoir "transposer" des informations dans un formulaire PDF (adobe) vers un fichier Word de manière automatique.

Un exemple : Dans mon formulaire PDF j'ai le champ "Nom :" et dans mon template Word j'ai un tableau avec une ligne "Nom_client : ". Quelles actions me permettraient d'automatiser cela (sans à avoir en envoyer le document Word directement aux personnes évidement ou encore de convertir le .pdf en .docx ^^)

Merci de m'avoir lu jusque ici,

[Invité]

Bonjour,

Si le contenu du fichier pdf est collé sur un document Word, le code ci-dessous peut vous aider à récupérer des informations dans le document.

• La variable RenseignementsPdf2 permet de définir les renseignements à recueillir. Cette variable est à compléter avec autant de valeurs que nécessaire.
• La variable tableau ChainesATrouver contient les chaînes à rechercher dans chacun des paragraphes.
• La fonction SansCaracteresSpeciaux permet d'enlever les caractères parasites dont les fins de paragraphe et les retours chariots.

Le résultat n'est pas optimum.

J'ai pris cet exemple :
Pièce jointe 546499

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
 
Option Explicit
 
Type RenseignementsPdf2
     ClientNom As String
     ClientAdresse As String
     ClientVille As String
End Type
 
 
Sub RecupererUneinfo()
 
Dim RenseignementsPdf As RenseignementsPdf2
Dim DocEnCours As Document
Dim I As Integer, J As Integer
Dim TexteParagraphe As String
Dim ChainesATrouver As Variant, ChainesTouvees As Variant
 
    ChainesATrouver = Array("Nom", "Adresse", "Ville")
 
    Set DocEnCours = ActiveDocument
    With DocEnCours
         For I = 1 To .Paragraphs.Count
             With .Paragraphs(I)
                  TexteParagraphe = Trim(SansCaracteresSpeciaux(.Range.Text))
                  For J = LBound(ChainesATrouver) To UBound(ChainesATrouver)
                      If Mid(TexteParagraphe, 1, Len(ChainesATrouver(J))) = ChainesATrouver(J) Then
                         ChainesTouvees = Split(TexteParagraphe, ChainesATrouver(J))
                         Select Case ChainesATrouver(J)
                                Case "Nom"
                                     RenseignementsPdf.ClientNom = Trim(Join(ChainesTouvees, " "))
                                Case "Adresse"
                                     RenseignementsPdf.ClientAdresse = Trim(Join(ChainesTouvees, " "))
                                Case "Ville"
                                     RenseignementsPdf.ClientVille = Trim(Join(ChainesTouvees, " "))
                         End Select
                  End If
                Next J
             End With
         Next I
    End With
 
    With RenseignementsPdf
         Debug.Print "Nom : " & .ClientNom & ", adresse : " & .ClientAdresse & ", ville : " & .ClientVille
    End With
 
    Set DocEnCours = Nothing
 
End Sub
 
 
Function SansCaracteresSpeciaux(ByVal ChaineATraiter As String) As String
 
Dim I As Integer
 
    SansCaracteresSpeciaux = ""
    For I = 1 To Len(ChaineATraiter)
        Select Case Mid(ChaineATraiter, I, 1)
               Case ":", Chr(10), Chr(13)
 
               Case Else
                    SansCaracteresSpeciaux = SansCaracteresSpeciaux & Mid(ChaineATraiter, I, 1)
        End Select
    Next I
 
End Function

[shepard01]

Bonsoir,

Merci de votre réponse. Finalement, je suis peut-être sur la mauvaise voie. J'essaye de conceptualiser un petit projet.

J'ai un formulaire PDF avec des infos et un tableau. J'aimerai envoyer ce tableau du formulaire PDF vers un fichier Excel et les autres informations du formulaire vers un document Word (rapport.docx). Ensuite, j'aimerai envoyer les tableaux et d'autres données supplémentairement du fichier Excel vers le document Word (rapport.docx).

Serait-il plus judicieux d'exporter les données PDF vers une sorte de bases de données, les données Excel vers cette même base de données et une fois la base de données complètes, générer le fichier Words ?


Merci