Discussion :

[Amstel]

Bonjour,

Etant dans l'obligation de me mettre à la gestion des fichiers XLM, je cherche un exemple de code permettant de lire un fichier XLM.

Je dois en effet développer un module permettant d'extraire les données d'un fichier XLM afin de les importer dans une base access.

J'ai juste besoin donc de savoir comment on peut ouvrir ce type de fichier et comment récupérer les valeurs.

Par avance merci de toute aide.

J-Marc

[SfJ5Rpw8]

bonjour et bienvenue sur le forum



voir FAQ : Comment lire un fichier XML ?

et ma signature..

[Amstel]

voir FAQ : Comment lire un fichier XML ?

Merci de votre réponse.
J'avais déjà regardé la FAQ et consulté cette source.
Ca affiche les en-têtes mais pas le contenu.

[SilkyRoad]

bonjour

tu peux tester cette procedure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Option Explicit
Dim oDoc As MSXML2.DOMDocument
 
Private Sub CommandButton1_Click()
    Set oDoc = New DOMDocument
    oDoc.async = False
    oDoc.Load "C:\Documents and Settings\michel\dossier\leFichier.xml"
 
    ExtractionXML oDoc.documentElement
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Function ExtractionXML(ByRef oElem As MSXML2.IXMLDOMNode)
    Dim oNodeList As MSXML2.IXMLDOMNodeList
    Dim i As Long
 
    Select Case oElem.nodeType
        Case MSXML2.NODE_ELEMENT 'type Element
        Debug.Print oElem.nodeName & " (" & GetAttributes(oElem) & ")"
 
        Case MSXML2.NODE_TEXT 'type texte
        Debug.Print "Text: " & oElem.nodeValue
 
        Case MSXML2.NODE_CDATA_SECTION 'type Cdata
        Debug.Print "CDATA: " & oElem.nodeValue
 
        Case Else
        Debug.Print oElem.nodeType & ": " & oElem.nodeName
    End Select
 
    'boucle récursive pour ajouter tous les noeuds enfants
    Set oNodeList = oElem.childNodes
 
    For i = 0 To oNodeList.Length - 1
        ExtractionXML oNodeList.Item(i)
    Next i
    '----------------------------------------------------
End Function

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Function GetAttributes(ByRef oElm As MSXML2.IXMLDOMNode) As String
    Dim sAttr As String
    Dim i As Long
 
    sAttr = ""
 
    For i = 0 To oElm.Attributes.Length - 1 'boucle sur tous les attributs
        sAttr = sAttr & oElm.Attributes.Item(i).nodeName & "='" & _
        oElm.Attributes.Item(i).nodeValue & "' "
    Next i
 
    GetAttributes = sAttr
End Function

bon week end
michel