Discussion :

[imagins]

Bonjour à tous,
je suis sur un projet qui avance est qui est fonctionnel pour le moment, mais pas très pratique. Je voudrais donc essayer de l'améliorer un peu.
J'ai fait une macro qui me copie une sélection dans une autre feuille.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub CdePochIndividuelle()
Range("aa4:aa100").Select
Dim c As Range, Plage As Range
For Each c In Selection
If c <> 0 Then
If Plage Is Nothing Then
Set Plage = c
Else
Set Plage = Union(Plage, c)
End If
End If
Next c
Plage.Select
Plage.Copy
Worksheets("Cde Poch Indiv").Activate
Range("A" & Rows.Count).End(xlUp).Offset(1).Select
ActiveCell.PasteSpecial Paste:=xlPasteValues
End Sub

Elle fonctionne correctement si j'ai bien une sélection qui existe. Par contre, il arrive que la sélection soit vide (car pas de commande) et dans ce cas, il y a un bug (ce qui semble normal puisque je lui demande de sélectionner quelques chose qui n'existe pas). Actuellement je contourne le problème en ne lançant pas la macro si il n'y a pas de sélection (commande), mais comme je dois la lancer sur plusieurs feuilles, j'aimerai savoir si il est possible de gérer cela automatiquement.

Je vous met mon fichier pour une meilleur compréhension gestion des commandes-4.xlsm
Merci

[Menhir]

Plus rapide :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub CdePochIndividuelle()
   Dim c As Range, Dest As Range
   Set Dest = Worksheets("Cde Poch Indiv").Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
   For Each c In Range("AA4:AA100").Cells
      If c <> 0 Then 
         Dest.Value = c.Value
         Set Dest = Dest.Offset(1, 0)
      End If
   Next c
End Sub

[imagins]

Super.
Merci beaucoup.
C'est vrai que je ne suis pas un expert en vba et que je ne suis pas très descriptif dans mon code.
Ca semble fonctionner. Merci