Discussion :

[thibdev]

Bonjour,

J'ai un tableau de données Excel qui comprends de nombreuses cellules fusionnées sans ordre précis.

Probablement pour gagner en lisibilité, la personne qui a créé le tableau a fusionné les cellules ayant les mêmes valeurs.

De mon coté, pour exploiter le contenu j'ai besoin d'annuler la fusion des cellules.

Seulement, si je fais ça, je me retrouve avec plein de cellules vides.

Imaginons par exemple que j'ai la cellule fusionnée :

-----------------------
1 |
2 | "Contenu"
3 |
-----------------------

Si j'annule la fusion j'obtiens :

-----------------------
1 | "Contenu"
-----------------------
2 |
-----------------------
3 |
-----------------------

Or ce dont j'ai besoin c'est de :

-----------------------
1 | "Contenu"
-----------------------
2 | "Contenu"
-----------------------
3 | "Contenu"
-----------------------

C'est facilement réglable à la main en faisant un glisser-déposer sur chaque cellule mais il y vraiment beaucoup de données. Je cherche une fonction ou une macro qui permet de réaliser cette opération sur l'ensemble des cellules de la feuille de calcul.

Merci

[Pierre Fauconnier]

Salut.

D'un premier jet... La macro balaie une plage et défusionne les cellules en y plaçant la valeur de la plage fusionnée. Il y a peut-être plus académique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub UnMergeAndReplace(Rng As Range)
  Dim merged As Range
  Dim Cell As Range
 
  For Each Cell In Rng
    If Cell.MergeArea.Cells.Count > 1 Then
      Set merged = Cell.MergeArea
      Cell.UnMerge
      merged.Value = Cell.Value
    End If
  Next
End Sub

[78chris]

Bonjour à tous

Une solution manuelle aussi mais rapide : partie Combler les trous http://www.excel-formations.fr/Trucs...s/ToucheF5.php

[Philippe Tulliez]

Bonjour,
Manuellement comme en vba d'ailleurs il est possible de supprimer en une seule opération les cellules fusionnées par la sélection de la plage concernée et ensuite décocher Fusionner centrer et ensuite comme indiqué par l'astuce proposée par Chris

En VBA pour une plage commençant en cellule A1 de la feuille nommée Test du classeur où se trouve le code VBA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub t()
  Dim rng As Range
  Set rng = ThisWorkbook.Worksheets("Test").Range("A1").CurrentRegion
  With rng
  .MergeCells = False
  .SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
  .Value = .Value
  End With
  Set rng = Nothing
End Sub

[Pierre Fauconnier]

[...]

Si la proc reçoit la plage plutôt que de la déterminer, ça fait un outil générique à se garder bien au chaud

[Philippe Tulliez]

Bonjour Pierre,

Si la proc reçoit la plage plutôt que de la déterminer, ça fait un outil générique à se garder bien au chaud

Oui, je l'ai écrite en vitesse sans placer ma fonction car ces derniers temps cela ne semble pas clair pour beaucoup de demandeurs. Merci pour le vote