Discussion :

[speedozrx]

Bonjour la communauté,
Dans le cadre d'un grand déploiement et la répétition de tâches toujours identiques au projet, j'ai pensé à automatiser ces opérations de copies de sauvegarde par un script très simple (mon premier).
J'aimerais saisir le nom du matricule = profil Windows avant chaque lancement de la commande (actuellement, je fais cette opération via la fonction "chercher / remplacer, mais ce n'est pas génial)
Je bloque sur la saisie du profil, j'ignore comment finaliser
D'avance merci pour votre aide ou conseils...

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
@echo off
color 0A
set /p profil = saisir le matricule :
 
 
md dir e:\z018568
 
md dir e:\z018568\Desktop
 
md dir e:\z018568\Favorites
 
md dir e:\z018568\Music
 
md dir e:\z018568\Documents
 
md dir e:\z018568\Pictures
 
md dir e:\z018568\Videos
 
md dir e:\z018568\Downloads
 
md dir e:\z018568\Signatures
 
md dir e:\z018568\Firefox
 
md dir e:\z018568\Disk
 
robocopy "C:\Users\z018568\Desktop" "e:\z018568\Desktop" /S /E /V /MT:30 /ETA 
 
robocopy "C:\Users\z018568\Favorites" "e:\z018568\Favorites" /S /E /MT:30 /ETA  
 
robocopy "C:\Users\z018568\Music" "e:\z018568\Music" /S /E /V /MT:30 /ETA  
 
robocopy "C:\Users\z018568\Documents" "e:\z018568\Documents" /S /E /V /MT:30 /ETA  
 
robocopy "C:\Users\z018568\Pictures" "e:\z018568\Pictures" /S /E /V /MT:30 /ETA  
 
robocopy "C:\Users\z018568\Downloads" "e:\z018568\Downloads" /S /E /V /MT:30 /ETA  
 
robocopy "C:\Users\z018568\AppData\Roaming\Microsoft\Signatures" "e:\z018568\Signatures" /S /E /V /MT:30 /ETA  
 
robocopy "C:\Users\z018568\Videos" "e:\z018568\Videos" /S /E /V /MT:30 /ETA  
 
robocopy "C:\Users\z018568\AppData\Roaming\Mozilla" "e:\z018568\Firefox" /S /E /V /MT:30 /ETA  
 
robocopy d: "e:\z018568\Disk" /S /E /V /MT:30 /ETA

[ericlm128]

Voici comment exploiter la saisie.

J'ai ajouter des étiquettes pour éviter la répétition de code et quelques vérifications.

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
@echo off
color 0A
 
set /p profil=Saisir le matricule : 
if not exist "C:\Users\%profil%\" goto fin
if "%profil%" == "" goto fin
 
call :saveprofil "C:\Users\%profil%\Desktop" "e:\%profil%\Desktop"
call :saveprofil "C:\Users\%profil%\Favorites" "e:\%profil%\Favorites"
call :saveprofil "C:\Users\%profil%\Music" "e:\%profil%\Music"
call :saveprofil "C:\Users\%profil%\Documents" "e:\%profil%\Documents"
call :saveprofil "C:\Users\%profil%\Pictures" "e:\%profil%\Pictures"
call :saveprofil "C:\Users\%profil%\Downloads" "e:\%profil%\Downloads"
call :saveprofil "C:\Users\%profil%\AppData\Roaming\Microsoft\Signatures" "e:\%profil%\Signatures"
call :saveprofil "C:\Users\%profil%\Videos" "e:\%profil%\Videos"
call :saveprofil "C:\Users\%profil%\AppData\Roaming\Mozilla" "e:\%profil%\Firefox"
call :saveprofil "d:" "e:\%profil%\Disk"
goto fin
 
:saveprofil
if not exist "%~1" goto :eof
md "%~2"
robocopy "%~1" "%~2" /S /E /V /MT:30 /ETA 
goto :eof
 
:fin
echo.
echo fin
pause>nul

[speedozrx]

Un grand MERCI Ericlm128 , cela fonctionne très bien !!!
Je vais grossièrement me servir de ta "science" pour refaire la manip inverse puisque je pars d'un profil sur Windows 7 qui passe sur Windows 10. Merci !!