Discussion :

[clem256]

Bonjour,

J'essaie de trouver la bonne formule pour récupérer la référence de type $X:$X sur une colonne dont le titre est "toto". En fait dans la feuille (que je récupère d'un autre outil) la colonne en question dont titre est "toto" peut se trouver tantôt à BL, tantôt à BP...Donc je voudrais m'affranchir de ces aléas dans mes formules.

Merci.
clem256

[Invité]

Bonjour,

Je me sers de cette fonction pour rechercher une colonne en lui indiquant l'onglet, la ligne de titre et le titre de la colonne à trouver.
Si la colonne n'est pas trouvée, la fonction est égale à 0.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Function ColonneFeuille(ByVal FeuilleTitre As Worksheet, ByVal LigneTitre As Long, ByVal TitreRecherche As String) As Long
 
Dim NbColonnes As Long
Dim Cellule As Range, Aire As Range
 
    With FeuilleTitre
 
         ColonneFeuille = 0
         NbColonnes = .Cells(LigneTitre, .Columns.Count).End(xlToLeft).Column
         Set Aire = .Range(.Cells(LigneTitre, 1), .Cells(LigneTitre, NbColonnes))
 
         For Each Cellule In Aire
             Select Case Mid(Cellule.Value, 1, Len(TitreRecherche))
                    Case TitreRecherche
                         ColonneFeuille = Cellule.Column
                         Exit For
             End Select
         Next
 
         If ColonneFeuille = 0 Then DetectionColonnes = DetectionColonnes & Chr(10) & TitreRecherche
 
         Set Aire = Nothing
 
    End With
 
End Function

DetectionColonnes est une variable string publique qui va m'indiquer le résultat pour N recherches non satisfaites. Dans ce cas, la suite du programme ne peut être lancée.

Attention, en cas d'homonymie, c'est la première valeur trouvée qui est prise en compte. On peut faire une recherche sur les N premiers caractères de la chaîne recherchée.

[clem256]

Merci Eric, Philippe. J'exploiterai les suggestions pour un développement en VBA par la suite. Dans un premier temps je voulais juste mettre des formules Excel dans des cellules si c'est possible et non traiter le problème avec du code VBA. Peut-être que je ne suis pas dans le bon sous-forums pour cette question?

Clem256.

[Invité]

Bonjour,

La question étant posée dans le forum Macro VBA Excel, vous avez reçu des réponses en VBA.
Sinon avez-vous regardé les fonctions RECHERCHEH, ou les combinaisons des fonctions INDEX et EQUIV ?

[clem256]

Bonjour,

La question étant posée dans le forum Macro VBA Excel, vous avez reçu des réponses en VBA.
Sinon avez-vous regardé les fonctions RECHERCHEH, ou les combinaisons des fonctions INDEX et EQUIV ?

Eric, merci pour la précision pour le forum. Je pense avoir déjà regarder les combinaisons de ces fonctions. Je n'ai pas pour l'instant trouvé la bonne combinaison. Mais je vais de nouveau me pencher sur la question.

Clem256.

[mjpmjp]

bonjour,



@+JP

[Philippe Tulliez]

Bonjour,
En supposant que la ligne 1 de la liste de données contient bien les étiquettes de colonnes et que la première colonne est remplie de la première à la dernière ligne, voici un petit exemple d'une fonction qui renvoie la colonne comme objet Range en lui passant comme argument le nom de l'étiquette.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Function LabelColumn(StartRange As Range, Label As String, Optional WithLabel As Boolean) As Range
 ' http://philippe.tulliez.be 
 ' Renvoie une colonne comme objet Range
 ' StartRange (Range)  : 1ère cellule de la liste de données
 ' Label      (String) : Nom de l'étiquette de colonne
 ' [WithLabel](Boolean): Si l'on souhaite renvoyer l'adresse avec la 1ère ligne
 Dim rngData As Range, ColumnNumber As Integer
 Set rngData = StartRange.CurrentRegion
 On Error Resume Next
 ColumnNumber = Application.Match(Label, rngData.Rows(1), 0)
 On Error GoTo 0
 If ColumnNumber Then
  With rngData
   Set LabelColumn = .Offset(Abs(Not WithLabel), ColumnNumber - 1).Resize(.Rows.Count - Abs(Not WithLabel), 1)
  End With
 End If
 Set RngData = Nothing 
End Function

Exemple d'une procédure invoquant la fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub TestLabelColumn()
 Dim rng As Range, Label As String
 Label = "salaire"
 Set rng = ThisWorkbook.Worksheets("db").Range("A1")
 Set rng = LabelColumn(rng, Label)
 If rng Is Nothing Then MsgBox "Non trouvé " & Label Else MsgBox rng.Address
End Sub