Discussion :

[Tortille]

Bonjour à tous,

j'affiche des textes sur un dessin à l'aide de la fonction DrawText de la classe ClGdiPlus d'Arkham46.

Si la longueur du texte est > 255, jusqu'à la longueur 255 le texte est en français, au delà le texte est transformé en chinois.

Pour info, le texte affiché provient d'un champ de type Mémo d'une table.

Existe-t-il une solution pour que tout le texte s'affiche en français ?
le texte affiché provient d'un champs de type Mémo

Merci d'avance pour vos solutions.

[volsan]

Bonjour,

Peux t'on voir un bout du code utilisé et une copie d'écran de ce qui s'affiche svp?

[Tortille]

Bonjour Volsan

voilà l'image



Je veux afficher le texte : "Le choix peut paraître anodin mais ces conséquences seront très concrètes en France, dont un petit millier de kilomètres sépare chacune des extrémités. Au jeu de la latitude et de la longitude, abandonner le changement d’heure n’aura en effet pas les mêmes conséquences selon que l’on vit au nord, au sud, à l’est ou à l’ouest.

Ce texte est dans la table T1.Info

Je fais la requête R1 : "Select T1.Info, T1.Rnfo, VraiFaux ([TypD]=3;[Rnfo];[Info]) As Ligne1 From T1;"

A l'affichage de la requête quand [TypD]=3, j'ai bien R1.Info = R1.ligne1 = T1.Info, les 2 textes sont les mêmes que celui de la table et c'est normal.

Et pour afficher le texte dans un rectangle sur l'image quand la souris survole une région.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Private Sub Img_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim Cdb As DAO.Database
Dim RS1 As DAO.Recordset
Dim strSql As String, lText As String, lTextInfo As String
 
    strSql = _
        "SELECT R1.* " & _
        "FROM R1 " & _
        "WHERE Id=" & mT_Reg(5) & ";"
 
        Set oRst = Cdb.OpenRecordset(strSql, dbOpenDynaset)
 
        If Not (oRst.EOF) Then
 
            Do Until oRst.EOF
                lText = oRst!Ligne1
                oRst.MoveNext
                lTextInfo = lTextInfo & lText
 
                Debug.Print "rs1!Info : "; RS1!Info
                Debug.Print "rs1!Ligne1 : "; RS1!Ligne1
 
            Loop
 
        End If
 
    With oGdi
        .DrawRectangle Gauche, Haut, Droite, Bas, Coufond, RGB(143, 143, 159), , , alfa
        .DrawText lTextInfo, TailleText, strPolice, Gauche, Haut, Droite, Bas, , , CouText
        .FastRepaint oCtrlImage0
    End With
 
'   Etc. ...
End Sub

Les 2 Debug.Print font apparaître l'erreur sur rs1!Ligne1

Debug.Print "rs1! Info : " ; rs1!Info
rs!vInfo : Le choix peut paraître anodin mais ces conséquences seront très concrètes en France, dont un petit millier de kilomètres sépare chacune des extrémités. Au jeu de la latitude et de la longitude, abandonner le changement d’heure n’aura en effet pas les mêmes conséquences selon que l’on vit au nord, au sud, à l’est ou à l’ouest.

Debug.Print "rs1!Ligne1 : " ; rs1!Ligne1
rs!Ligne1 : Le choix peut paraître anodin mais ces conséquences seront très concrètes en France, dont un petit millier de kilomètres sépare chacune des extrémités. Au jeu de la latitude et de la longitude, abandonner le changement d’heure n’aura en effet pas les même ?n????? k ?????n???? ????k ???? ???????n?? ?n ?n????v


Au début je pensais que l'erreur venais de la classe clGdiPlus, car les textes affichés dans la requête R1 étaient identiques et je n'imaginais pas que ça cloche entre la requête et la classe, d'où le titre.

En fait le problème vient du RecordSet rs1 qui récolte les données de R1.

Je demande de l'aide pour ce problème.

Merci par avance.

[Ric500]

Bonjour,

Juste pour ma compréhension:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set oRst = Cdb.OpenRecordset(strSql, dbOpenDynaset)

et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print "rs1!Ligne1 : "; RS1!Ligne1

C'est normal? Le recordset n'est pas le même. Ou alors il manque un bout de code?

En fait le problème vient du RecordSet rs1 qui récolte les données de R1.

Bah non! C'est oRst !

[Tortille]

Bonjour Ric

Merci d'avoir relevé mes erreurs.

