Discussion :

[mouftie]

Bonjour,

Les administrateurs doivent ouvrir une liste de fichiers, par des liens hypertextes, à partir d'un fichier mère qui contient toutes les macros (un par un), les déverrouiller (toutes les feuilles) et faire leur traitement.

Une fois ouvert, je voudrais automatiser le déverrouillage du classeur.
J'ai écrits une macro qui fonctionne, j'ai mis un bouton dans le fichier mère, mais il me manque le lien entre le fichier mère et le fichier de destination.
Je pensais utiliser un inputbox pour demander à l'administrateur de sélectionner une cellule dans le fichier de destination...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set DeV = Application.InputBox(prompt:="Cliquer sur le fichier de l'agence à déverrouiller", _ Type:=8)

Mais après je ne sais pas comment récupérer le nom du fichier qui apparait dans l'inputbox au moment de la sélection, avant les références de la cellule ?

Est-ce que qq'un peut m'aider, svp ?
Merci

[mfoxy]

Bonjour,

Il existe quelque chose de bien plus simple pour l'ouverture d'un fichier, le "application.FileDialog.

https://docs.microsoft.com/en-us/off...ion.filedialog

Bàt

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub UseFileDialogOpen()
 
    Dim lngCount As Long
 
    ' Open the file dialog
    With Application.FileDialog(msoFileDialogOpen)
        .AllowMultiSelect = True
        .Show
 
        ' Display paths of each file selected
        For lngCount = 1 To .SelectedItems.Count
            MsgBox .SelectedItems(lngCount)
        Next lngCount
 
    End With
 
End Sub

[mouftie]

Bonsoir mfoxy,

Merci pour ta réponse, mais le répertoire où se trouve les fichiers à ouvrir est un répertoire caché, donc les administrateurs ne peuvent pas le chercher et ce n'est pas plus simple

[Menhir]

Mais après je ne sais pas comment récupérer le nom du fichier qui apparait dans l'inputbox au moment de la sélection, avant les références de la cellule ?

C'est très simple: c'est une référence de cellule. Elle doit donc être traité comme telle.

Par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Workbooks.Open("C:\MonChemin\" & DeV.Text)

Cela dit, ne sachant pas exactement ce que contient ta cellule, je ne peux pas garantir que cette réponse est fiable.
Teste-la pour confirmer.

[mouftie]

Bonsoir Menhir,
Merci pour ta réponse.

Voilà le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub DeVerrAgc()
'Déprotection de toutes les feuilles d'1 fichier 
Dim NbFl As Integer, DeV As Range, WbDev As Variant
 
Set DeV = Application.InputBox(prompt:="Cliquer sur le fichier de l'agence à déverrouiller", Type:=8)
    If DeV Is Nothing Then Exit Sub
WbDev = DeV.Text
NbFl = ActiveWorkbook.Sheets.Count
WbDev.Activate
For i = 1 To NbFl
    Worksheets(i).Unprotect Password:="MdPV"
    Worksheets(i).Range("A1").Interior.ColorIndex = 43   'Couleur verte
Next i  '***** FIN Protection
'Si nécessaire, on masque la feuille Données.
If Sheets("Données").Visible = False Then Sheets("Données").Visible = True
End Sub

Quand l'administrateur clique sur une cellule du classeur à déverrouiller, il y a une info du genre

'[Rd AGENCE 321.xlsm]SAISIES'!$M$2

et moi, je voudrais récupérer Rd AGENCE 321.xlsm

Avec WbDev = DeV.Text, j'ai récupéré Null...

Merci pour ton aide

[Menhir]

Quand l'administrateur clique sur une cellule du classeur à déverrouiller, il y a une info du genre
'[Rd AGENCE 321.xlsm]SAISIES'!$M$2

et moi, je voudrais récupérer Rd AGENCE 321.xlsm

Avec WbDev = DeV.Text, j'ai récupéré Null...

A force de donner tes infos au goute-à-goute, tu fais perdre du temps à tout le monde et tu vas finir par lasser...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

WbDev = Mid(Dev.Address(External:=True), 2, Instr(Dev.Address(External:=true),"]") - 2)

[Pierre Fauconnier]

Salut

But du jeu: Récupérer les positions des crochets, puis extraire ce qu'il y a entre les deux...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
  Dim Value As String
  Dim Pos1 As Long, Pos2 As Long
 
  Value = "'[Rd AGENCE 321.xlsm]SAISIES'!$M$2 "
  Pos1 = InStr(1, Value, "[")
  Pos2 = InStr(1, Value, "]")
  Value = Mid(Value, Pos1 + 1, Pos2 - Pos1 - 1)

[mouftie]

Bonjour M Fauconnier,

Merci pour votre réponse, mais mon problème c'est de récupérer le nom de l'agence qui est inscrit dans la fenêtre de l'InputBox, avec les coordonnées de la cellule qui a été sélectionnée.

[Pierre Fauconnier]

Je t'ai donné une réponse générique, avec la chaîne que tu as donnée en exemple. Tu dois bien entendu remplacer la valeur de la chaine par la valeur de l'inputbox puis utiliser le code que j'ai donné pour récupérer la position des crochets et extraire ce qu'il y a entre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Value = inputbox(...)

Si ce n'est pas ce que tu souhaites, c'est que je n'ai pas compris ta question => pourras-tu alors la reformuler?

[mouftie]

Bonjour à vous et merci pour vos réponses.

Menhir, je croyais avoir expliquer ce que je voulais dans mon premier post, mais je n'ai pas été suffisamment claire, à vous lire. Je vous prie de m'en excuser. ce qui me manquait, c'était effectivement :

Address(External:=True)

Mais après je ne sais pas comment récupérer le nom du fichier qui apparait dans l'inputbox au moment de la sélection, avant les références de la cellule ?

peut-être aurais-je du préciser la fenêtre de l'InputBox...

Du coup, voici le code complet, si ça peut servir à qq'1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub DeVerrAgc()
'Déprotection de toutes les feuilles d'1 fichier agence
Dim NbFl As Integer, DeV As Range, WbDev As String
 
 Set DeV = Application.InputBox(prompt:="Cliquer sur le fichier de l'agence à déverrouiller", Type:=8)
    If DeV Is Nothing Then Exit Sub
WbDev = DeV.Address(External:=True)
 
'WbDev = Mid(DeV.Address(External:=True), 2, InStr(DeV.Address(External:=True), "]") - 2)
WbDev = Mid(DeV.Address(External:=True), 3, InStr(DeV.Address(External:=True), "]") - 3)
With Workbooks(WbDev)
    NbFl = .Sheets.Count
    .Activate
    For i = 1 To NbFl
        Worksheets(i).Unprotect Password:="SuperA"
        Worksheets(i).Range("A1").Interior.ColorIndex = 43   'Couleur verte
    Next i  '***** FIN Protection
    'Si nécessaire, on affiche la feuille Données.
    If .Sheets("Données").Visible = False Then .Sheets("Données").Visible = True
End With
End Sub

Merci à tous pour le temps passé