Taille des boites aux lettres ?

**thierryppp** · 25/10/2018, 10h13

Bonjour,

Au boulot nous avons migré "Outlook" sur Office 365 chez Microsoft Azure.
Du coup j'ai migré tous les pst que j'avais en plus dans la "boite aux lettres" (principale)
(on a 100 Go) en créant des répertoires correspondants au *.pst... ==> pas de souci.

Par contre j'ai une interrogation sur les tailles de cette boite aux lettres ?
En local sur le poste client PC il y a toujours le fichier "nom de la boite".ost
Sous Outlook la taille de la boite avec ces sous répertoires en "Données locales" et en "Données sur serveur".
Dans mon cas j'ai donc 3 tailles différentes :

le fichier .ost à 1,8 Go
En "données locales" 2,8 Go
En "Données serveurs" 14 Go

Je comprends bien la différence de taille entre le fichier .ost et la taille sur le serveur distant qui contient la totalité de la boite aux lettres ... (accès réseau, débit ...)
Mais je ne comprends pas la taille en "Données locales" ==> y a t-il un fichier, un cache ou autre qui explique cette différence.

Mon but étant de faire des programmes en VBS, PowerShell ou autre pour voir toutes ces tailles...

Merci,

Thierry.

**Oliv-** · 25/10/2018, 11h19

Salut,

Cela peut dépendre de la configuration du mode de synchronisation, à partir de OL2013 il y a la possibilité de ne synchroniser localement qu'une période donnée, la dernière année par exemple.

https://support.office.com/fr-fr/art...9-7c8c9522d633

ce qui peut expliquer la différence entre la taille locale et serveur;

Pour le fichier ost, il stocke donc les données locales de ton compte + éventuellement les autres comptes ( accès délégués + boites communes) paramétrés . il y a une case à cocher qui contrôle cela dans les options avancées du compte/ Paramètres du mode Exchange mis en cache/ Utiliser le mode Exchangemis en cache/ Télécharger les dossiers partagés.

A savoir que ce fichier ost grandit mais ne diminue pas automatiquement, il faut lancer une compression, c'est peut être parce qu'il est compressé que sa taille est inférieur dans ton exemple à la taille locale.

