Discussion :

[Christophe P.]

Bonjour,

j'ai un fichier csv dont le séparateur est une virgule. je voudrais le transformer en csv avec point-virgule pour séparateur. Mon problème est qu'il contient des chaînes avec des virgules. Exemple de ligne :
"a,b,c,d",e,f,g,"h,i",j
Il faudrait que je le transforme en :
"a,b,c,d";e;f;g;"h,i";j

J'ai essayé avec la commande sed mais je n'arrive à rien de bien.

Quelqu'un sait comment faire ?

[Flodelarab]

Bonjour

Répondre à côté de la question est tout un art. Je m'y essaie:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
$ cat antivirgule
"a,b,c,d",e,f,g,"h,i",j

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
$ awk -F',' '{etat=0; for (i=1;i<NF;i++) {if ($i ~ "\"") etat=1-etat; printf $i; if (!etat) printf ";"; else printf",";};printf $NF"\n";}' antivirgule
"a,b,c,d";e;f;g;"h,i";j

[Christophe P.]

Pas du tout à côté, c'est exactement ce dont j'ai besoin.
Merci.

[Flodelarab]

OK. Attention quand même aux cas particuliers: double quotes à l'intérieur des doubles quotes, nombre impair de double quotes, champ entre double quotes mais sans virgule, etc.

[BufferBob]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
$ awk -F',' '{etat=0; for (i=1;i<NF;i++) {if ($i ~ "\"") etat=1-etat; printf $i; if (!etat) printf ";"; else printf",";};printf $NF"\n";}' antivirgule
"a,b,c,d";e;f;g;"h,i";j

yep, et à mon avis ce sera difficile d'avoir un truc plus rigoureux sans avoir recours à un vrai gros parser avec sa grammaire etc., en mode vite fait bien fait c'est le mieux qu'on puisse faire

[CosmoKnacki]

Tu peux utiliser csvtool (à installer au besoin), par contre il sucrera au passage les double quotes devenus inutiles (mais d'un autre coté, il en ajoutera si nécessaire et gère aussi l'échappement):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
csvtool -t "," -u ";" cat <(echo '"a,b,c,d",e,f,g,"h,i",j')
a,b,c,d;e;f;g;h,i;j
 
csvtool -t "," -u ";" cat <(echo '"a;b,c,d",e;f,g,"h,i",j')
"a;b,c,d";"e;f";g;h,i;j
 
csvtool -t "," -u ";" cat <(echo '"a,b"",c,d",e;f,g,"h,i",j')
"a,b"",c,d";"e;f";g;h,i;j

[Flodelarab]

Une version sed pour répondre à la question initiale.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
$ sed 's@"[^"]*"@\n&\n@g;:z1;s@\n\([^"][^\n]*\)\?,\(.*\n\)\?@\n\1;\2@g;t z1;s/\n//g' antivirgule                                            
"a,b,c,d";e;f;g;"h,i";j

On utilise \n comme marqueur, puisque forcément absent de l'espace de travail.
Et on cherche \n ... , ... \n sans quotes, pour le remplacer.

[ctac_]

Bonjour,
Peut être ce sed

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed 's/"[^"]*"/\n&\n/g;:A;s/\(\n[^\n"]*\),/\1;/;tA;s/\n//g'

Cordialement.

[disedorgue]

Et si à l'intérieur d'une paire de guillemet, on avait un retour à la ligne (donc, en fait les 2 lignes ne sont qu'une seule ligne csv) ?

[Flodelarab]

Et si à l'intérieur d'une paire de guillemet, on avait un retour à la ligne (donc, en fait les 2 lignes ne sont qu'une seule ligne csv) ?

csvtool fonctionne.

Quand à sed, ça ne fonctionnera pas. Mais ça n'empêche pas moins qu'il ne peut y avoir de \n dans l'espace de travail sed sans l'y faire rentrer volontairement.
Donc on peut utiliser \n comme comme marqueur. Préférable à TOTO ou POUET ou ";" qui peuvent toujours exister dans le fichier.

[disedorgue]

Mais si, un exemple améliorable - ne gère pas correctement la dernière ligne (au sens csv) si elle n'est pas valide (manque le guillemet fermant) - :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
$ cat tt.csv
"a,b,c,d",e,f,g,"h,i",j
"a,b,
c,d",e,f,g,"h,
i",j
"a,b,\"c\",d",e,f,g,"h,i",j

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
$ cat tt.sed
#!/bin/sed -f
s/^/ /
:deb
 s/\([^\\]\)"/\1\n/
 trc
 bfin
:rc
 s/\([^\\]\)"/\1\n\n/
 tdeb
 s/$/\n\n/
 N
 brc
:fin
 s/\([^\n]\n\{2\}[^\n]*\),/\1;/
 tfin
 s/\([^\n]\)\n\{1,2\}\([^\n]\)/\1"\2/g
 s/ //
 s/\n\n\n/\n/g

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
$ ./tt.sed tt.csv
"a,b,c,d";e;f;g;"h,i";j
"a,b,
c,d";e;f;g;"h,
i";j
"a,b,\"c\",d";e;f;g;"h,i";j