Discussion :

[eriiic]

Bonjour à tous,

je bute sur un truc à-priori simple : comment désigner une feuille par son codename pour un classeur mis en variable ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub test()
    Dim wb As Workbook, sh As Worksheet
    Set wb = ThisWorkbook
    Set sh = wb.Feuil1 ' erreur
    Set sh = wb.Worksheets(Feuil1) ' erreur
End Sub

Peu de possibilités mais je suis à court d'idée pour la bonne syntaxe.
Ca n'est quand même pas réservé au classeur actif (?)
eric

[Pierre Fauconnier]

Salut Eric,

Je passe par cette fonction, qui est depuis longtemps dans mon module wbTools...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Function getWorksheetByCodename(Codename As String, Optional wb As Workbook) As Worksheet
  Dim Counter As Long
  Dim Found As Boolean
 
  If wb Is Nothing Then Set wb = ActiveWorkbook
 
  Counter = 1
  Do While Counter <= wb.Worksheets.Count And Not Found
    If UCase(wb.Worksheets(Counter).Codename) = UCase(Codename) Then
      Set getWorksheetByCodename = wb.Worksheets(Counter)
      Found = True
    End If
    Counter = Counter + 1
  Loop
End Function

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Test1()
  Dim sh As Worksheet
  Dim wb As Workbook
 
  Set wb = Workbooks("Book1")
  Set sh = getWorksheetByCodename("shTest", wb)
End Sub

[Menhir]

Peu de possibilités mais je suis à court d'idée pour la bonne syntaxe.

Je pense que tu as simplement oublié les guillemets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Set sh = wb.Worksheets("Feuil1")

Ecrire, comme tu l'as fait, wb.Worksheets(Feuil1) signifie de chercher le nom de la feuille dans la variable Feuil1 (variable qui, vraisemblablement, n'exixte pas).

Met en première ligne de ton module un Option Explicit qui t'obligera à déclarer tes variables et te permettra de détecter plus facilement ce type de problèmes.

[Pierre Fauconnier]

Salut Menhir,

[...]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Set sh = wb.Worksheets("Feuil1")

[...]

Ici, Eric parle du codename. Dans le code que tu donnes, tu utilises le name, c'est-à-dire le nom de l'onglet Excel.

Je pense que je ne m'amuserais pas à passer par une fonction perso si la solution était aussi simple que celle que tu proposes, tu ne crois pas?

...

[Menhir]

Ici, Eric parle du codename. Dans le code que tu donnes, tu utilises le name, c'est-à-dire le nom de l'onglet Excel.

Etant donné les erreurs que contient le code qu'il a fourni, je ne suis pas sûr qu'il ait une définition du codename aussi précise que la notre.
D'où ma proposition pour vérifier si, après tout, ce n'est pas simplement le name dont il a besoin (étant donné la simplicité, on ne perd rien à essayer).

[Pierre Fauconnier]

[...]je ne suis pas sûr qu'il ait une définition du codename aussi précise que la notre.[...]

Jamais vu quelqu'un parler du codename d'une feuille sans savoir de quoi il parlait...

[eriiic]

Si si, le codename est bien le codename chez moi aussi.
Les 'erreurs' sont des exemples infructueux, la 2nde étant la tentative en désespoir de cause ;-)

Merci Pierre, boucler j'y pensais bien mais ça me paraissait dommage. J'espérais une syntaxe plus directe.
Tant pis :-)
eric

[Marc-L]

Bonjour,

le CodeName étant déjà une variable et n'a une utilité directe uniquement pour le classeur contenant le code !
Dans ce cas créer une variable sur un CodeName est totalement superfétatoire,
du genre prendre l'ascenseur au 5è étage pour descendre au Rez de Chaussée puis remonter directement au 6è par l'escalier !

Dans le cas d'une feuille située sur un classeur différent de celui contenant le code,
ceci à une fin de sécurité vis à vis du changement de l'ordre de la feuille ou de son nom,
il faut alors parcourir la collection des feuilles de ce classeur afin d'y comparer leurs CodeName
et là il y a un intérêt de créer une variable sur la feuille ciblée mais
sans toutefois omettre de libérer cette variable après usage !
Voir par exemple la fonction GetSheetByCode publiée dans les discussions de ce forum …

___________________________________________________________________________________________________________

Je suis Paris, Barcelone, London, Manchester, Egypte, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

[Invité]

Bonjour,
un variante de la version de Pierre!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub test()
Set sh = CodeName("Feuil1", ThisWorkbook)
Set sh1 = CodeName("Feuil1", ThisWorkbook)
Set sh3 = CodeName("Feuil3", ThisWorkbook)
End Sub
Public Function CodeName(Cname As String, ByRef wb As Workbook) As Worksheet
Static dic As Object
Set CodeName = Nothing
If TypeName(dic) = "Nothing" Then Set dic = CreateObject("Scripting.Dictionary")
If Not dic.Exists(Cname & "©" & wb.Name) Then
    For i = 1 To wb.Sheets.Count
        If UCase(wb.Sheets(i).CodeName) = UCase(Cname) Then
             dic.Add Cname & "©" & wb.Name, wb.Sheets(i)
             Set CodeName = wb.Sheets(i)
             Exit For
         End If
 
 
    Next
Else
   Set CodeName = dic(Cname & "©" & wb.Name)
End If
End Function

[eriiic]

Merci à tous :-)