Discussion :

[Roland Chastain]

Bonjour ! Je suis en train d'étudier les questions d'encodage et je m'intéresse à titre d'exemple au problème des accents dans la console Windows.

Je ne m'explique pas le résultat du programme suivant. Pourquoi le résultat n'est-il pas deux fois le même ? À quel moment la différence se fait-elle ?

Si je remplace 133 par 233, c'est le premier caractère qui est correct.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
var
  s: string;
 
begin
  SetLength(s, 1);
  s[1] := #130;
  WriteLn(s);
  WriteLn(s[1]);
end.
 
{
  '
  é
}

[Roland Chastain]

Bref, si j'écris une chaîne de caractères dans la console, je dois utiliser la table ANSI ; si j'écris un caractère, la table OEM.

Question subsidiaire. En supposant que l'usage normal soit d'écrire une chaîne, il faut donc encoder en ANSI pour écrire dans la console, et non pas en OEM ? Pourtant si je veux écrire depuis un batch avec des caractères accentués correctement restitués, je dois encoder le batch en OEM. Je n'y comprends plus rien.

[DomDA91]

Bonjour, et Bonne Année (avec 24h d'avance) !

La différence est que s renvoie une valeur de type ansistring (sujet à des conversions codepage) alors que s[1] renvoie un type char (jamais de conversion).

Il est intéressant d'essayer ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
uses sysutils, Windows;
var
  s: string;
 
begin
  SetLength(s, 1);
  s[1] := #130;
  WriteLn('CP=', intToStr(stringcodepage(s)));  // affiche 1252 (page de code ANSI)
  SetCodePage(rawbytestring(s), GetOemCP, false); // change l'ID page de code de s sans modifier la chaîne elle-même
  WriteLn('CP=', intToStr(stringcodepage(s)));  // affiche 850 (page de code OEM)
  WriteLn(s);   
  WriteLn(s[1]); 
end.

Je présume qu'une conversion intervient lors du passage d'un paramètre ansistring à WriteLn si WriteLn est associé à la console et que la chaîne n'est pas OEM.
Cette conversion n'intervient pas pour un type char.

[Roland Chastain]

@DomDA91

Merci, je crois que j'ai compris. Dans la foulée, j'ai relu avec profit cette discussion, que j'avais un peu oubliée.

Moralité, il ne suffit pas de mettre les bonnes valeurs dans le corps de la chaîne, il faut aussi mettre à jour la "carte d'identité" de la chaîne. Si on ne le fait pas, le compilateur reconvertit la chaîne, d'où les erreurs. J'ai bon ?

J'attends un peu avant de clore la discussion. Bonne année à vous aussi ! Mais c'est vrai que nous n'y sommes pas encore.

[Roland Chastain]

C'est aujourd'hui que j'ai compris ce que fait la procédure SetCodePage. J'avais toujours plus ou moins cru qu'elle faisait une conversion du contenu de la chaîne. Merci de m'avoir éclairé.

Pour conclure (provisoirement) l'histoire du "é" dans la console Windows, un petit programme basé sur un exemple de Paul TOTH et sur l'explication de DomDA91.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
uses
  SysUtils;
 
{ https://www.developpez.net/forums/d1732510/environnements-developpement/delphi/contribuez/ne-prenez-pieds-strings/#post9515065 }
 
type
  TStringInfo = record
    CodePage: Word;
    CharSize: Word;
    RefCount: Integer;
    Length  : Integer;
  end;
 
procedure StringInfo(p: Pointer);
var
  i: ^TStringInfo;
begin
  i := p; // l'adresse du premier caractère
  Dec(i); // remonter de SizeOf(TStringInfo) en mémoire
  WriteLn(' CodePage = ', i^.CodePage);
  WriteLn(' CharSize = ', i^.CharSize);
  WriteLn(' RefCount = ', i^.RefCount);
  WriteLn(' Length   = ', i^.Length);
end;
 
var
  s: string;
 
begin
  s := 'é';
  WriteLn(Length(s) = 1); // FALSE
  StringInfo(pointer(s));
  WriteLn(s);
 
  SetCodePage(rawbytestring(s), 850, FALSE); // 850 ou GetOemCP de l'unité Windows
  StringInfo(pointer(s));
  WriteLn(s);
 
  SetLength(s, 1);
  s[1] := #130;
  StringInfo(pointer(s));
  WriteLn(s);
end.

Code X :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
  C:\Atelier\Pascal\encoding>stringinfotest
  FALSE
   CodePage = 0
   CharSize = 1
   RefCount = -1
   Length   = 2
  é
   CodePage = 850
   CharSize = 1
   RefCount = 1
   Length   = 2
  ├®
   CodePage = 850
   CharSize = 1
   RefCount = 1
   Length   = 1
  é

  C:\Atelier\Pascal\encoding>

[droggo]

Bonjour,

Eh oui, et ce problème va encore nous les briser longtemps, jusqu'à ce que TOUS les systèmes soient en Unicode.