Discussion :

[galopin01]

Bonjour,

Je désire travailler sur une feuille dont j'ignore le nom dans différents classeurs...
Dans tous les classeurs cette feuille à pour CodeName : "Ws1"

On en est donc au stade suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Workbooks.Open (Chemin & "/" & "WbCible.xlsm")

Je sais récupérer l'index de l'item qui m'intéresse dans VBComponents, mais...
Je voudrai récupérer dans une variable le nom de la Feuille Excel qui correspond à "Ws1"

Merci

[Pierre Fauconnier]

Salut.

Voici une fonction générique qui réalise cela, à stocker dans ta boite à outils. Elle renvoie la feuille souhaitée, ou Nothing si la feuille n'a pas été trouvée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function getSheetByCodeName(Codename As String, Optional wb As Workbook) As Object
  Dim Counter As Long
 
  If wb Is Nothing Then Set wb = ActiveWorkbook
  Counter = 1
  Do While Counter <= wb.Sheets.Count And getSheetByCodeName Is Nothing
    If StrComp(wb.Sheets(Counter).Codename, Codename, vbTextCompare) = 0 Then _
      Set getSheetByCodeName = wb.Sheets(Counter)
    Counter = Counter + 1
  Loop
End Function

[pijaku]

Bonjour,
Tout simplement :
Dim NomFeuil As String
NomFeuil = Ws1.Name

EDIT : ne fonctionne que si le classeur contenant cette feuille est le ThisWorkbook...
Utilise la solution de Pierre

[Pierre Fauconnier]

Salut Franck

Bonjour,
Tout simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim NomFeuil As String
NomFeuil =Ws1.Name

Si c'est une feuille de ThisWorkbook, c'est ok. Si tu cherches la feuille dans un autre classeur, ça ne fonctionne pas.

[EDIT]
PS: De plus, si jamais on modifie le codename (ça arrive, si si!), le code va boguer en compilation. En mettant les codename de feuilles en constantes dans un module de déclaration et en utilisant la fonction proposée, si par malheur on doit modifier le codename, on change simplement la valeur de la constante à un seul endroit du code sans devoir passer tout en revue

[galopin01]

Bonjour,
Oui mon erreur était de chercher à lire la collection des VBComponents plutôt que de comparer la liste des feuilles avec leur CodeName.
Merci à tous.
A+