Dans ma base, le code est bon, ici, j'essais de simplifier les noms de table, de requête, etc. et je me plante !

voilà le bon code simplifié, mais tu te doutes qu'avec le code que j'ai mis, il ne peut pas y avoir d'image en sortie !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub Img_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim Cdb As DAO.Database
Dim rs1 As DAO.Recordset
Dim strSql As String, lText As String, lTextInfo As String
 
    strSql = _
        "SELECT R1.* " & _
        "FROM R1 " & _
        "WHERE Id=" & mT_Reg(5) & ";"
 
        Set rs1 = Cdb.OpenRecordset(strSql, dbOpenDynaset)
 
        If Not (rs1.EOF) Then
 
            Do Until rs1.EOF
                lText = rs1!Ligne1
                rs1.MoveNext
                lTextInfo = lTextInfo & lText
                Debug.Print "rs1!Info : "; rs1!Info
                Debug.Print "rs1!Ligne1 : "; rs1!Ligne1
            Loop
 
        End If
 
    With oGdi
        .DrawRectangle Gauche, Haut, Droite, Bas, Coufond, RGB(143, 143, 159), , , alfa
        .DrawText lTextInfo, TailleText, strPolice, Gauche, Haut, Droite, Bas, , , CouText
        .FastRepaint oCtrlImage0
    End With
 
'   Etc. ...
End Sub

ça résout pas le problème;

Merci

[Invité]

Bonsoir,

cdb n'est pas initialisé avant son utilisation ?

[micniv]

Mon avis est que la fonction Drawtext() de la classe CLGDIPLUS pourrait ne pas gérer des strings de plus de 255 car.
A creuser ... avec le maître

CDLT

[Arkham46]

Bonjour

J'ai déjà eu un problème similaire avec une concaténation de texte avec un champ mémo.
Rien à voir avec gdi+ je pense.
L'expression retourne un resultat qui n'est que du text(255) et pas du mémo comme on pourrait s'y attendre.
On peut corriger avec une astuce (un union all pour forcer la colonne en mémo) mais j'ai pas ça ici, il faut que je regarde au boulot.

Sinon il faut déporter l'expression vraifaux dans le vba.
Si c'est possible ce sera plus simple.

[Ric500]

Bonjour,

Je pencherais pour ma part du côté d'Arkham. J'ai essayé avec une table contenant des conditions générales de vente.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub EssaiLText()
    Dim mabd As DAO.Database
    Dim mRec As DAO.Recordset
    Dim strSQL As String, lText As String, lTextInfo As String
 
    strSQL = "SELECT CGV.* FROM CGV;"
 
    Set mabd = CurrentDb()
    Set mRec = mabd.OpenRecordset(strSQL, dbOpenDynaset)
 
    Do While mRec.EOF = 0
        lText = mRec!CGV
        Debug.Print Len(mRec!CGV)
        Debug.Print "---------------------------------------"
        Debug.Print Len(lText)
        mRec.MoveNext
    Loop
    mRec.Close
    Set mRec = Nothing
    Set mabd = Nothing
End Sub

... Qui donne:

call EssaiLText
25776
---------------------------------------
25776

Peut-être que tu devrais regarder du côté de tes références???


EDIT: Je viens de faire un essai avec un recordset portant sur une requête et non plus sur une table pour coller au mieux avec ton modèle (comprenant également une fonction vrai/faux) : le résultat est toujours OK chez moi.

[micniv]

Encore désolé d'avoir suspecté clGDI+
En même temps grâce à vous 2 le pb est éclairci.
Ah, dès qu'on manipule les mémos ds les requêtes ....

CDLT

[Tortille]

Bonjour et merci pour toutes vos réponses.

Dans l'ordre:

Galoir,
C'est encore une erreur de ma part dans le code que j'ai fourni, mais dans ma base Cdb est initialisé.

Micniv,
L'erreur ne vient pas de la fonction Drawtext, elle est jute avant dans la fonction IIf qui traduit mon texte à sa guise, mon texte est de type mémo, et la fonction IIf ne doit pas être adapté pour les champs mémos.

Arkham,
Désolé d'avoir incriminé ta classe, Lorsque j'ai relevé l'erreur, la requête affichait le texte impeccable, et je ne me doutais pas que le RecordSet sur la requête modifiait le texte au delà de 255 caractères et comme le traitement suivant était la fonction DrawText, c'est elle qui a pris toute ma colère. Sinon j'ai déporté le IIf dans le vba, plus de problème.

