Discussion :

[SpaceX]

Bonjour,

D'habitude pour enregistrer mes données au format txt, je copie/colle les données qui m'intéresse sur une feuille vierge et j'applique cette instruction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
        Worksheets("Feuil1").SaveAs FileName:=chemin & "\Feuil1.txt", _
        FileFormat:=xlUnicodeText, CreateBackup:=False

J'aimerai savoir s'il existe un moyen en VBA, d'enregistrer une plage bien définie par exemple : A1:G50 de la feuil1 et non pas toute la feuille.

Merci d'avance.

[Theze]

Bonjour,

Une piste (voir commentaires) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Sub FichierTexte()
 
    'activer la référence "Microsoft Forms 2.0 Object Library." ou ajouter un formulaire (la référence sera automatiquement ajoutée)
    Dim PP As New DataObject
 
    Dim Plage As Range
    Dim Dossier As String
    Dim Fichier As String
    Dim Texte As String
 
 
    Dossier = "C:\Dossier1\Dossier2\Dossier3\"'<--- à adapter
    Fichier = "Test.txt"
 
    On Error Resume Next
    Kill Dossier & Fichier
    On Error GoTo 0
 
    Set Plage = ActiveSheet.Range("A1:G50")
 
    Plage.Copy
 
    With PP
 
        .Clear
        .GetFromClipboard
        Texte = .GetText(1)
 
    End With
 
    Application.CutCopyMode = False
 
    Texte = Replace(Texte, vbTab, ";") '<--- mettre ici le séparateur voulu en lieu et place des tabulations si nécessaire
 
    'création du fichier
    Open Dossier & Fichier For Binary Access Write As #1: Put #1, , Texte: Close #1
 
End Sub