Discussion :

[Sylcoco]

Bonjour à tous,

En A1 j'ai un n° de licence (format texte) type 069_12345678
En B1 j'utilise la fonction SUBSTITUE pour supprimer le "_"
En C1 j'utilise la fonction DROITE pour supprimer le 1er "0"
En D1 j'utilise la fonction CNUM pour remettre au format nombre.

Qu'elle serait donc la "méga formule" pour tout faire en une seule et unique formule ?

D'avance merci pour l'aide qui pourrait m'être apportée.

Sylvain

[Invité]

Bonsoir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=STXT(SUBSTITUE(A1;"_";"");2;NBCAR(A1))*1

[Philippe Tulliez]

Bonjour,
Si tu as décomposé le problème en plusieurs cellules, rien de plus simple

Récapitulons
En A1, la constante 069_12345678

En B1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SUBSTITUE(A1;"_";"")

En C1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DROITE(B1;NBCAR(B1)-1)

En D1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=CNUM(C1)

On commence la construction de la formule complète en partant de la droite, c'est à dire D1, où la fonction fait référence à la cellule C1 donc
Etape par étape

1. Sélection de la cellule C1
2. dans la barre des formules, sélection de l'ensemble de la formule sans le signe = soit DROITE(B1;NBCAR(B1)-1) et Ctrl+ C pour copier
3. Sélection de la cellule D1
4. Sélection de la référence à la cellule C1 et coller (Ctrl + V), ce qui donne
   

   Code :

   Sélectionner tout - Visualiser dans une fenêtre à part

   =CNUM(DROITE(B1;NBCAR(B1)-1))

5. Maintenant on fait la même chose en B1 (Copie de la formule sans le signe = et puis Copier et ensuite Coller dans la cellule D1 à toutes les références à la cellule B1 ce qui donne
   

   Code :

   Sélectionner tout - Visualiser dans une fenêtre à part

   =CNUM(DROITE(SUBSTITUE(A1;"_";"");NBCAR(SUBSTITUE(A1;"_";""))-1))

Tu peux maintenant supprimer le contenu des cellules B1 et C1 et déplacer D1 en B1

[Sylcoco]

MM bonsoir,

Merci beaucoup pour votre aide.
C'est tout à fait le résultat que j'attendais.

Philippe, merci beaucoup pour le détail de la construction d'une méga formule.

Bien à vous,

Sylvain