Ric,
Regarde cette base qui reproduit le problème, DatabaseErreurVraifaux.7z

Micniv,
Juré, je ne m'y aventurerais plus.

Ah, dès qu'on manipule les mémos ds les requêtes ....

Merci encore pour votre aide.

[Invité]

deux solutions :
dans la requete avec union all (cf arkham46) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
SELECT T1.Id, T1.TxtMemo, T1.TxtTexte, t1.TxtMemo as info FROM T1 WHERE 0=1
UNION ALL SELECT T1.Id, T1.TxtMemo, T1.TxtTexte, IIf([Id]=1,[TxtMemo],[TxtTexte]) FROM T1;

ou dans le code vba :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Do Until Rs1.EOF
                If !id = 1 Then
                  lTextInfo = lTextInfo & !txtmemo
                Else
                  lTextInfo = lTextInfo & !txttexte
                End If
...

[Ric500]

Galoir, tu m'as pris de vitesse

J'avais vu la solution VBA, mais je ne connaissais pas la solution SQL sur laquelle je vais me pencher sérieusement.

DatabaseErreurVraifaux.rar

Bon week end à tous

[Invité]

Bonsoir ric500,

le 1er select de la requête UNION ALL impose le format des colonnes, la source ici

a+

[Tortille]

Alors là champions,
Merci pour les solutions,

J'avais opté pour la solution vba, car je ne savais pas mettre en ouvre la solution requête union.

Maintenant que j'ai le choix, je n'arrive pas à me décider !

Je préfère la solution requête parce que je ne sais pas si c'est vrai, mais je me dis que si les calculs sont fait dans la requête avant de les importer dans le vba , ça doit aller plus vite que d'importer la requête et de faire les calculs dans vba.

Ce serait terrible pour la souris de perdre une microseconde !

Bien merci pour votre aide
et un beau WE à vous.

[Arkham46]

Je préfère la solution requête parce que je ne sais pas si c'est vrai, mais je me dis que si les calculs sont fait dans la requête avant de les importer dans le vba , ça doit aller plus vite que d'importer la requête et de faire les calculs dans vba.

Ce serait terrible pour la souris de perdre une microseconde !

Même pas sûr que les performances soient meilleures avec union all, peut être un gain mémoire mais bof j'ai un doute.
C'est surtout côté maintenance et documentation qu'il faut réfléchir.
Il y a déjà du vba dédié à une utilisation unique de la requête, alors je le ferais en vba.
Si la requete doit être utilisée à plusieurs endroits, ou doit être utilisée par une procédure générique, alors je mets tout dans la requête avec un union all.
Dans mon cas j'avais une procédure d'export générique utilisée par plusieurs requêtes, j'ai préféré ne pas mettre de spécificité dans la procédure d'export.
Dans ton cas je voterais pour un test en vba.

Déjà si ça fonctionne c'est bien, choisi la meilleure solution en fonction du temps de developpement, documentation, maintenance... et non pas en fonction des performances si c'est juste pour quelelques millièmes de secondes (et encore il faudrait le tester)

Bon choix !

[Tortille]

Bonjour Arkham,

Les 2 solutions fonctionnent.

Bien sur la différence finale en terme de réactivité de la souris est imperceptible.

Je choisis d'éviter le IIf dans le vba pour avoir TOUS les calculs dans la requête pour la maintenance.

Sinon en adaptant UNION ALL à ma requête, je ne comprenais pas le Where 0=1 donc je ne l'ai pas mis du coup la requête affiche les résultats en double, je l'ai vite remis.

En fait avec Where 0=1; Where 1=0; Where 0; Where FALSE, la requête donne le résultat de UNION ALL SELECT, (résultat attendu),
tandis que sans Where ou avec Where = TRUE, la requête donne le résultat de SELECT et celui de UNION ALL SELECT, (résultat en double).

J'ai aussi supprimé le ALL, retour instantané aux textes tronqués, je l'ai vite remis !

En tous cas, Merci Merci Merci pour ces solutions.

[Robert1957]

Bonjour Tortille,

je ne comprenais pas le Where 0=1

C'est un truc pour avoir seulement les champs et leurs formats mais pas de données puisque la condition sera toujours fausse. Explication de Galoir dans le post #14.

Bonne journée

[Tortille]

Bonjour Robert,

J'avais vu le post #14, mais bon je ne suis pas un habitué des UNION ALL, c'est mon premier, et peut être aussi mon dernier !

Merci à toi et à tous les participants pour l'aide que vous m'avez apporté.