Sur mon poste avec OL2010 (donc sans l'option de limitation à une période) j'ai cela :

Données locales 6.861.912 kb
Données serveur 8.863.615 kb
OST 9.586.209 ko (j'ai plusieurs comptes)

donc je sais pas trop pourquoi les données serveur >locales ...

edit: en regardant sur le webmail j'ai 6.76 Go d'utilisés donc cela colle avec les donnés locales

**thierryppp** · 25/10/2018, 11h47

Salur Oliv,

Merci de ta réponse.

Oui je comprends la différence : Données locales et Données serveur par rapport à la synchronisation sur une période donnée.
Par contre chez moi le fichier ost est plus petit en taille que les Données locales.
C'est là que c'est bizzare où il y a un autre fichier ou cache en local sur le PC...

Et par programme comment fait-on pour calculer les tailles.

Merci,

Thierry.

**Oliv-** · 25/10/2018, 15h53

Envoyé par thierryppp

Salur Oliv,

Merci de ta réponse.

Oui je comprends la différence : Données locales et Données serveur par rapport à la synchronisation sur une période donnée.
Par contre chez moi le fichier ost est plus petit en taille que les Données locales.
C'est là que c'est bizzare où il y a un autre fichier ou cache en local sur le PC...

Et par programme comment fait-on pour calculer les tailles.

Merci,

Thierry.

https://www.developpez.net/forums/bl...bal-exchanges/

**Oliv-** · 25/10/2018, 16h43

Pour les OST à partir d'excel
il faut une feuille nommée "OST"

truc = NOM DU PC
soit tu connais le nom du compte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
USER="TOTO"
strFolderName = "\\" & truc & "\c$\Users\" & USER & "\AppData\Local\Microsoft\Outlook"

soit tu checks tous les dossiers users (donc plus long)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
USER="TOTO"
strFolderName = "\\" & truc & "\c$\Users"

call ListOSTFiles (strFolderName)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
Sub ListOSTFiles(strFolderName)
' adapté de Ole P Erlandsen
' necessite d'activer la reference Microsoft Scripting RunTime
 
    Static fso As Object
    Dim oSourceFolder As Object
    Dim oSubFolder As Object
    Dim oFile As Object
    Static wksDest As Worksheet
    Static iRow As Long
    Static bNotFirstTime As Boolean
 
    If Not bNotFirstTime Then
        Set wksDest = ThisWorkbook.Worksheets("OST")
        Set fso = CreateObject("Scripting.FileSystemObject")
        wksDest.Cells(1, 1) = "Parent folder"
        wksDest.Cells(1, 2) = "Full path"
        wksDest.Cells(1, 3) = "File name"
        wksDest.Cells(1, 4) = "Size"
        wksDest.Cells(1, 5) = "Type"
        wksDest.Cells(1, 6) = "Date created"
        wksDest.Cells(1, 7) = "Date last modified"
        wksDest.Cells(1, 8) = "Date last accessed"
        wksDest.Cells(1, 9) = "Attributes"
        wksDest.Cells(1, 10) = "Short path"
        wksDest.Cells(1, 11) = "Short name"
        wksDest.Cells(1, 12) = "Date extraction"
 
        iRow = wksDest.Range("a" & wksDest.Rows.Count).End(xlUp).Row + 1
        bNotFirstTime = True
    End If
    On Error GoTo fin
    Set oSourceFolder = fso.GetFolder(strFolderName)
 
    For Each oFile In oSourceFolder.Files
 
        If fso.GetExtensionName(oFile.Name) = "ost" Then
            wksDest.Cells(iRow, 1) = oFile.ParentFolder.Path
            wksDest.Cells(iRow, 2) = oFile.Path
            wksDest.Cells(iRow, 3) = oFile.Name
            wksDest.Cells(iRow, 4) = MEF_Octet_Short(oFile.Size)
            wksDest.Cells(iRow, 5) = oFile.Type
            wksDest.Cells(iRow, 6) = oFile.DateCreated
            wksDest.Cells(iRow, 7) = oFile.DateLastModified
            wksDest.Cells(iRow, 8) = oFile.DateLastAccessed
            wksDest.Cells(iRow, 9) = oFile.Attributes
            wksDest.Cells(iRow, 10) = oFile.ShortPath
            wksDest.Cells(iRow, 11) = oFile.ShortName
            wksDest.Cells(iRow, 12) = Now
            wksDest.Hyperlinks.Add Anchor:=wksDest.Cells(iRow, 2), Address:= _
                                   oFile.Path, _
                                   TextToDisplay:= _
                                   oFile.Path
 
            iRow = iRow + 1
        End If
    Next oFile
 
fin:
 
 
End Sub

**thierryppp** · 25/10/2018, 18h20

Merci Oliv,

Merci pour les pointeurs sur les codes VBA.
Pour celui qui a le titre STORE SIZE / Tailles des BAL exchanges
Je m'en étais déjà servi de ce code pour calculer la taille de tous les pst avec :
Const PR_MESSAGE_SIZE_EXTENDED = "http://schemas.microsoft.com/mapi/proptag/0x0E080014"
en bouclant dans tous les sous dossiers.

J'avais fait un code HTA/VBS qui est un peu long en éxécution (code à l'extérieur d'outlook)
mais qui marche et ça me donne bien les 2,8 Go qui est équivalent à "Données locales"
Pour le fichier ost je fais dans le même code

Set objInbox = objNamespace.Folders(stPst)
iSize = objFSO.GetFile(ObjInbox.store.filepath).Size

Et ça me donne bien les 1,8 Go du fichier "boite aux lettres".ost

Question comment explique t-on la différence entre ces 2 valeurs ? ==> 1 Go de d'écart

Pour la taille de la boite aux lettres sur le serveur je ne sais pas comment on la calcule....

Thierry.

**Oliv-** · 26/10/2018, 09h52

Salut,

Quelle est ta version de OUTLOOK ?

Je suppose que tu as vérifié la date du fichier OST ?

**thierryppp** · 26/10/2018, 11h06

Salut Oliv,

Oui j'ai vérifié la date du fichier ost ==> il est bien utilisé par Outlook.
La produit c'est Microsoft Office 365 ProPlus et la version d'outlook 2016 version 1803

Thierry.

**Oliv-** · 26/10/2018, 13h51

Comme je le pensais OL2016 compresse son fichier OST

https://social.technet.microsoft.com...ffice2016ITPro

https://www.msoutlook.info/question/...size-explained

edit: pour la taille sur le serveur j'ai trouvé cela (https://www.pcreview.co.uk/threads/g...m-vba.3194800/)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Public Sub ShowQuotas()
' Show Outlook Exhange user quotas
' ----------
' References:
' Accessing Exchange proerties: https://msdn.microsoft.com/EN-US/library/office/ff863046.aspx
' Outlook quotas: http://blogs.technet.com/b/outlooking/archive/2013/09/19/mailbox-quota-in-outlook-2010-general-information-and-troubleshooting-tips.aspx
' Properties for quotas: http://blogs.msdn.com/b/stephen_griffin/archive/2012/04/17/cached-mode-quotas.aspx
' Property format: https://msdn.microsoft.com/en-us/library/ee159391(v=exchg.80).aspx
'    http://schemas.microsoft.com/mapi/proptag/0xQQQQRRRR
'    QQQQ = id
'    RRRR = type
 
    Dim oStore As Store
    Dim propertyAccessor As Outlook.propertyAccessor
 
    For Each oStore In Outlook.Application.Session.Stores
   ' Set oStore = Outlook.Application.Session.Stores.item(1)
        Debug.Print "Display name: " & oStore.DisplayName
        Debug.Print "Type: " & oStore.ExchangeStoreType & " (";
            If oStore.ExchangeStoreType = olAdditionalExchangeMailbox Then Debug.Print "olAdditionalExchangeMailbox)"
            If oStore.ExchangeStoreType = olExchangeMailbox Then Debug.Print "olExchangeMailbox)"
            If oStore.ExchangeStoreType = olExchangePublicFolder Then Debug.Print "olExchangePublicFolder)"
            If oStore.ExchangeStoreType = olNotExchange Then Debug.Print "olNotExchange)"
            If oStore.ExchangeStoreType = olPrimaryExchangeMailbox Then Debug.Print "olPrimaryExchangeMailbox)"
        Debug.Print "Path: " & oStore.FilePath
        Debug.Print "Cached (=online): " & oStore.IsCachedExchange
 
        Set propertyAccessor = oStore.propertyAccessor
        If oStore.ExchangeStoreType = olExchangePublicFolder Or oStore.ExchangeStoreType = olPrimaryExchangeMailbox Then
            PR_QUOTA_WARNING = propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x341A0003") / 1024
            PR_QUOTA_SEND = propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x341B0003") / 1024
            PR_QUOTA_RECEIVE = propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x341C0003") / 1024
            PR_MESSAGE_SIZE_EXTENDED = propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x0E080014") / 1024
            PR_MESSAGE_SIZE_EXTENDED = PR_MESSAGE_SIZE_EXTENDED / 1024
            Debug.Print "PR_QUOTA_WARNING: " & PR_QUOTA_WARNING & " MB"
            Debug.Print "PR_QUOTA_SEND: " & PR_QUOTA_SEND & " MB"
            Debug.Print "PR_QUOTA_RECEIVE: " & PR_QUOTA_RECEIVE & " MB"
            Debug.Print "PR_MESSAGE_SIZE_EXTENDED (Inbox size): " & Round(PR_MESSAGE_SIZE_EXTENDED) & " MB (=" & Round(100 * PR_MESSAGE_SIZE_EXTENDED / PR_QUOTA_RECEIVE) & "%)"
            Debug.Print "Free space: " & Round(PR_QUOTA_RECEIVE - PR_MESSAGE_SIZE_EXTENDED) & " MB"
        Else
            Debug.Print "   Quota data not available for local storage"
        End If
        Debug.Print "------------"
    Next
    Set oStore = Nothing
End Sub

**Oliv-** · 26/10/2018, 15h19

J'ai modifié la macro ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
Public Sub ShowQuotas()
' Show Outlook Exhange user quotas
' ----------
' References:
' Accessing Exchange proerties: https://msdn.microsoft.com/EN-US/library/office/ff863046.aspx
' Outlook quotas: http://blogs.technet.com/b/outlooking/archive/2013/09/19/mailbox-quota-in-outlook-2010-general-information-and-troubleshooting-tips.aspx
' Properties for quotas: http://blogs.msdn.com/b/stephen_griffin/archive/2012/04/17/cached-mode-quotas.aspx
' Property format: https://msdn.microsoft.com/en-us/library/ee159391(v=exchg.80).aspx
'    http://schemas.microsoft.com/mapi/proptag/0xQQQQRRRR
'    QQQQ = id
'    RRRR = type
' updated 20181026 by Oliv
 
    Dim oStore As Store
    Dim propertyAccessor As Outlook.propertyAccessor
 
    For Each oStore In Outlook.Application.Session.Stores
 
    If oStore.ExchangeStoreType = olPrimaryExchangeMailbox Then Stop
   ' Set oStore = Outlook.Application.Session.Stores.item(1)
        Debug.Print "Display name: " & oStore.displayName
        Debug.Print "Type: " & oStore.ExchangeStoreType & " (";
            If oStore.ExchangeStoreType = olAdditionalExchangeMailbox Then Debug.Print "olAdditionalExchangeMailbox)"
            If oStore.ExchangeStoreType = olExchangeMailbox Then Debug.Print "olExchangeMailbox)"
            If oStore.ExchangeStoreType = olExchangePublicFolder Then Debug.Print "olExchangePublicFolder)"
            If oStore.ExchangeStoreType = olNotExchange Then Debug.Print "olNotExchange)"
            If oStore.ExchangeStoreType = olPrimaryExchangeMailbox Then Debug.Print "olPrimaryExchangeMailbox)"
        Debug.Print "Path: " & oStore.filepath
        Debug.Print "Cached (=online): " & oStore.IsCachedExchange
 
        Set propertyAccessor = oStore.propertyAccessor
        'If oStore.ExchangeStoreType = olExchangePublicFolder Or oStore.ExchangeStoreType = olPrimaryExchangeMailbox Then
        If oStore.ExchangeStoreType <> olNotExchange Then
            PR_QUOTA_WARNING = MEF_Octet_Short(propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x341A0003") * 1024)
            PR_QUOTA_SEND = MEF_Octet_Short(propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x341B0003") * 1024)
            PR_QUOTA_RECEIVE = MEF_Octet_Short(propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x341C0003") * 1024)
            PR_MESSAGE_SIZE_EXTENDED = MEF_Octet_Short(propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x0E080014"))
            PR_MESSAGE_SIZE_EXTENDED_P = Round(100 * propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x0E080014") / (propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x341C0003") * 1024), 2)
            FreeSpace = MEF_Octet_Short((propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x341B0003") * 1024) - propertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x0E080014"))
            'PR_MESSAGE_SIZE_EXTENDED = MEF_Octet_Short(PR_MESSAGE_SIZE_EXTENDED) '/ 1024
            Debug.Print "PR_QUOTA_WARNING: " & PR_QUOTA_WARNING '& " MB"
            Debug.Print "PR_QUOTA_SEND: " & PR_QUOTA_SEND '& " MB"
            Debug.Print "PR_QUOTA_RECEIVE: " & PR_QUOTA_RECEIVE '& " MB"
            Debug.Print "PR_MESSAGE_SIZE_EXTENDED (Inbox size): " & (PR_MESSAGE_SIZE_EXTENDED) & "(=" & PR_MESSAGE_SIZE_EXTENDED_P & "%)"
            Debug.Print "Free space: " & FreeSpace
        Else
            Debug.Print "   Quota data not available for local storage"
        End If
        Debug.Print "------------"
    Next
    Set oStore = Nothing
End Sub
 
Public Function MEF_Octet_Short(lgValeur As Double) As String
'---------------------------------------------------------------------------------------
' Procédure : MEF_Octet_Short
' Auteur    : Dolphy35 - http://dolphy35.developpez.com/
' Date      : 25/04/2008
' Détail    : Fonction permettant un affichage en octet, kilo, mega ou giga selon valeur passée en paramètre
 
' Modif par : joe.levrai
' Date      : 25/04/2015
' Détail    : conversion des If imbriqués en une boucle While Wend avec utilisation d'un tableau d'unités
'---------------------------------------------------------------------------------------
    Dim tableau, i
    tableau = Array("Oct", "Ko", "Mo", "Go")  ' stockage des unités
    While (lgValeur / 1024 > 1) And i < UBound(tableau)  ' itération des divisions par 1024
        i = i + 1  ' décalage de l'unité
        lgValeur = lgValeur / 1024
    Wend
    MEF_Octet_Short = CStr(Round(lgValeur, 2)) & " " & tableau(i)
End Function

**thierryppp** · 26/10/2018, 17h31

Oliv,

Merci bien.

J'ai bien lu les documents sur internet et je comprends maintenant les différences de tailles sur les "bal" et ost...
Je testerai la macro plus tard.
Il me semble qu'elle va calculer la taille des dossiers et sous dossiers en bouclant sur le serveur distant.
C'est je pense l’équivalent de "Données sur serveur".

Mais je pense aussi qu'i doit y avoir une commande qui donne directement la taille du fichier "bal" sur le serveur distant.
Comme on a une commande en local qui donne la taille du fichier ost...
D'ailleurs dans la barre de status en bas à gauche de la fenêtre outlook j'ai l'information suivante 86,7 Go libre.
Dans mon cas j'ai une bal à 100 Go.

Thierry.

Taille des boites aux lettres ?

Outlook

Discussions similaires

Partager

Partager