Discussion :

[Anthony47]

Bonjour à tous,

Sur un fichier Excel qui comporte plusieurs onglets, j'ai paramétré les plages de cellules autorisées, et verrouillé les autres (par révision > protéger).

En revanche, sur deux onglets j'ai besoin de pouvoir utiliser les 1,2 et 3 de mes plans (obtenus via données > plan > grouper)
Mais quand la feuille est protégée on ne peut plus s'en servir (on peut utiliser les + et - mais pas les 1,2,3).

Sur le net j'ai ce bout de code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub Workbook_Open() ' Macro pour permettre de developper les 1 2 3 du plan avec la protection
Dim WS_Count As Integer
Dim I As Integer
 
WS_Count = ActiveWorkbook.Worksheets.Count
For I = 1 To WS_Count
With ActiveWorkbook.Worksheets(I)
.EnableAutoFilter = True
.EnableOutlining = True
.Protect Contents:=True, UserInterfaceOnly:=True
End With
Next I
 
End Sub

Il fonctionne, les cellules autoriser sont toujours modifiables et je peux utiliser les 1,2,3 mais il n'est pas parfait.
Il faudrait qu'il ne soit actif que pour les onglets nécessaires, et qu'il me permette d'autoriser plus de choses.
Par exemple, si j'autorise la modification des formats de cellules ou l'insertion de lignes, à la prochaine ouverture du fichier ces paramètre d'autorisation sautent et tous les onglets de reprotègent.

Ca doit être assez simple à faire mais je ne suis pas très doué en vba du coup je ne parviens pas à l'adapter comme je veux.
J'ai tenté de lancer la macro pour autoriser les 1,2,3 puis de supprimer la macro pour pas que ça réinitialise mes paramètres mais si je ferme et réouvre le fichier mes paramètres sont bien mémorisés mais plus possible d'utiliser les 1,2,3.


NB : Sur d'autres onglets j'ai besoin de pouvoir fusionner des cellules (parmis les cellules autoriser à la modification) tout en gardant la protection de la feuille activée. Si vous avez la solution

[joe.levrai]

Bonjour,

ici, on place le nom de feuilles qu'on veut traiter dans le tableau ListeFeuilles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Workbook_Open() ' Macro pour permettre de developper les 1 2 3 du plan avec la protection
Dim I As Integer, ListeFeuilles()
ListeFeuilles = Array("Feuil1", "Feuil2")
    With ActiveWorkbook
        For I = LBound(ListeFeuilles) To UBound(ListeFeuilles)
            With .Worksheets(ListeFeuilles(I))
                .EnableAutoFilter = True
                .EnableOutlining = True
                .Protect Contents:=True, UserInterfaceOnly:=True
            End With
        Next I
    End With
End Sub

[MarcelG]

Salut Anthony,

Il y a plusieurs autorisations possibles et que l'on peut affecter à une protection.
Elles sont décrites ici.

[Anthony47]

Bonjour Joe, Rebonjour Marcel,

Merci à vous deux, alors, j'ai pu rajouter quelques critère

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub Workbook_Open() ' Macro pour permettre de developper les 1 2 3 du plan avec la protection
Dim I As Integer, ListeFeuilles()
ListeFeuilles = Array("EC (1)")
    With ActiveWorkbook
        For I = LBound(ListeFeuilles) To UBound(ListeFeuilles)
            With .Worksheets(ListeFeuilles(I))
                .EnableAutoFilter = True
                .EnableOutlining = True
                .Protect Contents:=True, UserInterfaceOnly:=True, AllowFormattingCells:=True, AllowInsertingRows:=True, AllowDeletingRows:=True, AllowFormattingColumns:=True
 
            End With
        Next I
    End With
End Sub

Mais deux choses :

1-J'ai pas trouvé le critère qui autorise de fusionner les cellules

2-Mon onglet EC (1) peut être amené à être dupliqué plusieurs fois, il faudrait qu'à l'ouverture je puisse appliquer ça à tout les EC (X)
Sur une autre macro, j'ai simplement utilisé la présence d'un caractère dans une cellule (en AA1) pour identifier les feuilles en question

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub PrintingChoose()
Dim wb
For Each wb In Worksheets 'ou worbooks pour classeurs worksheets si tu veux parcourir les feuilles au lieu des classeurs
 
  If wb.Range("AA1").Value = 1 Then  'tu verifies la valeur de la cellule Z1 dans la feuille active lors de l'ouverture du classeur. pour le parcours des feuilles au lieu des classeurs, il faut juste enlever ".activesheet"
    wb.Outline.ShowLevels RowLevels:=2
    wb.Outline.ShowLevels RowLevels:=0, ColumnLevels:=1
    wb.Columns("G:G").EntireColumn.Hidden = True
    wb.PrintPreview 'Lance l'impression du classeur/ de la feuille. Fais juste attention à ce que l'imprimante par défaut soit active
    wb.Columns("G:G").EntireColumn.Hidden = False
   End If
 
Next
   Sheets("Récap général").PrintPreview
End Sub

Si vous savez comment appliquer ce principe à la macro

[joe.levrai]

Pour l'appliquer à toutes les feuilles commençant par "EC ("

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Workbook_Open() ' Macro pour permettre de developper les 1 2 3 du plan avec la protection
Dim Feuille As Worksheet
    For Each Feuille In ActiveWorkbook.Worksheets
        If Feuille.Name Like "EC (" & "*" Then
            With Feuille
                .EnableAutoFilter = True
                .EnableOutlining = True
                .Protect Contents:=True, UserInterfaceOnly:=True, AllowFormattingCells:=True, AllowInsertingRows:=True, AllowDeletingRows:=True, AllowFormattingColumns:=True
 
            End With
        End If
    Next Feuille
End Sub

Concernant la fusion, le plus simple est de proposer un bouton sur ces feuilles, quand on appuie dessus ça fusionne la sélection
La macro à affecter à chaque bouton

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub Fusion()
    Selection.Cells.Merge
End Sub