Discussion :

[Eloli]

Bonjour,

Je cherche à modifier le formatage d'une série de cellule pour intégrer automatiquement l'année du système dans le formatage.
Ce code fonctionne seulement si je met l'année en "dur" dans la macro Selection.NumberFormat = "###0""/2020"""

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Changement_Année()
 
If Day(Date) = "01" And Month(Date) = "1" Then
 
Workbooks.Open "D:\amelioration ticket incident\Tableau de suivi des incidents vierge.xlsx"
    Columns("A:A").Select
    Selection.NumberFormat = "###0""/2020"""
    Range("A3").Select
    ActiveCell.FormulaR1C1 = "1"
    Selection.AutoFill Destination:=Range("A3:A3000"), Type:=xlFillSeries
    Range("A3:A3000").Interior.Color = vbGreen
    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs "D:\amelioration ticket incident\Tableau de suivi des incidents " & Year(Date) & ".xlsx"
    ActiveWorkbook.Close
    Application.DisplayAlerts = True
Else
MsgBox "fin macro"
 
End If
End Sub

Cette macro est destinée à mettre en forme un tableau le premier janvier de chaque année pour remplir les cellules en repartant du N°1.

Merci

[Eloli]

Bonjour

Solution trouvé un simple problème d' écriture il manquait 1 " en fin de ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Selection.NumberFormat = "###0""/" & Year(Date) & """"

[MarcelG]

Bonjour Eloli, Bonjour au Forum,

Quelques remarques.

1 - Par soucu de confidentialité, éviter de mentionner des répertoires qui concernent ton lieu de travail
Les fonctions Day et Month sont numériques de type Byte (à mon avis, car l'aide Microsoft avance Integer)

2 - Eviter les blocs If trop importants. Pour une lisibilité optimale, procéder de préférence par appel de procédure.
Supprimer lette s...de Select. Celles-ci n'ont qu'un effet: alourdir le code et, partant, le rendre moins lisible.

3 - Constater le champ de cellules plutôt que considérer une valeur maximale (ici 3000)

4 - Si les propriétés et méthodes sont affectées à un même objet Range, alors utiliser le bloc With

5 - Même s'ils sont tacites, toujours préciser les paramètres (ici Filename)

6 - Si une chaîne de caractères se reporte plusieurs fois dans une procédure (voire un module), alors la déclarer en lui affectant une variable

Comme ta discussion est résolue, je te reporte une proposition.

Tu compares.

(non testé)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Option Explicit
 
Sub Changement_Année_V2()
 
If Day(Date) = 14 And Month(Date) = 10 Then
 
        Call open_mise_au_format
 
Else
 
        MsgBox "fin macro"
 
End If
 
End Sub
 
Sub open_mise_au_format()
 
Dim racine As String
racine = "D:\amelioration ticket incident\Tableau de suivi des incidents"
 
Dim dernl As Long
 
With Application
        .DisplayAlerts = False
        .ScreenUpdating = False
End With
 
Workbooks.Open Filename:=racine & " vierge.xlsx"
 
With ActiveSheet
        dernl = .Cells(.Rows.Count, 1).End(xlUp).Row
        With .Range("A1:A" & dernl)
                .NumberFormat = "###0""/" & Year(Date) & """"
                .Value = 1
                .Interior.Color = vbGreen
        End With
End With
 
With ActiveWorkbook
        .SaveAs Filename:=racine & "_" & Year(Date) & ".xlsx"
        .Close
End With
 
With Application
        .ScreenUpdating = True
        .DisplayAlerts = True
End With
 
End Sub

[Eloli]

Bonsoir MarcelG,

Merci de ta réponse.

Ne possédant pas un haut niveau de programmation VBA je n'ai fait qu'un enregistrement de macro puis l'ai modifié légèrement pour la faire correspondre à mes besoins.

Je suis tout a fait d'accord sur tes remarques , sauf au niveau du point 03, car de base la colonne A est vide c'est pour cela que j'ai défini un nombre précis.

Demain j'essaye ta version pour voir si elle fonctionne.
Bonne soirée

[MarcelG]

Bonjour Eloli, Bonjour le Forum,

sauf au niveau du point 03, car de base la colonne A est vide c'est pour cela que j'ai défini un nombre précis.

J'avoue ne pas comprendre.

Ce que signifiait ma remarque.
Il faut considérer un champ précis en définissant sa dernière cellule (voir le code proposé)